readd plugins
authorBenjamin Doumenc <big.clop@gmail.com>
Wed, 10 Apr 2013 09:10:39 +0000 (11:10 +0200)
committerBenjamin Doumenc <big.clop@gmail.com>
Wed, 10 Apr 2013 09:10:39 +0000 (11:10 +0200)
25 files changed:
vim/vimfiles/bundle/ag.vim/autoload/ag.vim [new file with mode: 0644]
vim/vimfiles/bundle/ag.vim/doc/ag.txt [new file with mode: 0644]
vim/vimfiles/bundle/ag.vim/plugin/ag.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/bookmarkdir.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/buffertag.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/changes.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/dir.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/line.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/mixed.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/mrufiles.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/quickfix.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/rtscript.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/tag.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/undo.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/autoload/ctrlp/utils.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/doc/ctrlp.txt [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/doc/tags [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/plugin/ctrlp.vim [new file with mode: 0644]
vim/vimfiles/bundle/ctrlp/readme.md [new file with mode: 0644]
vim/vimfiles/bundle/tagbar/README [new file with mode: 0644]
vim/vimfiles/bundle/tagbar/autoload/tagbar.vim [new file with mode: 0644]
vim/vimfiles/bundle/tagbar/doc/tagbar.txt [new file with mode: 0644]
vim/vimfiles/bundle/tagbar/plugin/tagbar.vim [new file with mode: 0644]
vim/vimfiles/bundle/tagbar/syntax/tagbar.vim [new file with mode: 0644]

diff --git a/vim/vimfiles/bundle/ag.vim/autoload/ag.vim b/vim/vimfiles/bundle/ag.vim/autoload/ag.vim
new file mode 100644 (file)
index 0000000..686d598
--- /dev/null
@@ -0,0 +1,101 @@
+" NOTE: You must, of course, install ag / the_silver_searcher
+
+" Location of the ag utility
+if !exists("g:agprg")
+  let g:agprg="ag --column"
+endif
+
+if !exists("g:ag_apply_qmappings")
+  let g:ag_apply_qmappings = !exists("g:ag_qhandler")
+endif
+
+if !exists("g:ag_apply_lmappings")
+  let g:ag_apply_lmappings = !exists("g:ag_lhandler")
+endif
+
+if !exists("g:ag_qhandler")
+  let g:ag_qhandler="botright copen"
+endif
+
+if !exists("g:ag_lhandler")
+  let g:ag_lhandler="botright lopen"
+endif
+
+function! ag#Ag(cmd, args)
+  " If no pattern is provided, search for the word under the cursor
+  if empty(a:args)
+    let l:grepargs = expand("<cword>")
+  else
+    let l:grepargs = a:args . join(a:000, ' ')
+  end
+
+  " Format, used to manage column jump
+  if a:cmd =~# '-g$'
+    let g:agformat="%f"
+  else
+    let g:agformat="%f:%l:%c:%m"
+  end
+
+  let grepprg_bak=&grepprg
+  let grepformat_bak=&grepformat
+  try
+    let &grepprg=g:agprg
+    let &grepformat=g:agformat
+    silent execute a:cmd . " " . escape(l:grepargs, '|')
+  finally
+    let &grepprg=grepprg_bak
+    let &grepformat=grepformat_bak
+  endtry
+
+  if a:cmd =~# '^l'
+    exe g:ag_lhandler
+    let l:apply_mappings = g:ag_apply_lmappings
+  else
+    exe g:ag_qhandler
+    let l:apply_mappings = g:ag_apply_qmappings
+  endif
+
+  " If highlighting is on, highlight the search keyword.
+  if exists("g:aghighlight")
+    let @/=a:args
+    set hlsearch
+  end
+
+  redraw!
+
+  if l:apply_mappings
+    exec "nnoremap <silent> <buffer> q :ccl<CR>"
+    exec "nnoremap <silent> <buffer> t <C-W><CR><C-W>T"
+    exec "nnoremap <silent> <buffer> T <C-W><CR><C-W>TgT<C-W><C-W>"
+    exec "nnoremap <silent> <buffer> o <CR>"
+    exec "nnoremap <silent> <buffer> go <CR><C-W><C-W>"
+    exec "nnoremap <silent> <buffer> h <C-W><CR><C-W>K"
+    exec "nnoremap <silent> <buffer> H <C-W><CR><C-W>K<C-W>b"
+    exec "nnoremap <silent> <buffer> v <C-W><CR><C-W>H<C-W>b<C-W>J<C-W>t"
+    exec "nnoremap <silent> <buffer> gv <C-W><CR><C-W>H<C-W>b<C-W>J"
+    echom "ag.vim keys: q=quit <cr>/t/h/v=enter/tab/split/vsplit go/T/H/gv=preview versions of same"
+  endif
+endfunction
+
+function! ag#AgFromSearch(cmd, args)
+  let search =  getreg('/')
+  " translate vim regular expression to perl regular expression.
+  let search = substitute(search,'\(\\<\|\\>\)','\\b','g')
+  call ag#Ag(a:cmd, '"' .  search .'" '. a:args)
+endfunction
+
+function! ag#GetDocLocations()
+    let dp = ''
+    for p in split(&rtp,',')
+        let p = p.'/doc/'
+        if isdirectory(p)
+            let dp = p.'*.txt '.dp
+        endif
+    endfor
+    return dp
+endfunction
+
+function! ag#AgHelp(cmd,args)
+    let args = a:args.' '.ag#GetDocLocations()
+    call ag#Ag(a:cmd,args)
+endfunction
diff --git a/vim/vimfiles/bundle/ag.vim/doc/ag.txt b/vim/vimfiles/bundle/ag.vim/doc/ag.txt
new file mode 100644 (file)
index 0000000..f8c30cc
--- /dev/null
@@ -0,0 +1,80 @@
+*ag.txt*   Plugin that integrates ag with Vim
+
+==============================================================================
+INTRODUCTION                                                             *ag*
+
+This plugin is a front for the_silver_searcher: ag.  Ag can be used as a
+replacement for ack.  This plugin will allow you to run ag from vim, and
+shows the results in a split window.
+
+:Ag[!] [options] {pattern} [{directory}]                               *:Ag*
+
+    Search recursively in {directory} (which defaults to the current
+    directory) for the {pattern}.  Behaves just like the |:grep| command, but
+    will open the |Quickfix| window for you. If [!] is not given the first
+    error is jumped to.
+
+:AgAdd [options] {pattern} [{directory}]                            *:AgAdd*
+
+    Just like |:Ag|, but instead of making a new list, the matches are
+    appended to the current |quickfix| list.
+
+:AgFromSearch [{directory}]                                  *:AgFromSearch*
+
+    Just like |:Ag| but the pattern is from previous search.
+
+:LAg [options] {pattern} [{directory}]                                *:LAg*
+
+    Just like |:Ag| but instead of the |quickfix| list, matches are placed in
+    the current |location-list|.
+
+:LAgAdd [options] {pattern} [{directory}]                          *:LAgAdd*
+
+    Just like |:AgAdd| but instead of the |quickfix| list, matches are added
+    to the current |location-list|
+
+:AgFile [options] {pattern} [{directory}]                          *:AgFile*
+
+    Search recursively in {directory} (which defaults to the current
+    directory) for filenames matching the {pattern}.  Behaves just like the
+    |:grep| command, but will open the |Quickfix| window for you.
+
+:AgHelp[!] [options] {pattern}                                      *:AgHelp*
+
+    Search vim documentation files for the {pattern}.  Behaves just like the
+    |:Ag| command, but searches only vim documentation .txt files
+
+:LAgHelp [options] {pattern}                                        *:LAgHelp*
+
+    Just like |:AgHelp| but instead of the |quickfix| list, matches are placed
+    in the current |location-list|.
+
+Files containing the search term will be listed in the split window, along
+with the line number of the occurrence, once for each occurrence.  <Enter> on
+a line in this window will open the file, and place the cursor on the matching
+line.
+
+See http://betterthangrep.com/ for more information.
+
+==============================================================================
+MAPPINGS                                                        *ag-mappings*
+
+The following keyboard shortcuts are available in the quickfix window:
+
+o                   open file (same as enter).
+
+go                  preview file (open but maintain focus on ag.vim results).
+
+t                   open in a new tab.
+
+T                   open in new tab silently.
+
+h                   open in horizontal split.
+
+H                  open in horizontal split silently.
+
+v                   open in vertical split.
+
+gv                  open in vertical split silently.
+
+q                   close the quickfix window.
diff --git a/vim/vimfiles/bundle/ag.vim/plugin/ag.vim b/vim/vimfiles/bundle/ag.vim/plugin/ag.vim
new file mode 100644 (file)
index 0000000..eb5bc22
--- /dev/null
@@ -0,0 +1,9 @@
+" NOTE: You must, of course, install ag / the_silver_searcher
+command! -bang -nargs=* -complete=file Ag call ag#Ag('grep<bang>',<q-args>)
+command! -bang -nargs=* -complete=file AgAdd call ag#Ag('grepadd<bang>', <q-args>)
+command! -bang -nargs=* -complete=file AgFromSearch call ag#AgFromSearch('grep<bang>', <q-args>)
+command! -bang -nargs=* -complete=file LAg call ag#Ag('lgrep<bang>', <q-args>)
+command! -bang -nargs=* -complete=file LAgAdd call ag#Ag('lgrepadd<bang>', <q-args>)
+command! -bang -nargs=* -complete=file AgFile call ag#Ag('grep<bang> -g', <q-args>)
+command! -bang -nargs=* -complete=help AgHelp call ag#AgHelp('grep<bang>',<q-args>)
+command! -bang -nargs=* -complete=help LAgHelp call ag#AgHelp('lgrep<bang>',<q-args>)
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp.vim
new file mode 100644 (file)
index 0000000..324ad3a
--- /dev/null
@@ -0,0 +1,2110 @@
+" =============================================================================
+" File:          autoload/ctrlp.vim
+" Description:   Fuzzy file, buffer, mru, tag, etc finder.
+" Author:        Kien Nguyen <github.com/kien>
+" Version:       1.78
+" =============================================================================
+
+" ** Static variables {{{1
+" s:ignore() {{{2
+fu! s:ignore()
+       let igdirs = [
+               \ '\.git',
+               \ '\.hg',
+               \ '\.svn',
+               \ '_darcs',
+               \ '\.bzr',
+               \ '\.cdv',
+               \ '\~\.dep',
+               \ '\~\.dot',
+               \ '\~\.nib',
+               \ '\~\.plst',
+               \ '\.pc',
+               \ '_MTN',
+               \ 'blib',
+               \ 'CVS',
+               \ 'RCS',
+               \ 'SCCS',
+               \ '_sgbak',
+               \ 'autom4te\.cache',
+               \ 'cover_db',
+               \ '_build',
+               \ ]
+       let igfiles = [
+               \ '\~$',
+               \ '#.+#$',
+               \ '[._].*\.swp$',
+               \ 'core\.\d+$',
+               \ '\.exe$',
+               \ '\.so$',
+               \ '\.bak$',
+               \ '\.png$',
+               \ '\.jpg$',
+               \ '\.gif$',
+               \ '\.zip$',
+               \ '\.rar$',
+               \ '\.tar\.gz$',
+               \ ]
+       retu {
+               \ 'dir': '\v[\/]('.join(igdirs, '|').')$',
+               \ 'file': '\v'.join(igfiles, '|'),
+               \ }
+endf
+" Script local vars {{{2
+let [s:pref, s:bpref, s:opts, s:new_opts, s:lc_opts] =
+       \ ['g:ctrlp_', 'b:ctrlp_', {
+       \ 'abbrev':                ['s:abbrev', {}],
+       \ 'arg_map':               ['s:argmap', 0],
+       \ 'buffer_func':           ['s:buffunc', {}],
+       \ 'by_filename':           ['s:byfname', 0],
+       \ 'custom_ignore':         ['s:usrign', s:ignore()],
+       \ 'default_input':         ['s:deftxt', 0],
+       \ 'dont_split':            ['s:nosplit', 'netrw'],
+       \ 'dotfiles':              ['s:showhidden', 0],
+       \ 'extensions':            ['s:extensions', []],
+       \ 'follow_symlinks':       ['s:folsym', 0],
+       \ 'highlight_match':       ['s:mathi', [1, 'CtrlPMatch']],
+       \ 'jump_to_buffer':        ['s:jmptobuf', 'Et'],
+       \ 'key_loop':              ['s:keyloop', 0],
+       \ 'lazy_update':           ['s:lazy', 0],
+       \ 'match_func':            ['s:matcher', {}],
+       \ 'match_window_bottom':   ['s:mwbottom', 1],
+       \ 'match_window_reversed': ['s:mwreverse', 1],
+       \ 'max_depth':             ['s:maxdepth', 40],
+       \ 'max_files':             ['s:maxfiles', 10000],
+       \ 'max_height':            ['s:mxheight', 10],
+       \ 'max_history':           ['s:maxhst', exists('+hi') ? &hi : 20],
+       \ 'mruf_default_order':    ['s:mrudef', 0],
+       \ 'open_func':             ['s:openfunc', {}],
+       \ 'open_multi':            ['s:opmul', '1v'],
+       \ 'open_new_file':         ['s:newfop', 'v'],
+       \ 'prompt_mappings':       ['s:urprtmaps', 0],
+       \ 'regexp_search':         ['s:regexp', 0],
+       \ 'root_markers':          ['s:rmarkers', []],
+       \ 'split_window':          ['s:splitwin', 0],
+       \ 'status_func':           ['s:status', {}],
+       \ 'tabpage_position':      ['s:tabpage', 'ac'],
+       \ 'use_caching':           ['s:caching', 1],
+       \ 'use_migemo':            ['s:migemo', 0],
+       \ 'user_command':          ['s:usrcmd', ''],
+       \ 'working_path_mode':     ['s:pathmode', 'ra'],
+       \ }, {
+       \ 'open_multiple_files':   's:opmul',
+       \ 'regexp':                's:regexp',
+       \ 'reuse_window':          's:nosplit',
+       \ 'show_hidden':           's:showhidden',
+       \ 'switch_buffer':         's:jmptobuf',
+       \ }, {
+       \ 'root_markers':          's:rmarkers',
+       \ 'user_command':          's:usrcmd',
+       \ 'working_path_mode':     's:pathmode',
+       \ }]
+
+" Global options
+let s:glbs = { 'magic': 1, 'to': 1, 'tm': 0, 'sb': 1, 'hls': 0, 'im': 0,
+       \ 'report': 9999, 'sc': 0, 'ss': 0, 'siso': 0, 'mfd': 200, 'mouse': 'n',
+       \ 'gcr': 'a:blinkon0', 'ic': 1, 'lmap': '', 'mousef': 0, 'imd': 1 }
+
+" Keymaps
+let [s:lcmap, s:prtmaps] = ['nn <buffer> <silent>', {
+       \ 'PrtBS()':              ['<bs>', '<c-]>'],
+       \ 'PrtDelete()':          ['<del>'],
+       \ 'PrtDeleteWord()':      ['<c-w>'],
+       \ 'PrtClear()':           ['<c-u>'],
+       \ 'PrtSelectMove("j")':   ['<c-j>', '<down>'],
+       \ 'PrtSelectMove("k")':   ['<c-k>', '<up>'],
+       \ 'PrtSelectMove("t")':   ['<Home>', '<kHome>'],
+       \ 'PrtSelectMove("b")':   ['<End>', '<kEnd>'],
+       \ 'PrtSelectMove("u")':   ['<PageUp>', '<kPageUp>'],
+       \ 'PrtSelectMove("d")':   ['<PageDown>', '<kPageDown>'],
+       \ 'PrtHistory(-1)':       ['<c-n>'],
+       \ 'PrtHistory(1)':        ['<c-p>'],
+       \ 'AcceptSelection("e")': ['<cr>', '<2-LeftMouse>'],
+       \ 'AcceptSelection("h")': ['<c-x>', '<c-cr>', '<c-s>'],
+       \ 'AcceptSelection("t")': ['<c-t>'],
+       \ 'AcceptSelection("v")': ['<c-v>', '<RightMouse>'],
+       \ 'ToggleFocus()':        ['<s-tab>'],
+       \ 'ToggleRegex()':        ['<c-r>'],
+       \ 'ToggleByFname()':      ['<c-d>'],
+       \ 'ToggleType(1)':        ['<c-f>', '<c-up>'],
+       \ 'ToggleType(-1)':       ['<c-b>', '<c-down>'],
+       \ 'PrtExpandDir()':       ['<tab>'],
+       \ 'PrtInsert("c")':       ['<MiddleMouse>', '<insert>'],
+       \ 'PrtInsert()':          ['<c-\>'],
+       \ 'PrtCurStart()':        ['<c-a>'],
+       \ 'PrtCurEnd()':          ['<c-e>'],
+       \ 'PrtCurLeft()':         ['<c-h>', '<left>', '<c-^>'],
+       \ 'PrtCurRight()':        ['<c-l>', '<right>'],
+       \ 'PrtClearCache()':      ['<F5>'],
+       \ 'PrtDeleteEnt()':       ['<F7>'],
+       \ 'CreateNewFile()':      ['<c-y>'],
+       \ 'MarkToOpen()':         ['<c-z>'],
+       \ 'OpenMulti()':          ['<c-o>'],
+       \ 'PrtExit()':            ['<esc>', '<c-c>', '<c-g>'],
+       \ }]
+
+if !has('gui_running')
+       cal add(s:prtmaps['PrtBS()'], remove(s:prtmaps['PrtCurLeft()'], 0))
+en
+
+let s:compare_lim = 3000
+
+let s:ficounts = {}
+
+let s:ccex = s:pref.'clear_cache_on_exit'
+
+" Regexp
+let s:fpats = {
+       \ '^\(\\|\)\|\(\\|\)$': '\\|',
+       \ '^\\\(zs\|ze\|<\|>\)': '^\\\(zs\|ze\|<\|>\)',
+       \ '^\S\*$': '\*',
+       \ '^\S\\?$': '\\?',
+       \ }
+
+" Keypad
+let s:kprange = {
+       \ 'Plus': '+',
+       \ 'Minus': '-',
+       \ 'Divide': '/',
+       \ 'Multiply': '*',
+       \ 'Point': '.',
+       \ }
+
+" Highlight groups
+let s:hlgrps = {
+       \ 'NoEntries': 'Error',
+       \ 'Mode1': 'Character',
+       \ 'Mode2': 'LineNr',
+       \ 'Stats': 'Function',
+       \ 'Match': 'Identifier',
+       \ 'PrtBase': 'Comment',
+       \ 'PrtText': 'Normal',
+       \ 'PrtCursor': 'Constant',
+       \ }
+" s:opts() {{{2
+fu! s:opts(...)
+       unl! s:usrign s:usrcmd s:urprtmaps
+       for each in ['byfname', 'regexp', 'extensions'] | if exists('s:'.each)
+               let {each} = s:{each}
+       en | endfo
+       for [ke, va] in items(s:opts)
+               let {va[0]} = exists(s:pref.ke) ? {s:pref.ke} : va[1]
+       endfo
+       unl va
+       for [ke, va] in items(s:new_opts)
+               let {va} = {exists(s:pref.ke) ? s:pref.ke : va}
+       endfo
+       unl va
+       for [ke, va] in items(s:lc_opts)
+               if exists(s:bpref.ke)
+                       unl {va}
+                       let {va} = {s:bpref.ke}
+               en
+       endfo
+       if a:0 && a:1 != {}
+               unl va
+               for [ke, va] in items(a:1)
+                       let opke = substitute(ke, '\(\w:\)\?ctrlp_', '', '')
+                       if has_key(s:lc_opts, opke)
+                               let sva = s:lc_opts[opke]
+                               unl {sva}
+                               let {sva} = va
+                       en
+               endfo
+       en
+       for each in ['byfname', 'regexp'] | if exists(each)
+               let s:{each} = {each}
+       en | endfo
+       if !exists('g:ctrlp_newcache') | let g:ctrlp_newcache = 0 | en
+       let s:maxdepth = min([s:maxdepth, 100])
+       let s:mxheight = max([s:mxheight, 1])
+       let s:glob = s:showhidden ? '.*\|*' : '*'
+       let s:igntype = empty(s:usrign) ? -1 : type(s:usrign)
+       let s:lash = ctrlp#utils#lash()
+       if s:keyloop
+               let [s:lazy, s:glbs['imd']] = [0, 0]
+       en
+       if s:lazy
+               cal extend(s:glbs, { 'ut': ( s:lazy > 1 ? s:lazy : 250 ) })
+       en
+       " Extensions
+       if !( exists('extensions') && extensions == s:extensions )
+               for each in s:extensions
+                       exe 'ru autoload/ctrlp/'.each.'.vim'
+               endfo
+       en
+       " Keymaps
+       if type(s:urprtmaps) == 4
+               cal extend(s:prtmaps, s:urprtmaps)
+       en
+endf
+"}}}1
+" * Open & Close {{{1
+fu! s:Open()
+       cal s:log(1)
+       cal s:getenv()
+       cal s:execextvar('enter')
+       sil! exe 'keepa' ( s:mwbottom ? 'bo' : 'to' ) '1new ControlP'
+       cal s:buffunc(1)
+       let [s:bufnr, s:winw] = [bufnr('%'), winwidth(0)]
+       let [s:focus, s:prompt] = [1, ['', '', '']]
+       abc <buffer>
+       if !exists('s:hstry')
+               let hst = filereadable(s:gethistloc()[1]) ? s:gethistdata() : ['']
+               let s:hstry = empty(hst) || !s:maxhst ? [''] : hst
+       en
+       for [ke, va] in items(s:glbs) | if exists('+'.ke)
+               sil! exe 'let s:glb_'.ke.' = &'.ke.' | let &'.ke.' = '.string(va)
+       en | endfo
+       if s:opmul != '0' && has('signs')
+               sign define ctrlpmark text=+> texthl=Search
+       en
+       cal s:setupblank()
+endf
+
+fu! s:Close()
+       cal s:buffunc(0)
+       try | bun!
+       cat | clo! | endt
+       cal s:unmarksigns()
+       for key in keys(s:glbs) | if exists('+'.key)
+               sil! exe 'let &'.key.' = s:glb_'.key
+       en | endfo
+       if exists('s:glb_acd') | let &acd = s:glb_acd | en
+       let g:ctrlp_lines = []
+       if s:winres[1] >= &lines && s:winres[2] == winnr('$')
+               exe s:winres[0].s:winres[0]
+       en
+       unl! s:focus s:hisidx s:hstgot s:marked s:statypes s:cline s:init s:savestr
+               \ s:mrbs s:did_exp
+       cal ctrlp#recordhist()
+       cal s:execextvar('exit')
+       cal s:log(0)
+       let v:errmsg = s:ermsg
+       ec
+endf
+" * Clear caches {{{1
+fu! ctrlp#clr(...)
+       let [s:matches, g:ctrlp_new{ a:0 ? a:1 : 'cache' }] = [1, 1]
+endf
+
+fu! ctrlp#clra()
+       let cadir = ctrlp#utils#cachedir()
+       if isdirectory(cadir)
+               let cafiles = split(s:glbpath(s:fnesc(cadir, 'g', ','), '**', 1), "\n")
+               let eval = '!isdirectory(v:val) && fnamemodify(v:val, ":t") !~'
+                       \ . ' ''\v^<cache>[.a-z]+$|\.log$'''
+               sil! cal map(filter(cafiles, eval), 'delete(v:val)')
+       en
+       cal ctrlp#clr()
+endf
+
+fu! s:Reset(args)
+       let opts = has_key(a:args, 'opts') ? [a:args['opts']] : []
+       cal call('s:opts', opts)
+       cal s:autocmds()
+       cal ctrlp#utils#opts()
+       cal s:execextvar('opts')
+endf
+" * Files {{{1
+fu! ctrlp#files()
+       let cafile = ctrlp#utils#cachefile()
+       if g:ctrlp_newcache || !filereadable(cafile) || s:nocache(cafile)
+               let [lscmd, s:initcwd, g:ctrlp_allfiles] = [s:lsCmd(), s:dyncwd, []]
+               " Get the list of files
+               if empty(lscmd)
+                       cal s:GlobPath(s:fnesc(s:dyncwd, 'g', ','), 0)
+               el
+                       sil! cal ctrlp#progress('Indexing...')
+                       try | cal s:UserCmd(lscmd)
+                       cat | retu [] | endt
+               en
+               " Remove base directory
+               cal ctrlp#rmbasedir(g:ctrlp_allfiles)
+               if len(g:ctrlp_allfiles) <= s:compare_lim
+                       cal sort(g:ctrlp_allfiles, 'ctrlp#complen')
+               en
+               cal s:writecache(cafile)
+               let catime = getftime(cafile)
+       el
+               let catime = getftime(cafile)
+               if !( exists('s:initcwd') && s:initcwd == s:dyncwd )
+                       \ || get(s:ficounts, s:dyncwd, [0, catime])[1] != catime
+                       let s:initcwd = s:dyncwd
+                       let g:ctrlp_allfiles = ctrlp#utils#readfile(cafile)
+               en
+       en
+       cal extend(s:ficounts, { s:dyncwd : [len(g:ctrlp_allfiles), catime] })
+       retu g:ctrlp_allfiles
+endf
+
+fu! s:GlobPath(dirs, depth)
+       let entries = split(globpath(a:dirs, s:glob), "\n")
+       let [dnf, depth] = [ctrlp#dirnfile(entries), a:depth + 1]
+       cal extend(g:ctrlp_allfiles, dnf[1])
+       if !empty(dnf[0]) && !s:maxf(len(g:ctrlp_allfiles)) && depth <= s:maxdepth
+               sil! cal ctrlp#progress(len(g:ctrlp_allfiles), 1)
+               cal s:GlobPath(join(map(dnf[0], 's:fnesc(v:val, "g", ",")'), ','), depth)
+       en
+endf
+
+fu! s:UserCmd(lscmd)
+       let [path, lscmd] = [s:dyncwd, a:lscmd]
+       if exists('+ssl') && &ssl
+               let [ssl, &ssl, path] = [&ssl, 0, tr(path, '/', '\')]
+       en
+       if has('win32') || has('win64')
+               let lscmd = substitute(lscmd, '\v(^|&&\s*)\zscd (/d)@!', 'cd /d ', '')
+       en
+       let path = exists('*shellescape') ? shellescape(path) : path
+       let g:ctrlp_allfiles = split(system(printf(lscmd, path)), "\n")
+       if exists('+ssl') && exists('ssl')
+               let &ssl = ssl
+               cal map(g:ctrlp_allfiles, 'tr(v:val, "\\", "/")')
+       en
+       if exists('s:vcscmd') && s:vcscmd
+               cal map(g:ctrlp_allfiles, 'tr(v:val, "/", "\\")')
+       en
+       if type(s:usrcmd) == 4 && has_key(s:usrcmd, 'ignore') && s:usrcmd['ignore']
+               if !empty(s:usrign)
+                       let g:ctrlp_allfiles = ctrlp#dirnfile(g:ctrlp_allfiles)[1]
+               en
+               if &wig != ''
+                       cal filter(g:ctrlp_allfiles, 'glob(v:val) != ""')
+               en
+       en
+endf
+
+fu! s:lsCmd()
+       let cmd = s:usrcmd
+       if type(cmd) == 1
+               retu cmd
+       elsei type(cmd) == 3 && len(cmd) >= 2 && cmd[:1] != ['', '']
+               if s:findroot(s:dyncwd, cmd[0], 0, 1) == []
+                       retu len(cmd) == 3 ? cmd[2] : ''
+               en
+               let s:vcscmd = s:lash == '\'
+               retu cmd[1]
+       elsei type(cmd) == 4 && ( has_key(cmd, 'types') || has_key(cmd, 'fallback') )
+               let fndroot = []
+               if has_key(cmd, 'types') && cmd['types'] != {}
+                       let [markrs, cmdtypes] = [[], values(cmd['types'])]
+                       for pair in cmdtypes
+                               cal add(markrs, pair[0])
+                       endfo
+                       let fndroot = s:findroot(s:dyncwd, markrs, 0, 1)
+               en
+               if fndroot == []
+                       retu has_key(cmd, 'fallback') ? cmd['fallback'] : ''
+               en
+               for pair in cmdtypes
+                       if pair[0] == fndroot[0] | brea | en
+               endfo
+               let s:vcscmd = s:lash == '\'
+               retu pair[1]
+       en
+endf
+" - Buffers {{{1
+fu! ctrlp#buffers(...)
+       let ids = sort(filter(range(1, bufnr('$')), 'empty(getbufvar(v:val, "&bt"))'
+               \ .' && getbufvar(v:val, "&bl") && strlen(bufname(v:val))'), 's:compmreb')
+       retu a:0 && a:1 == 'id' ? ids : map(ids, 'fnamemodify(bufname(v:val), ":.")')
+endf
+" * MatchedItems() {{{1
+fu! s:MatchIt(items, pat, limit, exc)
+       let [lines, id] = [[], 0]
+       let pat =
+               \ s:byfname ? map(split(a:pat, '^[^;]\+\\\@<!\zs;', 1), 's:martcs.v:val')
+               \ : s:martcs.a:pat
+       for item in a:items
+               let id += 1
+               try | if !( s:ispath && item == a:exc ) && call(s:mfunc, [item, pat]) >= 0
+                       cal add(lines, item)
+               en | cat | brea | endt
+               if a:limit > 0 && len(lines) >= a:limit | brea | en
+       endfo
+       let s:mdata = [s:dyncwd, s:itemtype, s:regexp, s:sublist(a:items, id, -1)]
+       retu lines
+endf
+
+fu! s:MatchedItems(items, pat, limit)
+       let exc = exists('s:crfilerel') ? s:crfilerel : ''
+       let items = s:narrowable() ? s:matched + s:mdata[3] : a:items
+       if s:matcher != {}
+               let argms = [items, a:pat, a:limit, s:mmode(), s:ispath, exc, s:regexp]
+               let lines = call(s:matcher['match'], argms)
+       el
+               let lines = s:MatchIt(items, a:pat, a:limit, exc)
+       en
+       let s:matches = len(lines)
+       unl! s:did_exp
+       retu lines
+endf
+
+fu! s:SplitPattern(str)
+       let str = a:str
+       if s:migemo && s:regexp && len(str) > 0 && executable('cmigemo')
+               let str = s:migemo(str)
+       en
+       let s:savestr = str
+       if s:regexp
+               let pat = s:regexfilter(str)
+       el
+               let lst = split(str, '\zs')
+               if exists('+ssl') && !&ssl
+                       cal map(lst, 'escape(v:val, ''\'')')
+               en
+               for each in ['^', '$', '.']
+                       cal map(lst, 'escape(v:val, each)')
+               endfo
+       en
+       if exists('lst')
+               let pat = ''
+               if !empty(lst)
+                       if s:byfname && index(lst, ';') > 0
+                               let fbar = index(lst, ';')
+                               let lst_1 = s:sublist(lst, 0, fbar - 1)
+                               let lst_2 = len(lst) - 1 > fbar ? s:sublist(lst, fbar + 1, -1) : ['']
+                               let pat = s:buildpat(lst_1).';'.s:buildpat(lst_2)
+                       el
+                               let pat = s:buildpat(lst)
+                       en
+               en
+       en
+       retu escape(pat, '~')
+endf
+" * BuildPrompt() {{{1
+fu! s:Render(lines, pat)
+       let [&ma, lines, s:height] = [1, a:lines, min([len(a:lines), s:winh])]
+       let pat = s:byfname ? split(a:pat, '^[^;]\+\\\@<!\zs;', 1)[0] : a:pat
+       " Setup the match window
+       sil! exe '%d _ | res' s:height
+       " Print the new items
+       if empty(lines)
+               let [s:matched, s:lines] = [[], []]
+               cal setline(1, ' == NO ENTRIES ==')
+               setl noma nocul
+               cal s:unmarksigns()
+               if s:dohighlight() | cal clearmatches() | en
+               retu
+       en
+       let s:matched = copy(lines)
+       " Sorting
+       if !s:nosort()
+               let s:compat = s:martcs.pat
+               cal sort(lines, 's:mixedsort')
+               unl s:compat
+       en
+       if s:mwreverse | cal reverse(lines) | en
+       let s:lines = copy(lines)
+       cal map(lines, 's:formatline(v:val)')
+       cal setline(1, lines)
+       setl noma cul
+       exe 'keepj norm!' ( s:mwreverse ? 'G' : 'gg' ).'1|'
+       cal s:unmarksigns()
+       cal s:remarksigns()
+       if exists('s:cline') && s:nolim != 1
+               cal cursor(s:cline, 1)
+       en
+       " Highlighting
+       if s:dohighlight()
+               cal s:highlight(pat, s:mathi[1])
+       en
+endf
+
+fu! s:Update(str)
+       " Get the previous string if existed
+       let oldstr = exists('s:savestr') ? s:savestr : ''
+       " Get the new string sans tail
+       let str = s:sanstail(a:str)
+       " Stop if the string's unchanged
+       if str == oldstr && !empty(str) && !exists('s:force') | retu | en
+       let s:martcs = &scs && str =~ '\u' ? '\C' : ''
+       let pat = s:matcher == {} ? s:SplitPattern(str) : str
+       let lines = s:nolim == 1 && empty(str) ? copy(g:ctrlp_lines)
+               \ : s:MatchedItems(g:ctrlp_lines, pat, s:winh)
+       cal s:Render(lines, pat)
+endf
+
+fu! s:ForceUpdate()
+       sil! cal s:Update(escape(s:getinput(), '\'))
+endf
+
+fu! s:BuildPrompt(upd)
+       let base = ( s:regexp ? 'r' : '>' ).( s:byfname ? 'd' : '>' ).'> '
+       let str = escape(s:getinput(), '\')
+       let lazy = str == '' || exists('s:force') || !has('autocmd') ? 0 : s:lazy
+       if a:upd && !lazy && ( s:matches || s:regexp || exists('s:did_exp')
+               \ || str =~ '\(\\\(<\|>\)\|[*|]\)\|\(\\\:\([^:]\|\\:\)*$\)' )
+               sil! cal s:Update(str)
+       en
+       sil! cal ctrlp#statusline()
+       " Toggling
+       let [hiactive, hicursor, base] = s:focus
+               \ ? ['CtrlPPrtText', 'CtrlPPrtCursor', base]
+               \ : ['CtrlPPrtBase', 'CtrlPPrtBase', tr(base, '>', '-')]
+       let hibase = 'CtrlPPrtBase'
+       " Build it
+       redr
+       let prt = copy(s:prompt)
+       cal map(prt, 'escape(v:val, ''"\'')')
+       exe 'echoh' hibase '| echon "'.base.'"
+               \ | echoh' hiactive '| echon "'.prt[0].'"
+               \ | echoh' hicursor '| echon "'.prt[1].'"
+               \ | echoh' hiactive '| echon "'.prt[2].'" | echoh None'
+       " Append the cursor at the end
+       if empty(prt[1]) && s:focus
+               exe 'echoh' hibase '| echon "_" | echoh None'
+       en
+endf
+" - SetDefTxt() {{{1
+fu! s:SetDefTxt()
+       if s:deftxt == '0' || ( s:deftxt == 1 && !s:ispath ) | retu | en
+       let txt = s:deftxt
+       if !type(txt)
+               let txt = txt && !stridx(s:crfpath, s:dyncwd)
+                       \ ? ctrlp#rmbasedir([s:crfpath])[0] : ''
+               let txt = txt != '' ? txt.s:lash(s:crfpath) : ''
+       el
+               let txt = expand(txt, 1)
+       en
+       let s:prompt[0] = txt
+endf
+" ** Prt Actions {{{1
+" Editing {{{2
+fu! s:PrtClear()
+       if !s:focus | retu | en
+       unl! s:hstgot
+       let [s:prompt, s:matches] = [['', '', ''], 1]
+       cal s:BuildPrompt(1)
+endf
+
+fu! s:PrtAdd(char)
+       unl! s:hstgot
+       let s:act_add = 1
+       let s:prompt[0] .= a:char
+       cal s:BuildPrompt(1)
+       unl s:act_add
+endf
+
+fu! s:PrtBS()
+       if !s:focus | retu | en
+       unl! s:hstgot
+       let [s:prompt[0], s:matches] = [substitute(s:prompt[0], '.$', '', ''), 1]
+       cal s:BuildPrompt(1)
+endf
+
+fu! s:PrtDelete()
+       if !s:focus | retu | en
+       unl! s:hstgot
+       let [prt, s:matches] = [s:prompt, 1]
+       let prt[1] = matchstr(prt[2], '^.')
+       let prt[2] = substitute(prt[2], '^.', '', '')
+       cal s:BuildPrompt(1)
+endf
+
+fu! s:PrtDeleteWord()
+       if !s:focus | retu | en
+       unl! s:hstgot
+       let [str, s:matches] = [s:prompt[0], 1]
+       let str = str =~ '\W\w\+$' ? matchstr(str, '^.\+\W\ze\w\+$')
+               \ : str =~ '\w\W\+$' ? matchstr(str, '^.\+\w\ze\W\+$')
+               \ : str =~ '\s\+$' ? matchstr(str, '^.*\S\ze\s\+$')
+               \ : str =~ '\v^(\S+|\s+)$' ? '' : str
+       let s:prompt[0] = str
+       cal s:BuildPrompt(1)
+endf
+
+fu! s:PrtInsert(...)
+       if !s:focus | retu | en
+       let type = !a:0 ? '' : a:1
+       if !a:0
+               let type = s:insertstr()
+               if type == 'cancel' | retu | en
+       en
+       if type ==# 'r'
+               let regcont = s:getregs()
+               if regcont < 0 | retu | en
+       en
+       unl! s:hstgot
+       let s:act_add = 1
+       let s:prompt[0] .= type ==# 'w' ? s:crword
+               \ : type ==# 'f' ? s:crgfile
+               \ : type ==# 's' ? s:regisfilter('/')
+               \ : type ==# 'v' ? s:crvisual
+               \ : type ==# 'c' ? s:regisfilter('+')
+               \ : type ==# 'r' ? regcont : ''
+       cal s:BuildPrompt(1)
+       unl s:act_add
+endf
+
+fu! s:PrtExpandDir()
+       if !s:focus | retu | en
+       let str = s:getinput('c')
+       if str =~ '\v^\@(cd|lc[hd]?|chd)\s.+' && s:spi
+               let hasat = split(str, '\v^\@(cd|lc[hd]?|chd)\s*\zs')
+               let str = get(hasat, 1, '')
+       en
+       if str == '' | retu | en
+       unl! s:hstgot
+       let s:act_add = 1
+       let [base, seed] = s:headntail(str)
+       let dirs = s:dircompl(base, seed)
+       if len(dirs) == 1
+               let str = dirs[0]
+       elsei len(dirs) > 1
+               let str .= s:findcommon(dirs, str)
+       en
+       let s:prompt[0] = exists('hasat') ? hasat[0].str : str
+       cal s:BuildPrompt(1)
+       unl s:act_add
+endf
+" Movement {{{2
+fu! s:PrtCurLeft()
+       if !s:focus | retu | en
+       let prt = s:prompt
+       if !empty(prt[0])
+               let s:prompt = [substitute(prt[0], '.$', '', ''), matchstr(prt[0], '.$'),
+                       \ prt[1] . prt[2]]
+       en
+       cal s:BuildPrompt(0)
+endf
+
+fu! s:PrtCurRight()
+       if !s:focus | retu | en
+       let prt = s:prompt
+       let s:prompt = [prt[0] . prt[1], matchstr(prt[2], '^.'),
+               \ substitute(prt[2], '^.', '', '')]
+       cal s:BuildPrompt(0)
+endf
+
+fu! s:PrtCurStart()
+       if !s:focus | retu | en
+       let str = join(s:prompt, '')
+       let s:prompt = ['', matchstr(str, '^.'), substitute(str, '^.', '', '')]
+       cal s:BuildPrompt(0)
+endf
+
+fu! s:PrtCurEnd()
+       if !s:focus | retu | en
+       let s:prompt = [join(s:prompt, ''), '', '']
+       cal s:BuildPrompt(0)
+endf
+
+fu! s:PrtSelectMove(dir)
+       let wht = winheight(0)
+       let dirs = {'t': 'gg','b': 'G','j': 'j','k': 'k','u': wht.'k','d': wht.'j'}
+       exe 'keepj norm!' dirs[a:dir]
+       if s:nolim != 1 | let s:cline = line('.') | en
+       if line('$') > winheight(0) | cal s:BuildPrompt(0) | en
+endf
+
+fu! s:PrtSelectJump(char)
+       let lines = copy(s:lines)
+       if s:byfname
+               cal map(lines, 'split(v:val, ''[\/]\ze[^\/]\+$'')[-1]')
+       en
+       " Cycle through matches, use s:jmpchr to store last jump
+       let chr = escape(matchstr(a:char, '^.'), '.~')
+       let smartcs = &scs && chr =~ '\u' ? '\C' : ''
+       if match(lines, smartcs.'^'.chr) >= 0
+               " If not exists or does but not for the same char
+               let pos = match(lines, smartcs.'^'.chr)
+               if !exists('s:jmpchr') || ( exists('s:jmpchr') && s:jmpchr[0] != chr )
+                       let [jmpln, s:jmpchr] = [pos, [chr, pos]]
+               elsei exists('s:jmpchr') && s:jmpchr[0] == chr
+                       " Start of lines
+                       if s:jmpchr[1] == -1 | let s:jmpchr[1] = pos | en
+                       let npos = match(lines, smartcs.'^'.chr, s:jmpchr[1] + 1)
+                       let [jmpln, s:jmpchr] = [npos == -1 ? pos : npos, [chr, npos]]
+               en
+               exe 'keepj norm!' ( jmpln + 1 ).'G'
+               if s:nolim != 1 | let s:cline = line('.') | en
+               if line('$') > winheight(0) | cal s:BuildPrompt(0) | en
+       en
+endf
+" Misc {{{2
+fu! s:PrtFocusMap(char)
+       cal call(( s:focus ? 's:PrtAdd' : 's:PrtSelectJump' ), [a:char])
+endf
+
+fu! s:PrtClearCache()
+       if s:itemtype == 0
+               cal ctrlp#clr()
+       elsei s:itemtype > 2
+               cal ctrlp#clr(s:statypes[s:itemtype][1])
+       en
+       if s:itemtype == 2
+               let g:ctrlp_lines = ctrlp#mrufiles#refresh()
+       el
+               cal ctrlp#setlines()
+       en
+       let s:force = 1
+       cal s:BuildPrompt(1)
+       unl s:force
+endf
+
+fu! s:PrtDeleteEnt()
+       if s:itemtype == 2
+               cal s:PrtDeleteMRU()
+       elsei type(s:getextvar('wipe')) == 1
+               cal s:delent(s:getextvar('wipe'))
+       en
+endf
+
+fu! s:PrtDeleteMRU()
+       if s:itemtype == 2
+               cal s:delent('ctrlp#mrufiles#remove')
+       en
+endf
+
+fu! s:PrtExit()
+       if !has('autocmd') | cal s:Close() | en
+       exe ( winnr('$') == 1 ? 'bw!' : 'winc p' )
+endf
+
+fu! s:PrtHistory(...)
+       if !s:focus || !s:maxhst | retu | en
+       let [str, hst, s:matches] = [join(s:prompt, ''), s:hstry, 1]
+       " Save to history if not saved before
+       let [hst[0], hslen] = [exists('s:hstgot') ? hst[0] : str, len(hst)]
+       let idx = exists('s:hisidx') ? s:hisidx + a:1 : a:1
+       " Limit idx within 0 and hslen
+       let idx = idx < 0 ? 0 : idx >= hslen ? hslen > 1 ? hslen - 1 : 0 : idx
+       let s:prompt = [hst[idx], '', '']
+       let [s:hisidx, s:hstgot, s:force] = [idx, 1, 1]
+       cal s:BuildPrompt(1)
+       unl s:force
+endf
+"}}}1
+" * Mappings {{{1
+fu! s:MapNorms()
+       if exists('s:nmapped') && s:nmapped == s:bufnr | retu | en
+       let pcmd = "nn \<buffer> \<silent> \<k%s> :\<c-u>cal \<SID>%s(\"%s\")\<cr>"
+       let cmd = substitute(pcmd, 'k%s', 'char-%d', '')
+       let pfunc = 'PrtFocusMap'
+       let ranges = [32, 33, 125, 126] + range(35, 91) + range(93, 123)
+       for each in [34, 92, 124]
+               exe printf(cmd, each, pfunc, escape(nr2char(each), '"|\'))
+       endfo
+       for each in ranges
+               exe printf(cmd, each, pfunc, nr2char(each))
+       endfo
+       for each in range(0, 9)
+               exe printf(pcmd, each, pfunc, each)
+       endfo
+       for [ke, va] in items(s:kprange)
+               exe printf(pcmd, ke, pfunc, va)
+       endfo
+       let s:nmapped = s:bufnr
+endf
+
+fu! s:MapSpecs()
+       if !( exists('s:smapped') && s:smapped == s:bufnr )
+               " Correct arrow keys in terminal
+               if ( has('termresponse') && v:termresponse =~ "\<ESC>" )
+                       \ || &term =~? '\vxterm|<k?vt|gnome|screen|linux|ansi'
+                       for each in ['\A <up>','\B <down>','\C <right>','\D <left>']
+                               exe s:lcmap.' <esc>['.each
+                       endfo
+               en
+       en
+       for [ke, va] in items(s:prtmaps) | for kp in va
+               exe s:lcmap kp ':<c-u>cal <SID>'.ke.'<cr>'
+       endfo | endfo
+       let s:smapped = s:bufnr
+endf
+
+fu! s:KeyLoop()
+       wh exists('s:init') && s:keyloop
+               redr
+               let nr = getchar()
+               let chr = !type(nr) ? nr2char(nr) : nr
+               if nr >=# 0x20
+                       cal s:PrtFocusMap(chr)
+               el
+                       let cmd = matchstr(maparg(chr), ':<C-U>\zs.\+\ze<CR>$')
+                       exe ( cmd != '' ? cmd : 'norm '.chr )
+               en
+       endw
+endf
+" * Toggling {{{1
+fu! s:ToggleFocus()
+       let s:focus = !s:focus
+       cal s:BuildPrompt(0)
+endf
+
+fu! s:ToggleRegex()
+       let s:regexp = !s:regexp
+       cal s:PrtSwitcher()
+endf
+
+fu! s:ToggleByFname()
+       if s:ispath
+               let s:byfname = !s:byfname
+               let s:mfunc = s:mfunc()
+               cal s:PrtSwitcher()
+       en
+endf
+
+fu! s:ToggleType(dir)
+       let max = len(g:ctrlp_ext_vars) + 2
+       let next = s:walker(max, s:itemtype, a:dir)
+       cal ctrlp#syntax()
+       cal ctrlp#setlines(next)
+       cal s:PrtSwitcher()
+endf
+
+fu! s:ToggleKeyLoop()
+       let s:keyloop = !s:keyloop
+       if exists('+imd')
+               let &imd = !s:keyloop
+       en
+       if s:keyloop
+               let [&ut, s:lazy] = [0, 0]
+               cal s:KeyLoop()
+       elsei has_key(s:glbs, 'ut')
+               let [&ut, s:lazy] = [s:glbs['ut'], 1]
+       en
+endf
+
+fu! s:PrtSwitcher()
+       let [s:force, s:matches] = [1, 1]
+       cal s:BuildPrompt(1)
+       unl s:force
+endf
+" - SetWD() {{{1
+fu! s:SetWD(args)
+       if has_key(a:args, 'args') && stridx(a:args['args'], '--dir') >= 0
+               \ && exists('s:dyncwd')
+               cal ctrlp#setdir(s:dyncwd) | retu
+       en
+       if has_key(a:args, 'dir') && a:args['dir'] != ''
+               cal ctrlp#setdir(a:args['dir']) | retu
+       en
+       let pmode = has_key(a:args, 'mode') ? a:args['mode'] : s:pathmode
+       let [s:crfilerel, s:dyncwd] = [fnamemodify(s:crfile, ':.'), getcwd()]
+       if s:crfile =~ '^.\+://' | retu | en
+       if pmode =~ 'c' || ( pmode =~ 'a' && stridx(s:crfpath, s:cwd) < 0 )
+               \ || ( !type(pmode) && pmode )
+               if exists('+acd') | let [s:glb_acd, &acd] = [&acd, 0] | en
+               cal ctrlp#setdir(s:crfpath)
+       en
+       if pmode =~ 'r' || pmode == 2
+               let markers = ['.git', '.hg', '.svn', '.bzr', '_darcs']
+               let spath = pmode =~ 'd' ? s:dyncwd : pmode =~ 'w' ? s:cwd : s:crfpath
+               if type(s:rmarkers) == 3 && !empty(s:rmarkers)
+                       if s:findroot(spath, s:rmarkers, 0, 0) != [] | retu | en
+                       cal filter(markers, 'index(s:rmarkers, v:val) < 0')
+               en
+               cal s:findroot(spath, markers, 0, 0)
+       en
+endf
+" * AcceptSelection() {{{1
+fu! ctrlp#acceptfile(mode, line, ...)
+       let [md, filpath] = [a:mode, fnamemodify(a:line, ':p')]
+       cal s:PrtExit()
+       let [bufnr, tail] = [bufnr('^'.filpath.'$'), s:tail()]
+       let j2l = a:0 ? a:1 : matchstr(tail, '^ +\zs\d\+$')
+       if ( s:jmptobuf =~ md || ( s:jmptobuf && md =~ '[et]' ) ) && bufnr > 0
+               \ && !( md == 'e' && bufnr == bufnr('%') )
+               let [jmpb, bufwinnr] = [1, bufwinnr(bufnr)]
+               let buftab = ( s:jmptobuf =~# '[tTVH]' || s:jmptobuf > 1 )
+                       \ ? s:buftab(bufnr, md) : [0, 0]
+       en
+       " Switch to existing buffer or open new one
+       if exists('jmpb') && bufwinnr > 0
+               \ && !( md == 't' && ( s:jmptobuf !~# toupper(md) || buftab[0] ) )
+               exe bufwinnr.'winc w'
+               if j2l | cal ctrlp#j2l(j2l) | en
+       elsei exists('jmpb') && buftab[0]
+               \ && !( md =~ '[evh]' && s:jmptobuf !~# toupper(md) )
+               exe 'tabn' buftab[0]
+               exe buftab[1].'winc w'
+               if j2l | cal ctrlp#j2l(j2l) | en
+       el
+               " Determine the command to use
+               let useb = bufnr > 0 && buflisted(bufnr) && empty(tail)
+               let cmd =
+                       \ md == 't' || s:splitwin == 1 ? ( useb ? 'tab sb' : 'tabe' ) :
+                       \ md == 'h' || s:splitwin == 2 ? ( useb ? 'sb' : 'new' ) :
+                       \ md == 'v' || s:splitwin == 3 ? ( useb ? 'vert sb' : 'vne' ) :
+                       \ call('ctrlp#normcmd', useb ? ['b', 'bo vert sb'] : ['e'])
+               " Reset &switchbuf option
+               let [swb, &swb] = [&swb, '']
+               " Open new window/buffer
+               let [fid, tail] = [( useb ? bufnr : filpath ), ( a:0 ? ' +'.a:1 : tail )]
+               let args = [cmd, fid, tail, 1, [useb, j2l]]
+               cal call('s:openfile', args)
+               let &swb = swb
+       en
+endf
+
+fu! s:SpecInputs(str)
+       if a:str =~ '\v^(\.\.([\/]\.\.)*[\/]?[.\/]*)$' && s:spi
+               let cwd = s:dyncwd
+               cal ctrlp#setdir(a:str =~ '^\.\.\.*$' ?
+                       \ '../'.repeat('../', strlen(a:str) - 2) : a:str)
+               if cwd != s:dyncwd | cal ctrlp#setlines() | en
+               cal s:PrtClear()
+               retu 1
+       elsei a:str == s:lash && s:spi
+               cal s:SetWD({ 'mode': 'rd' })
+               cal ctrlp#setlines()
+               cal s:PrtClear()
+               retu 1
+       elsei a:str =~ '^@.\+' && s:spi
+               retu s:at(a:str)
+       elsei a:str == '?'
+               cal s:PrtExit()
+               let hlpwin = &columns > 159 ? '| vert res 80' : ''
+               sil! exe 'bo vert h ctrlp-mappings' hlpwin '| norm! 0'
+               retu 1
+       en
+       retu 0
+endf
+
+fu! s:AcceptSelection(mode)
+       if a:mode != 'e' && s:OpenMulti(a:mode) != -1 | retu | en
+       let str = s:getinput()
+       if a:mode == 'e' | if s:SpecInputs(str) | retu | en | en
+       " Get the selected line
+       let line = ctrlp#getcline()
+       if a:mode != 'e' && !s:itemtype && line == ''
+               \ && str !~ '\v^(\.\.([\/]\.\.)*[\/]?[.\/]*|/|\\|\?|\@.+)$'
+               cal s:CreateNewFile(a:mode) | retu
+       en
+       if empty(line) | retu | en
+       " Do something with it
+       if s:openfunc != {} && has_key(s:openfunc, s:ctype)
+               let actfunc = s:openfunc[s:ctype]
+       el
+               let actfunc = s:itemtype < 3 ? 'ctrlp#acceptfile' : s:getextvar('accept')
+       en
+       cal call(actfunc, [a:mode, line])
+endf
+" - CreateNewFile() {{{1
+fu! s:CreateNewFile(...)
+       let [md, str] = ['', s:getinput('n')]
+       if empty(str) | retu | en
+       if s:argmap && !a:0
+               " Get the extra argument
+               let md = s:argmaps(md, 1)
+               if md == 'cancel' | retu | en
+       en
+       let str = s:sanstail(str)
+       let [base, fname] = s:headntail(str)
+       if fname =~ '^[\/]$' | retu | en
+       if exists('s:marked') && len(s:marked)
+               " Use the first marked file's path
+               let path = fnamemodify(values(s:marked)[0], ':p:h')
+               let base = path.s:lash(path).base
+               let str = fnamemodify(base.s:lash.fname, ':.')
+       en
+       if base != '' | if isdirectory(ctrlp#utils#mkdir(base))
+               let optyp = str | en | el | let optyp = fname
+       en
+       if !exists('optyp') | retu | en
+       let [filpath, tail] = [fnamemodify(optyp, ':p'), s:tail()]
+       if !stridx(filpath, s:dyncwd) | cal s:insertcache(str) | en
+       cal s:PrtExit()
+       let cmd = md == 'r' ? ctrlp#normcmd('e') :
+               \ s:newfop =~ '1\|t' || ( a:0 && a:1 == 't' ) || md == 't' ? 'tabe' :
+               \ s:newfop =~ '2\|h' || ( a:0 && a:1 == 'h' ) || md == 'h' ? 'new' :
+               \ s:newfop =~ '3\|v' || ( a:0 && a:1 == 'v' ) || md == 'v' ? 'vne' :
+               \ ctrlp#normcmd('e')
+       cal s:openfile(cmd, filpath, tail, 1)
+endf
+" * OpenMulti() {{{1
+fu! s:MarkToOpen()
+       if s:bufnr <= 0 || s:opmul == '0'
+               \ || ( s:itemtype > 2 && s:getextvar('opmul') != 1 )
+               retu
+       en
+       let line = ctrlp#getcline()
+       if empty(line) | retu | en
+       let filpath = s:ispath ? fnamemodify(line, ':p') : line
+       if exists('s:marked') && s:dictindex(s:marked, filpath) > 0
+               " Unmark and remove the file from s:marked
+               let key = s:dictindex(s:marked, filpath)
+               cal remove(s:marked, key)
+               if empty(s:marked) | unl s:marked | en
+               if has('signs')
+                       exe 'sign unplace' key 'buffer='.s:bufnr
+               en
+       el
+               " Add to s:marked and place a new sign
+               if exists('s:marked')
+                       let vac = s:vacantdict(s:marked)
+                       let key = empty(vac) ? len(s:marked) + 1 : vac[0]
+                       let s:marked = extend(s:marked, { key : filpath })
+               el
+                       let [key, s:marked] = [1, { 1 : filpath }]
+               en
+               if has('signs')
+                       exe 'sign place' key 'line='.line('.').' name=ctrlpmark buffer='.s:bufnr
+               en
+       en
+       sil! cal ctrlp#statusline()
+endf
+
+fu! s:OpenMulti(...)
+       let has_marked = exists('s:marked')
+       if ( !has_marked && a:0 ) || s:opmul == '0' || !s:ispath
+               \ || ( s:itemtype > 2 && s:getextvar('opmul') != 1 )
+               retu -1
+       en
+       " Get the options
+       let [nr, md] = [matchstr(s:opmul, '\d\+'), matchstr(s:opmul, '[thvi]')]
+       let [ur, jf] = [s:opmul =~ 'r', s:opmul =~ 'j']
+       let md = a:0 ? a:1 : ( md == '' ? 'v' : md )
+       let nopt = exists('g:ctrlp_open_multiple_files')
+       if !has_marked
+               let line = ctrlp#getcline()
+               if line == '' | retu | en
+               let marked = { 1 : fnamemodify(line, ':p') }
+               let [nr, ur, jf, nopt] = ['1', 0, 0, 1]
+       en
+       if ( s:argmap || !has_marked ) && !a:0
+               let md = s:argmaps(md, !has_marked ? 2 : 0)
+               if md == 'c'
+                       cal s:unmarksigns()
+                       unl! s:marked
+                       cal s:BuildPrompt(0)
+               elsei !has_marked && md =~ '[axd]'
+                       retu s:OpenNoMarks(md, line)
+               en
+               if md =~ '\v^c(ancel)?$' | retu | en
+               let nr = nr == '0' ? ( nopt ? '' : '1' ) : nr
+               let ur = !has_marked && md == 'r' ? 1 : ur
+       en
+       let mkd = values(has_marked ? s:marked : marked)
+       cal s:sanstail(join(s:prompt, ''))
+       cal s:PrtExit()
+       if nr == '0' || md == 'i'
+               retu map(mkd, "s:openfile('bad', v:val, '', 0)")
+       en
+       let tail = s:tail()
+       let [emptytail, bufnr] = [empty(tail), bufnr('^'.mkd[0].'$')]
+       let useb = bufnr > 0 && buflisted(bufnr) && emptytail
+       " Move to a replaceable window
+       let ncmd = ( useb ? ['b', 'bo vert sb'] : ['e', 'bo vne'] )
+               \ + ( ur ? [] : ['ignruw'] )
+       let fst = call('ctrlp#normcmd', ncmd)
+       " Check if the current window has a replaceable buffer
+       let repabl = !( md == 't' && !ur ) && empty(bufname('%')) && empty(&l:ft)
+       " Commands for the rest of the files
+       let [ic, cmds] = [1, { 'v': ['vert sb', 'vne'], 'h': ['sb', 'new'],
+               \ 't': ['tab sb', 'tabe'] }]
+       let [swb, &swb] = [&swb, '']
+       if md == 't' && ctrlp#tabcount() < tabpagenr()
+               let s:tabct = ctrlp#tabcount()
+       en
+       " Open the files
+       for va in mkd
+               let bufnr = bufnr('^'.va.'$')
+               if bufnr < 0 && getftype(va) == '' | con | en
+               let useb = bufnr > 0 && buflisted(bufnr) && emptytail
+               let snd = md != '' && has_key(cmds, md) ?
+                       \ ( useb ? cmds[md][0] : cmds[md][1] ) : ( useb ? 'vert sb' : 'vne' )
+               let cmd = ic == 1 && ( !( !ur && fst =~ '^[eb]$' ) || repabl ) ? fst : snd
+               let conds = [( nr != '' && nr > 1 && nr < ic ) || ( nr == '' && ic > 1 ),
+                       \ nr != '' && nr < ic]
+               if conds[nopt]
+                       if !buflisted(bufnr) | cal s:openfile('bad', va, '', 0) | en
+               el
+                       cal s:openfile(cmd, useb ? bufnr : va, tail, ic == 1)
+                       if jf | if ic == 1
+                               let crpos = [tabpagenr(), winnr()]
+                       el
+                               let crpos[0] += tabpagenr() <= crpos[0]
+                               let crpos[1] += winnr() <= crpos[1]
+                       en | en
+                       let ic += 1
+               en
+       endfo
+       if jf && exists('crpos') && ic > 2
+               exe ( md == 't' ? 'tabn '.crpos[0] : crpos[1].'winc w' )
+       en
+       let &swb = swb
+       unl! s:tabct
+endf
+
+fu! s:OpenNoMarks(md, line)
+       if a:md == 'a'
+               let [s:marked, key] = [{}, 1]
+               for line in s:lines
+                       let s:marked = extend(s:marked, { key : fnamemodify(line, ':p') })
+                       let key += 1
+               endfo
+               cal s:remarksigns()
+               cal s:BuildPrompt(0)
+       elsei a:md == 'x'
+               cal call(s:openfunc[s:ctype], [a:md, a:line])
+       elsei a:md == 'd'
+               let dir = fnamemodify(a:line, ':h')
+               if isdirectory(dir)
+                       cal ctrlp#setdir(dir)
+                       cal ctrlp#switchtype(0)
+                       cal ctrlp#recordhist()
+                       cal s:PrtClear()
+               en
+       en
+endf
+" ** Helper functions {{{1
+" Sorting {{{2
+fu! ctrlp#complen(...)
+       " By length
+       let [len1, len2] = [strlen(a:1), strlen(a:2)]
+       retu len1 == len2 ? 0 : len1 > len2 ? 1 : -1
+endf
+
+fu! s:compmatlen(...)
+       " By match length
+       let mln1 = s:shortest(s:matchlens(a:1, s:compat))
+       let mln2 = s:shortest(s:matchlens(a:2, s:compat))
+       retu mln1 == mln2 ? 0 : mln1 > mln2 ? 1 : -1
+endf
+
+fu! s:comptime(...)
+       " By last modified time
+       let [time1, time2] = [getftime(a:1), getftime(a:2)]
+       retu time1 == time2 ? 0 : time1 < time2 ? 1 : -1
+endf
+
+fu! s:compmreb(...)
+       " By last entered time (bufnr)
+       let [id1, id2] = [index(s:mrbs, a:1), index(s:mrbs, a:2)]
+       retu id1 == id2 ? 0 : id1 > id2 ? 1 : -1
+endf
+
+fu! s:compmref(...)
+       " By last entered time (MRU)
+       let [id1, id2] = [index(g:ctrlp_lines, a:1), index(g:ctrlp_lines, a:2)]
+       retu id1 == id2 ? 0 : id1 > id2 ? 1 : -1
+endf
+
+fu! s:comparent(...)
+       " By same parent dir
+       if !stridx(s:crfpath, s:dyncwd)
+               let [as1, as2] = [s:dyncwd.s:lash().a:1, s:dyncwd.s:lash().a:2]
+               let [loc1, loc2] = [s:getparent(as1), s:getparent(as2)]
+               if loc1 == s:crfpath && loc2 != s:crfpath | retu -1 | en
+               if loc2 == s:crfpath && loc1 != s:crfpath | retu 1  | en
+               retu 0
+       en
+       retu 0
+endf
+
+fu! s:compfnlen(...)
+       " By filename length
+       let len1 = strlen(split(a:1, s:lash)[-1])
+       let len2 = strlen(split(a:2, s:lash)[-1])
+       retu len1 == len2 ? 0 : len1 > len2 ? 1 : -1
+endf
+
+fu! s:matchlens(str, pat, ...)
+       if empty(a:pat) || index(['^', '$'], a:pat) >= 0 | retu {} | en
+       let st   = a:0 ? a:1 : 0
+       let lens = a:0 >= 2 ? a:2 : {}
+       let nr   = a:0 >= 3 ? a:3 : 0
+       if nr > 20 | retu {} | en
+       if match(a:str, a:pat, st) >= 0
+               let [mst, mnd] = [matchstr(a:str, a:pat, st), matchend(a:str, a:pat, st)]
+               let lens = extend(lens, { nr : [strlen(mst), mst] })
+               let lens = s:matchlens(a:str, a:pat, mnd, lens, nr + 1)
+       en
+       retu lens
+endf
+
+fu! s:shortest(lens)
+       retu min(map(values(a:lens), 'v:val[0]'))
+endf
+
+fu! s:mixedsort(...)
+       let [cln, cml] = [ctrlp#complen(a:1, a:2), s:compmatlen(a:1, a:2)]
+       if s:ispath
+               let ms = []
+               if s:height < 21
+                       let ms += [s:compfnlen(a:1, a:2)]
+                       if s:itemtype !~ '^[12]$' | let ms += [s:comptime(a:1, a:2)] | en
+                       if !s:itemtype | let ms += [s:comparent(a:1, a:2)] | en
+               en
+               if s:itemtype =~ '^[12]$'
+                       let ms += [s:compmref(a:1, a:2)]
+                       let cln = cml ? cln : 0
+               en
+               let ms += [cml, 0, 0, 0]
+               let mp = call('s:multipliers', ms[:3])
+               retu cln + ms[0] * mp[0] + ms[1] * mp[1] + ms[2] * mp[2] + ms[3] * mp[3]
+       en
+       retu cln + cml * 2
+endf
+
+fu! s:multipliers(...)
+       let mp0 = !a:1 ? 0 : 2
+       let mp1 = !a:2 ? 0 : 1 + ( !mp0 ? 1 : mp0 )
+       let mp2 = !a:3 ? 0 : 1 + ( !( mp0 + mp1 ) ? 1 : ( mp0 + mp1 ) )
+       let mp3 = !a:4 ? 0 : 1 + ( !( mp0 + mp1 + mp2 ) ? 1 : ( mp0 + mp1 + mp2 ) )
+       retu [mp0, mp1, mp2, mp3]
+endf
+
+fu! s:compval(...)
+       retu a:1 - a:2
+endf
+" Statusline {{{2
+fu! ctrlp#statusline()
+       if !exists('s:statypes')
+               let s:statypes = [
+                       \ ['files', 'fil'],
+                       \ ['buffers', 'buf'],
+                       \ ['mru files', 'mru'],
+                       \ ]
+               if !empty(g:ctrlp_ext_vars)
+                       cal map(copy(g:ctrlp_ext_vars),
+                               \ 'add(s:statypes, [ v:val["lname"], v:val["sname"] ])')
+               en
+       en
+       let tps = s:statypes
+       let max = len(tps) - 1
+       let nxt = tps[s:walker(max, s:itemtype,  1)][1]
+       let prv = tps[s:walker(max, s:itemtype, -1)][1]
+       let s:ctype = tps[s:itemtype][0]
+       let focus   = s:focus ? 'prt'  : 'win'
+       let byfname = s:byfname ? 'file' : 'path'
+       let marked  = s:opmul != '0' ?
+               \ exists('s:marked') ? ' <'.s:dismrk().'>' : ' <->' : ''
+       if s:status != {}
+               let args = [focus, byfname, s:regexp, prv, s:ctype, nxt, marked]
+               let &l:stl = call(s:status['main'], args)
+       el
+               let item    = '%#CtrlPMode1# '.s:ctype.' %*'
+               let focus   = '%#CtrlPMode2# '.focus.' %*'
+               let byfname = '%#CtrlPMode1# '.byfname.' %*'
+               let regex   = s:regexp  ? '%#CtrlPMode2# regex %*' : ''
+               let slider  = ' <'.prv.'>={'.item.'}=<'.nxt.'>'
+               let dir     = ' %=%<%#CtrlPMode2# %{getcwd()} %*'
+               let &l:stl  = focus.byfname.regex.slider.marked.dir
+       en
+endf
+
+fu! s:dismrk()
+       retu has('signs') ? len(s:marked) :
+               \ '%<'.join(values(map(copy(s:marked), 'split(v:val, "[\\/]")[-1]')), ', ')
+endf
+
+fu! ctrlp#progress(enum, ...)
+       if has('macunix') || has('mac') | sl 1m | en
+       let txt = a:0 ? '(press ctrl-c to abort)' : ''
+       let &l:stl = s:status != {} ? call(s:status['prog'], [a:enum])
+               \ : '%#CtrlPStats# '.a:enum.' %* '.txt.'%=%<%#CtrlPMode2# %{getcwd()} %*'
+       redraws
+endf
+" *** Paths {{{2
+" Line formatting {{{3
+fu! s:formatline(str)
+       let str = a:str
+       if s:itemtype == 1
+               let bfnr = bufnr('^'.fnamemodify(str, ':p').'$')
+               let idc = ( bfnr == bufnr('#') ? '#' : '' )
+                       \ . ( getbufvar(bfnr, '&ma') ? '' : '-' )
+                       \ . ( getbufvar(bfnr, '&ro') ? '=' : '' )
+                       \ . ( getbufvar(bfnr, '&mod') ? '+' : '' )
+               let str .= idc != '' ? ' '.idc : ''
+       en
+       let cond = s:ispath && ( s:winw - 4 ) < s:strwidth(str)
+       retu '> '.( cond ? s:pathshorten(str) : str )
+endf
+
+fu! s:pathshorten(str)
+       retu matchstr(a:str, '^.\{9}').'...'
+               \ .matchstr(a:str, '.\{'.( s:winw - 16 ).'}$')
+endf
+" Directory completion {{{3
+fu! s:dircompl(be, sd)
+       if a:sd == '' | retu [] | en
+       let [be, sd] = a:be == '' ? [s:dyncwd, a:sd] : [a:be, a:be.s:lash(a:be).a:sd]
+       let dirs = ctrlp#rmbasedir(split(globpath(s:fnesc(be, 'g', ','), a:sd.'*/'), "\n"))
+       cal filter(dirs, '!match(v:val, escape(sd, ''~$.\''))'
+               \ . ' && v:val !~ ''\v(^|[\/])\.{1,2}[\/]$''')
+       retu dirs
+endf
+
+fu! s:findcommon(items, seed)
+       let [items, id, cmn, ic] = [copy(a:items), strlen(a:seed), '', 0]
+       cal map(items, 'strpart(v:val, id)')
+       for char in split(items[0], '\zs')
+               for item in items[1:]
+                       if item[ic] != char | let brk = 1 | brea | en
+               endfo
+               if exists('brk') | brea | en
+               let cmn .= char
+               let ic += 1
+       endfo
+       retu cmn
+endf
+" Misc {{{3
+fu! s:headntail(str)
+       let parts = split(a:str, '[\/]\ze[^\/]\+[\/:]\?$')
+       retu len(parts) == 1 ? ['', parts[0]] : len(parts) == 2 ? parts : []
+endf
+
+fu! s:lash(...)
+       retu ( a:0 ? a:1 : s:dyncwd ) !~ '[\/]$' ? s:lash : ''
+endf
+
+fu! s:ispathitem()
+       retu s:itemtype < 3 || ( s:itemtype > 2 && s:getextvar('type') == 'path' )
+endf
+
+fu! ctrlp#dirnfile(entries)
+       let [items, cwd] = [[[], []], s:dyncwd.s:lash()]
+       for each in a:entries
+               let etype = getftype(each)
+               if s:igntype >= 0 && s:usrign(each, etype) | con | en
+               if etype == 'dir'
+                       if s:showhidden | if each !~ '[\/]\.\{1,2}$'
+                               cal add(items[0], each)
+                       en | el
+                               cal add(items[0], each)
+                       en
+               elsei etype == 'link'
+                       if s:folsym
+                               let isfile = !isdirectory(each)
+                               if s:folsym == 2 || !s:samerootsyml(each, isfile, cwd)
+                                       cal add(items[isfile], each)
+                               en
+                       en
+               elsei etype == 'file'
+                       cal add(items[1], each)
+               en
+       endfo
+       retu items
+endf
+
+fu! s:usrign(item, type)
+       retu s:igntype == 1 ? a:item =~ s:usrign
+               \ : s:igntype == 4 && has_key(s:usrign, a:type) && s:usrign[a:type] != ''
+               \ ? a:item =~ s:usrign[a:type] : 0
+endf
+
+fu! s:samerootsyml(each, isfile, cwd)
+       let resolve = fnamemodify(resolve(a:each), ':p:h')
+       let resolve .= s:lash(resolve)
+       retu !( stridx(resolve, a:cwd) && ( stridx(a:cwd, resolve) || a:isfile ) )
+endf
+
+fu! ctrlp#rmbasedir(items)
+       if a:items != [] && !stridx(a:items[0], s:dyncwd)
+               let idx = strlen(s:dyncwd) + ( s:dyncwd !~ '[\/]$' )
+               retu map(a:items, 'strpart(v:val, idx)')
+       en
+       retu a:items
+endf
+" Working directory {{{3
+fu! s:getparent(item)
+       let parent = substitute(a:item, '[\/][^\/]\+[\/:]\?$', '', '')
+       if parent == '' || parent !~ '[\/]'
+               let parent .= s:lash
+       en
+       retu parent
+endf
+
+fu! s:findroot(curr, mark, depth, type)
+       let [depth, fnd] = [a:depth + 1, 0]
+       if type(a:mark) == 1
+               let fnd = s:glbpath(s:fnesc(a:curr, 'g', ','), a:mark, 1) != ''
+       elsei type(a:mark) == 3
+               for markr in a:mark
+                       if s:glbpath(s:fnesc(a:curr, 'g', ','), markr, 1) != ''
+                               let fnd = 1
+                               brea
+                       en
+               endfo
+       en
+       if fnd
+               if !a:type | cal ctrlp#setdir(a:curr) | en
+               retu [exists('markr') ? markr : a:mark, a:curr]
+       elsei depth > s:maxdepth
+               cal ctrlp#setdir(s:cwd)
+       el
+               let parent = s:getparent(a:curr)
+               if parent != a:curr
+                       retu s:findroot(parent, a:mark, depth, a:type)
+               en
+       en
+       retu []
+endf
+
+fu! ctrlp#setdir(path, ...)
+       let cmd = a:0 ? a:1 : 'lc!'
+       sil! exe cmd s:fnesc(a:path, 'c')
+       let [s:crfilerel, s:dyncwd] = [fnamemodify(s:crfile, ':.'), getcwd()]
+endf
+" Fallbacks {{{3
+fu! s:glbpath(...)
+       retu call('ctrlp#utils#globpath', a:000)
+endf
+
+fu! s:fnesc(...)
+       retu call('ctrlp#utils#fnesc', a:000)
+endf
+
+fu! ctrlp#setlcdir()
+       if exists('*haslocaldir')
+               cal ctrlp#setdir(getcwd(), haslocaldir() ? 'lc!' : 'cd!')
+       en
+endf
+" Highlighting {{{2
+fu! ctrlp#syntax()
+       if ctrlp#nosy() | retu | en
+       for [ke, va] in items(s:hlgrps) | cal ctrlp#hicheck('CtrlP'.ke, va) | endfo
+       if !hlexists('CtrlPLinePre')
+               \ && synIDattr(synIDtrans(hlID('Normal')), 'bg') !~ '^-1$\|^$'
+               sil! exe 'hi CtrlPLinePre '.( has("gui_running") ? 'gui' : 'cterm' ).'fg=bg'
+       en
+       sy match CtrlPNoEntries '^ == NO ENTRIES ==$'
+       if hlexists('CtrlPLinePre')
+               sy match CtrlPLinePre '^>'
+       en
+endf
+
+fu! s:highlight(pat, grp)
+       if s:matcher != {} | retu | en
+       cal clearmatches()
+       if !empty(a:pat) && s:ispath
+               let pat = s:regexp ? substitute(a:pat, '\\\@<!\^', '^> \\zs', 'g') : a:pat
+               if s:byfname
+                       let pat = substitute(pat, '\[\^\(.\{-}\)\]\\{-}', '[^\\/\1]\\{-}', 'g')
+                       let pat = substitute(pat, '\$\@<!$', '\\ze[^\\/]*$', 'g')
+               en
+               cal matchadd(a:grp, ( s:martcs == '' ? '\c' : '\C' ).pat)
+               cal matchadd('CtrlPLinePre', '^>')
+       en
+endf
+
+fu! s:dohighlight()
+       retu s:mathi[0] && exists('*clearmatches') && !ctrlp#nosy()
+endf
+" Prompt history {{{2
+fu! s:gethistloc()
+       let utilcadir = ctrlp#utils#cachedir()
+       let cache_dir = utilcadir.s:lash(utilcadir).'hist'
+       retu [cache_dir, cache_dir.s:lash(cache_dir).'cache.txt']
+endf
+
+fu! s:gethistdata()
+       retu ctrlp#utils#readfile(s:gethistloc()[1])
+endf
+
+fu! ctrlp#recordhist()
+       let str = join(s:prompt, '')
+       if empty(str) || !s:maxhst | retu | en
+       let hst = s:hstry
+       if len(hst) > 1 && hst[1] == str | retu | en
+       cal extend(hst, [str], 1)
+       if len(hst) > s:maxhst | cal remove(hst, s:maxhst, -1) | en
+       cal ctrlp#utils#writecache(hst, s:gethistloc()[0], s:gethistloc()[1])
+endf
+" Signs {{{2
+fu! s:unmarksigns()
+       if !s:dosigns() | retu | en
+       for key in keys(s:marked)
+               exe 'sign unplace' key 'buffer='.s:bufnr
+       endfo
+endf
+
+fu! s:remarksigns()
+       if !s:dosigns() | retu | en
+       for ic in range(1, len(s:lines))
+               let line = s:ispath ? fnamemodify(s:lines[ic - 1], ':p') : s:lines[ic - 1]
+               let key = s:dictindex(s:marked, line)
+               if key > 0
+                       exe 'sign place' key 'line='.ic.' name=ctrlpmark buffer='.s:bufnr
+               en
+       endfo
+endf
+
+fu! s:dosigns()
+       retu exists('s:marked') && s:bufnr > 0 && s:opmul != '0' && has('signs')
+endf
+" Lists & Dictionaries {{{2
+fu! s:dictindex(dict, expr)
+       for key in keys(a:dict)
+               if a:dict[key] == a:expr | retu key | en
+       endfo
+       retu -1
+endf
+
+fu! s:vacantdict(dict)
+       retu filter(range(1, max(keys(a:dict))), '!has_key(a:dict, v:val)')
+endf
+
+fu! s:sublist(l, s, e)
+       retu v:version > 701 ? a:l[(a:s):(a:e)] : s:sublist7071(a:l, a:s, a:e)
+endf
+
+fu! s:sublist7071(l, s, e)
+       let [newlist, id, ae] = [[], a:s, a:e == -1 ? len(a:l) - 1 : a:e]
+       wh id <= ae
+               cal add(newlist, get(a:l, id))
+               let id += 1
+       endw
+       retu newlist
+endf
+" Buffers {{{2
+fu! s:buftab(bufnr, md)
+       for tabnr in range(1, tabpagenr('$'))
+               if tabpagenr() == tabnr && a:md == 't' | con | en
+               let buflist = tabpagebuflist(tabnr)
+               if index(buflist, a:bufnr) >= 0
+                       for winnr in range(1, tabpagewinnr(tabnr, '$'))
+                               if buflist[winnr - 1] == a:bufnr | retu [tabnr, winnr] | en
+                       endfo
+               en
+       endfo
+       retu [0, 0]
+endf
+
+fu! s:bufwins(bufnr)
+       let winns = 0
+       for tabnr in range(1, tabpagenr('$'))
+               let winns += count(tabpagebuflist(tabnr), a:bufnr)
+       endfo
+       retu winns
+endf
+
+fu! ctrlp#normcmd(cmd, ...)
+       if a:0 < 2 && s:nosplit() | retu a:cmd | en
+       let norwins = filter(range(1, winnr('$')),
+               \ 'empty(getbufvar(winbufnr(v:val), "&bt"))')
+       for each in norwins
+               let bufnr = winbufnr(each)
+               if empty(bufname(bufnr)) && empty(getbufvar(bufnr, '&ft'))
+                       let fstemp = each | brea
+               en
+       endfo
+       let norwin = empty(norwins) ? 0 : norwins[0]
+       if norwin
+               if index(norwins, winnr()) < 0
+                       exe ( exists('fstemp') ? fstemp : norwin ).'winc w'
+               en
+               retu a:cmd
+       en
+       retu a:0 ? a:1 : 'bo vne'
+endf
+
+fu! ctrlp#modfilecond(w)
+       retu &mod && !&hid && &bh != 'hide' && s:bufwins(bufnr('%')) == 1 && !&cf &&
+               \ ( ( !&awa && a:w ) || filewritable(fnamemodify(bufname('%'), ':p')) != 1 )
+endf
+
+fu! s:nosplit()
+       retu !empty(s:nosplit) && match([bufname('%'), &l:ft, &l:bt], s:nosplit) >= 0
+endf
+
+fu! s:setupblank()
+       setl noswf nonu nobl nowrap nolist nospell nocuc wfh
+       setl fdc=0 fdl=99 tw=0 bt=nofile bh=unload
+       if v:version > 702
+               setl nornu noudf cc=0
+       en
+endf
+
+fu! s:leavepre()
+       if exists('s:bufnr') && s:bufnr == bufnr('%') | bw! | en
+       if !( exists(s:ccex) && !{s:ccex} )
+               \ && !( has('clientserver') && len(split(serverlist(), "\n")) > 1 )
+               cal ctrlp#clra()
+       en
+endf
+
+fu! s:checkbuf()
+       if !exists('s:init') && exists('s:bufnr') && s:bufnr > 0
+               exe s:bufnr.'bw!'
+       en
+endf
+
+fu! s:iscmdwin()
+       let ermsg = v:errmsg
+       sil! noa winc p
+       sil! noa winc p
+       let [v:errmsg, ermsg] = [ermsg, v:errmsg]
+       retu ermsg =~ '^E11:'
+endf
+" Arguments {{{2
+fu! s:at(str)
+       if a:str =~ '\v^\@(cd|lc[hd]?|chd).*'
+               let str = substitute(a:str, '\v^\@(cd|lc[hd]?|chd)\s*', '', '')
+               if str == '' | retu 1 | en
+               let str = str =~ '^%:.\+' ? fnamemodify(s:crfile, str[1:]) : str
+               let path = fnamemodify(expand(str, 1), ':p')
+               if isdirectory(path)
+                       if path != s:dyncwd
+                               cal ctrlp#setdir(path)
+                               cal ctrlp#setlines()
+                       en
+                       cal ctrlp#recordhist()
+                       cal s:PrtClear()
+               en
+               retu 1
+       en
+       retu 0
+endf
+
+fu! s:tail()
+       if exists('s:optail') && !empty('s:optail')
+               let tailpref = s:optail !~ '^\s*+' ? ' +' : ' '
+               retu tailpref.s:optail
+       en
+       retu ''
+endf
+
+fu! s:sanstail(str)
+       let str = s:spi ?
+               \ substitute(a:str, '^\(@.*$\|\\\\\ze@\|\.\.\zs[.\/]\+$\)', '', 'g') : a:str
+       let [str, pat] = [substitute(str, '\\\\', '\', 'g'), '\([^:]\|\\:\)*$']
+       unl! s:optail
+       if str =~ '\\\@<!:'.pat
+               let s:optail = matchstr(str, '\\\@<!:\zs'.pat)
+               let str = substitute(str, '\\\@<!:'.pat, '', '')
+       en
+       retu substitute(str, '\\\ze:', '', 'g')
+endf
+
+fu! s:argmaps(md, i)
+       let roh = [
+               \ ['Open Multiple Files', '/h[i]dden/[c]lear', ['i', 'c']],
+               \ ['Create a New File', '/[r]eplace', ['r']],
+               \ ['Open Selected', '/[r]eplace', ['r', 'd', 'a']],
+               \ ]
+       if a:i == 2
+               if !buflisted(bufnr('^'.fnamemodify(ctrlp#getcline(), ':p').'$'))
+                       let roh[2][1] .= '/h[i]dden'
+                       let roh[2][2] += ['i']
+               en
+               if s:openfunc != {} && has_key(s:openfunc, s:ctype)
+                       let roh[2][1] .= '/e[x]ternal'
+                       let roh[2][2] += ['x']
+               en
+       en
+       let str = roh[a:i][0].': [t]ab/[v]ertical/[h]orizontal'.roh[a:i][1].'? '
+       retu s:choices(str, ['t', 'v', 'h'] + roh[a:i][2], 's:argmaps', [a:md, a:i])
+endf
+
+fu! s:insertstr()
+       let str = 'Insert: c[w]ord/c[f]ile/[s]earch/[v]isual/[c]lipboard/[r]egister? '
+       retu s:choices(str, ['w', 'f', 's', 'v', 'c', 'r'], 's:insertstr', [])
+endf
+
+fu! s:textdialog(str)
+       redr | echoh MoreMsg | echon a:str | echoh None
+       retu nr2char(getchar())
+endf
+
+fu! s:choices(str, choices, func, args)
+       let char = s:textdialog(a:str)
+       if index(a:choices, char) >= 0
+               retu char
+       elsei char =~# "\\v\<Esc>|\<C-c>|\<C-g>|\<C-u>|\<C-w>|\<C-[>"
+               cal s:BuildPrompt(0)
+               retu 'cancel'
+       elsei char =~# "\<CR>" && a:args != []
+               retu a:args[0]
+       en
+       retu call(a:func, a:args)
+endf
+
+fu! s:getregs()
+       let char = s:textdialog('Insert from register: ')
+       if char =~# "\\v\<Esc>|\<C-c>|\<C-g>|\<C-u>|\<C-w>|\<C-[>"
+               cal s:BuildPrompt(0)
+               retu -1
+       elsei char =~# "\<CR>"
+               retu s:getregs()
+       en
+       retu s:regisfilter(char)
+endf
+
+fu! s:regisfilter(reg)
+       retu substitute(getreg(a:reg), "[\t\n]", ' ', 'g')
+endf
+" Misc {{{2
+fu! s:modevar()
+       let s:matchtype = s:mtype()
+       let s:ispath = s:ispathitem()
+       if !s:ispath | let s:byfname = 0 | en
+       let s:mfunc = s:mfunc()
+       let s:nolim = s:getextvar('nolim')
+       let s:dosort = s:getextvar('sort')
+       let s:spi = !s:itemtype || s:getextvar('specinput') > 0
+endf
+
+fu! s:nosort()
+       retu s:matcher != {} || s:nolim == 1 || ( s:itemtype == 2 && s:mrudef )
+               \ || ( s:itemtype =~ '\v^(1|2)$' && s:prompt == ['', '', ''] ) || !s:dosort
+endf
+
+fu! s:narrowable()
+       retu exists('s:act_add') && exists('s:matched') && s:matched != []
+               \ && exists('s:mdata') && s:mdata[:2] == [s:dyncwd, s:itemtype, s:regexp]
+               \ && s:matcher == {} && !exists('s:did_exp')
+endf
+
+fu! s:getinput(...)
+       let [prt, spi] = [s:prompt, ( a:0 ? a:1 : '' )]
+       if s:abbrev != {}
+               let gmd = has_key(s:abbrev, 'gmode') ? s:abbrev['gmode'] : ''
+               let str = ( gmd =~ 't' && !a:0 ) || spi == 'c' ? prt[0] : join(prt, '')
+               if gmd =~ 't' && gmd =~ 'k' && !a:0 && matchstr(str, '.$') =~ '\k'
+                       retu join(prt, '')
+               en
+               let [pf, rz] = [( s:byfname ? 'f' : 'p' ), ( s:regexp ? 'r' : 'z' )]
+               for dict in s:abbrev['abbrevs']
+                       let dmd = has_key(dict, 'mode') ? dict['mode'] : ''
+                       let pat = escape(dict['pattern'], '~')
+                       if ( dmd == '' || ( dmd =~ pf && dmd =~ rz && !a:0 )
+                               \ || dmd =~ '['.spi.']' ) && str =~ pat
+                               let [str, s:did_exp] = [join(split(str, pat, 1), dict['expanded']), 1]
+                       en
+               endfo
+               if gmd =~ 't' && !a:0
+                       let prt[0] = str
+               el
+                       retu str
+               en
+       en
+       retu spi == 'c' ? prt[0] : join(prt, '')
+endf
+
+fu! s:migemo(str)
+       let [str, rtp] = [a:str, s:fnesc(&rtp, 'g')]
+       let dict = s:glbpath(rtp, printf("dict/%s/migemo-dict", &enc), 1)
+       if !len(dict)
+               let dict = s:glbpath(rtp, "dict/migemo-dict", 1)
+       en
+       if len(dict)
+               let [tokens, str, cmd] = [split(str, '\s'), '', 'cmigemo -v -w %s -d %s']
+               for token in tokens
+                       let rtn = system(printf(cmd, shellescape(token), shellescape(dict)))
+                       let str .= !v:shell_error && strlen(rtn) > 0 ? '.*'.rtn : token
+               endfo
+       en
+       retu str
+endf
+
+fu! s:strwidth(str)
+       retu exists('*strdisplaywidth') ? strdisplaywidth(a:str) : strlen(a:str)
+endf
+
+fu! ctrlp#j2l(nr)
+       exe 'norm!' a:nr.'G'
+       sil! norm! zvzz
+endf
+
+fu! s:maxf(len)
+       retu s:maxfiles && a:len > s:maxfiles
+endf
+
+fu! s:regexfilter(str)
+       let str = a:str
+       for key in keys(s:fpats) | if str =~ key
+               let str = substitute(str, s:fpats[key], '', 'g')
+       en | endfo
+       retu str
+endf
+
+fu! s:walker(m, p, d)
+       retu a:d >= 0 ? a:p < a:m ? a:p + a:d : 0 : a:p > 0 ? a:p + a:d : a:m
+endf
+
+fu! s:delent(rfunc)
+       if a:rfunc == '' | retu | en
+       let [s:force, tbrem] = [1, []]
+       if exists('s:marked')
+               let tbrem = values(s:marked)
+               cal s:unmarksigns()
+               unl s:marked
+       en
+       if tbrem == [] && ( has('dialog_gui') || has('dialog_con') ) &&
+               \ confirm("Wipe all entries?", "&OK\n&Cancel") != 1
+               unl s:force
+               cal s:BuildPrompt(0)
+               retu
+       en
+       let g:ctrlp_lines = call(a:rfunc, [tbrem])
+       cal s:BuildPrompt(1)
+       unl s:force
+endf
+" Entering & Exiting {{{2
+fu! s:getenv()
+       let [s:cwd, s:winres] = [getcwd(), [winrestcmd(), &lines, winnr('$')]]
+       let [s:crfile, s:crfpath] = [expand('%:p', 1), expand('%:p:h', 1)]
+       let [s:crword, s:crline] = [expand('<cword>', 1), getline('.')]
+       let [s:winh, s:crcursor] = [min([s:mxheight, &lines]), getpos('.')]
+       let [s:crbufnr, s:crvisual] = [bufnr('%'), s:lastvisual()]
+       let [s:mrbs, s:crgfile] = [ctrlp#mrufiles#bufs(), expand('<cfile>', 1)]
+endf
+
+fu! s:lastvisual()
+       let cview = winsaveview()
+       let [ovreg, ovtype] = [getreg('v'), getregtype('v')]
+       let [oureg, outype] = [getreg('"'), getregtype('"')]
+       sil! norm! gv"vy
+       let selected = s:regisfilter('v')
+       cal setreg('v', ovreg, ovtype)
+       cal setreg('"', oureg, outype)
+       cal winrestview(cview)
+       retu selected
+endf
+
+fu! s:log(m)
+       if exists('g:ctrlp_log') && g:ctrlp_log | if a:m
+               let cadir = ctrlp#utils#cachedir()
+               sil! exe 'redi! >' cadir.s:lash(cadir).'ctrlp.log'
+       el
+               sil! redi END
+       en | en
+endf
+
+fu! s:buffunc(e)
+       if a:e && has_key(s:buffunc, 'enter')
+               cal call(s:buffunc['enter'], [])
+       elsei !a:e && has_key(s:buffunc, 'exit')
+               cal call(s:buffunc['exit'], [])
+       en
+endf
+
+fu! s:openfile(cmd, fid, tail, chkmod, ...)
+       let cmd = a:cmd
+       if a:chkmod && cmd =~ '^[eb]$' && ctrlp#modfilecond(!( cmd == 'b' && &aw ))
+               let cmd = cmd == 'b' ? 'sb' : 'sp'
+       en
+       let cmd = cmd =~ '^tab' ? ctrlp#tabcount().cmd : cmd
+       let j2l = a:0 && a:1[0] ? a:1[1] : 0
+       exe cmd.( a:0 && a:1[0] ? '' : a:tail ) s:fnesc(a:fid, 'f')
+       if j2l
+               cal ctrlp#j2l(j2l)
+       en
+       if !empty(a:tail)
+               sil! norm! zvzz
+       en
+       if cmd != 'bad'
+               cal ctrlp#setlcdir()
+       en
+endf
+
+fu! ctrlp#tabcount()
+       if exists('s:tabct')
+               let tabct = s:tabct
+               let s:tabct += 1
+       elsei !type(s:tabpage)
+               let tabct = s:tabpage
+       elsei type(s:tabpage) == 1
+               let tabpos =
+                       \ s:tabpage =~ 'c' ? tabpagenr() :
+                       \ s:tabpage =~ 'f' ? 1 :
+                       \ s:tabpage =~ 'l' ? tabpagenr('$') :
+                       \ tabpagenr()
+               let tabct =
+                       \ s:tabpage =~ 'a' ? tabpos :
+                       \ s:tabpage =~ 'b' ? tabpos - 1 :
+                       \ tabpos
+       en
+       retu tabct < 0 ? 0 : tabct
+endf
+
+fu! s:settype(type)
+       retu a:type < 0 ? exists('s:itemtype') ? s:itemtype : 0 : a:type
+endf
+" Matching {{{2
+fu! s:matchfname(item, pat)
+       let parts = split(a:item, '[\/]\ze[^\/]\+$')
+       let mfn = match(parts[-1], a:pat[0])
+       retu len(a:pat) == 1 ? mfn : len(a:pat) == 2 ?
+               \ ( mfn >= 0 && ( len(parts) == 2 ? match(parts[0], a:pat[1]) : -1 ) >= 0
+               \ ? 0 : -1 ) : -1
+       en
+endf
+
+fu! s:matchtabs(item, pat)
+       retu match(split(a:item, '\t\+')[0], a:pat)
+endf
+
+fu! s:matchtabe(item, pat)
+       retu match(split(a:item, '\t\+[^\t]\+$')[0], a:pat)
+endf
+
+fu! s:buildpat(lst)
+       let pat = a:lst[0]
+       for item in range(1, len(a:lst) - 1)
+               let pat .= '[^'.a:lst[item - 1].']\{-}'.a:lst[item]
+       endfo
+       retu pat
+endf
+
+fu! s:mfunc()
+       let mfunc = 'match'
+       if s:byfname && s:ispath
+               let mfunc = 's:matchfname'
+       elsei s:itemtype > 2
+               let matchtypes = { 'tabs': 's:matchtabs', 'tabe': 's:matchtabe' }
+               if has_key(matchtypes, s:matchtype)
+                       let mfunc = matchtypes[s:matchtype]
+               en
+       en
+       retu mfunc
+endf
+
+fu! s:mmode()
+       let matchmodes = {
+               \ 'match': 'full-line',
+               \ 's:matchfname': 'filename-only',
+               \ 's:matchtabs': 'first-non-tab',
+               \ 's:matchtabe': 'until-last-tab',
+               \ }
+       retu matchmodes[s:mfunc]
+endf
+" Cache {{{2
+fu! s:writecache(cafile)
+       if ( g:ctrlp_newcache || !filereadable(a:cafile) ) && !s:nocache()
+               cal ctrlp#utils#writecache(g:ctrlp_allfiles)
+               let g:ctrlp_newcache = 0
+       en
+endf
+
+fu! s:nocache(...)
+       if !s:caching
+               retu 1
+       elsei s:caching > 1
+               if !( exists(s:ccex) && !{s:ccex} ) || has_key(s:ficounts, s:dyncwd)
+                       retu get(s:ficounts, s:dyncwd, [0, 0])[0] < s:caching
+               elsei a:0 && filereadable(a:1)
+                       retu len(ctrlp#utils#readfile(a:1)) < s:caching
+               en
+               retu 1
+       en
+       retu 0
+endf
+
+fu! s:insertcache(str)
+       let [data, g:ctrlp_newcache, str] = [g:ctrlp_allfiles, 1, a:str]
+       if strlen(str) <= strlen(data[0])
+               let pos = 0
+       elsei strlen(str) >= strlen(data[-1])
+               let pos = len(data) - 1
+       el
+               let pos = 0
+               for each in data
+                       if strlen(each) > strlen(str) | brea | en
+                       let pos += 1
+               endfo
+       en
+       cal insert(data, str, pos)
+       cal s:writecache(ctrlp#utils#cachefile())
+endf
+" Extensions {{{2
+fu! s:mtype()
+       retu s:itemtype > 2 ? s:getextvar('type') : 'path'
+endf
+
+fu! s:execextvar(key)
+       if !empty(g:ctrlp_ext_vars)
+               cal map(filter(copy(g:ctrlp_ext_vars),
+                       \ 'has_key(v:val, a:key)'), 'eval(v:val[a:key])')
+       en
+endf
+
+fu! s:getextvar(key)
+       if s:itemtype > 2
+               let vars = g:ctrlp_ext_vars[s:itemtype - 3]
+               retu has_key(vars, a:key) ? vars[a:key] : -1
+       en
+       retu -1
+endf
+
+fu! ctrlp#getcline()
+       retu !empty(s:lines) ? s:lines[line('.') - 1] : ''
+endf
+
+fu! ctrlp#getmarkedlist()
+       retu exists('s:marked') ? values(s:marked) : []
+endf
+
+fu! ctrlp#exit()
+       cal s:PrtExit()
+endf
+
+fu! ctrlp#prtclear()
+       cal s:PrtClear()
+endf
+
+fu! ctrlp#switchtype(id)
+       cal s:ToggleType(a:id - s:itemtype)
+endf
+
+fu! ctrlp#nosy()
+       retu !( has('syntax') && exists('g:syntax_on') )
+endf
+
+fu! ctrlp#hicheck(grp, defgrp)
+       if !hlexists(a:grp)
+               exe 'hi link' a:grp a:defgrp
+       en
+endf
+
+fu! ctrlp#call(func, ...)
+       cal call(a:func, a:000)
+endf
+"}}}1
+" * Initialization {{{1
+fu! ctrlp#setlines(...)
+       if a:0 | let s:itemtype = a:1 | en
+       cal s:modevar()
+       let types = ['ctrlp#files()', 'ctrlp#buffers()', 'ctrlp#mrufiles#list()']
+       if !empty(g:ctrlp_ext_vars)
+               cal map(copy(g:ctrlp_ext_vars), 'add(types, v:val["init"])')
+       en
+       let g:ctrlp_lines = eval(types[s:itemtype])
+endf
+
+fu! ctrlp#init(type, ...)
+       if exists('s:init') || s:iscmdwin() | retu | en
+       let [s:ermsg, v:errmsg] = [v:errmsg, '']
+       let [s:matches, s:init] = [1, 1]
+       cal s:Reset(a:0 ? a:1 : {})
+       noa cal s:Open()
+       cal s:SetWD(a:0 ? a:1 : {})
+       cal s:MapNorms()
+       cal s:MapSpecs()
+       cal ctrlp#syntax()
+       cal ctrlp#setlines(s:settype(a:type))
+       cal s:SetDefTxt()
+       cal s:BuildPrompt(1)
+       if s:keyloop | cal s:KeyLoop() | en
+endf
+" - Autocmds {{{1
+if has('autocmd')
+       aug CtrlPAug
+               au!
+               au BufEnter ControlP cal s:checkbuf()
+               au BufLeave ControlP noa cal s:Close()
+               au VimLeavePre * cal s:leavepre()
+       aug END
+en
+
+fu! s:autocmds()
+       if !has('autocmd') | retu | en
+       if exists('#CtrlPLazy')
+               au! CtrlPLazy
+       en
+       if s:lazy
+               aug CtrlPLazy
+                       au!
+                       au CursorHold ControlP cal s:ForceUpdate()
+               aug END
+       en
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/bookmarkdir.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/bookmarkdir.vim
new file mode 100644 (file)
index 0000000..7d955b5
--- /dev/null
@@ -0,0 +1,140 @@
+" =============================================================================
+" File:          autoload/ctrlp/bookmarkdir.vim
+" Description:   Bookmarked directories extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_bookmarkdir') && g:loaded_ctrlp_bookmarkdir
+       fini
+en
+let g:loaded_ctrlp_bookmarkdir = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#bookmarkdir#init()',
+       \ 'accept': 'ctrlp#bookmarkdir#accept',
+       \ 'lname': 'bookmarked dirs',
+       \ 'sname': 'bkd',
+       \ 'type': 'tabs',
+       \ 'opmul': 1,
+       \ 'nolim': 1,
+       \ 'wipe': 'ctrlp#bookmarkdir#remove',
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:getinput(str, ...)
+       echoh Identifier
+       cal inputsave()
+       let input = call('input', a:0 ? [a:str] + a:000 : [a:str])
+       cal inputrestore()
+       echoh None
+       retu input
+endf
+
+fu! s:cachefile()
+       if !exists('s:cadir') || !exists('s:cafile')
+               let s:cadir = ctrlp#utils#cachedir().ctrlp#utils#lash().'bkd'
+               let s:cafile = s:cadir.ctrlp#utils#lash().'cache.txt'
+       en
+       retu s:cafile
+endf
+
+fu! s:writecache(lines)
+       cal ctrlp#utils#writecache(a:lines, s:cadir, s:cafile)
+endf
+
+fu! s:getbookmarks()
+       retu ctrlp#utils#readfile(s:cachefile())
+endf
+
+fu! s:savebookmark(name, cwd)
+       let cwds = exists('+ssl') ? [tr(a:cwd, '\', '/'), tr(a:cwd, '/', '\')] : [a:cwd]
+       let entries = filter(s:getbookmarks(), 'index(cwds, s:parts(v:val)[1]) < 0')
+       cal s:writecache(insert(entries, a:name.'       '.a:cwd))
+endf
+
+fu! s:setentries()
+       let time = getftime(s:cachefile())
+       if !( exists('s:bookmarks') && time == s:bookmarks[0] )
+               let s:bookmarks = [time, s:getbookmarks()]
+       en
+endf
+
+fu! s:parts(str)
+       let mlist = matchlist(a:str, '\v([^\t]+)\t(.*)$')
+       retu mlist != [] ? mlist[1:2] : ['', '']
+endf
+
+fu! s:process(entries, type)
+       retu map(a:entries, 's:modify(v:val, a:type)')
+endf
+
+fu! s:modify(entry, type)
+       let [name, dir] = s:parts(a:entry)
+       let dir = fnamemodify(dir, a:type)
+       retu name.'     '.( dir == '' ? '.' : dir )
+endf
+
+fu! s:msg(name, cwd)
+       redr
+       echoh Identifier | echon 'Bookmarked ' | echoh Constant
+       echon a:name.' ' | echoh Directory | echon a:cwd
+       echoh None
+endf
+
+fu! s:syntax()
+       if !ctrlp#nosy()
+               cal ctrlp#hicheck('CtrlPBookmark', 'Identifier')
+               cal ctrlp#hicheck('CtrlPTabExtra', 'Comment')
+               sy match CtrlPBookmark '^> [^\t]\+' contains=CtrlPLinePre
+               sy match CtrlPTabExtra '\zs\t.*\ze$'
+       en
+endf
+" Public {{{1
+fu! ctrlp#bookmarkdir#init()
+       cal s:setentries()
+       cal s:syntax()
+       retu s:process(copy(s:bookmarks[1]), ':.')
+endf
+
+fu! ctrlp#bookmarkdir#accept(mode, str)
+       let parts = s:parts(s:modify(a:str, ':p'))
+       cal call('s:savebookmark', parts)
+       if a:mode =~ 't\|v\|h'
+               cal ctrlp#exit()
+       en
+       cal ctrlp#setdir(parts[1], a:mode =~ 't\|h' ? 'chd!' : 'lc!')
+       if a:mode == 'e'
+               cal ctrlp#switchtype(0)
+               cal ctrlp#recordhist()
+               cal ctrlp#prtclear()
+       en
+endf
+
+fu! ctrlp#bookmarkdir#add(dir)
+       let str = 'Directory to bookmark: '
+       let cwd = a:dir != '' ? a:dir : s:getinput(str, getcwd(), 'dir')
+       if cwd == '' | retu | en
+       let cwd = fnamemodify(cwd, ':p')
+       let name = s:getinput('Bookmark as: ', cwd)
+       if name == '' | retu | en
+       let name = tr(name, '   ', ' ')
+       cal s:savebookmark(name, cwd)
+       cal s:msg(name, cwd)
+endf
+
+fu! ctrlp#bookmarkdir#remove(entries)
+       cal s:process(a:entries, ':p')
+       cal s:writecache(a:entries == [] ? [] :
+               \ filter(s:getbookmarks(), 'index(a:entries, v:val) < 0'))
+       cal s:setentries()
+       retu s:process(copy(s:bookmarks[1]), ':.')
+endf
+
+fu! ctrlp#bookmarkdir#id()
+       retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/buffertag.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/buffertag.vim
new file mode 100644 (file)
index 0000000..0a24eef
--- /dev/null
@@ -0,0 +1,261 @@
+" =============================================================================
+" File:          autoload/ctrlp/buffertag.vim
+" Description:   Buffer Tag extension
+" Maintainer:    Kien Nguyen <github.com/kien>
+" Credits:       Much of the code was taken from tagbar.vim by Jan Larres, plus
+"                a few lines from taglist.vim by Yegappan Lakshmanan and from
+"                buffertag.vim by Takeshi Nishida.
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_buftag') && g:loaded_ctrlp_buftag
+       fini
+en
+let g:loaded_ctrlp_buftag = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#buffertag#init(s:crfile)',
+       \ 'accept': 'ctrlp#buffertag#accept',
+       \ 'lname': 'buffer tags',
+       \ 'sname': 'bft',
+       \ 'exit': 'ctrlp#buffertag#exit()',
+       \ 'type': 'tabs',
+       \ 'opts': 'ctrlp#buffertag#opts()',
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+let [s:pref, s:opts] = ['g:ctrlp_buftag_', {
+       \ 'systemenc': ['s:enc', &enc],
+       \ 'ctags_bin': ['s:bin', ''],
+       \ 'types': ['s:usr_types', {}],
+       \ }]
+
+let s:bins = [
+       \ 'ctags-exuberant',
+       \ 'exuberant-ctags',
+       \ 'exctags',
+       \ '/usr/local/bin/ctags',
+       \ '/opt/local/bin/ctags',
+       \ 'ctags',
+       \ 'ctags.exe',
+       \ 'tags',
+       \ ]
+
+let s:types = {
+       \ 'asm'    : '%sasm%sasm%sdlmt',
+       \ 'aspperl': '%sasp%sasp%sfsv',
+       \ 'aspvbs' : '%sasp%sasp%sfsv',
+       \ 'awk'    : '%sawk%sawk%sf',
+       \ 'beta'   : '%sbeta%sbeta%sfsv',
+       \ 'c'      : '%sc%sc%sdgsutvf',
+       \ 'cpp'    : '%sc++%sc++%snvdtcgsuf',
+       \ 'cs'     : '%sc#%sc#%sdtncEgsipm',
+       \ 'cobol'  : '%scobol%scobol%sdfgpPs',
+       \ 'eiffel' : '%seiffel%seiffel%scf',
+       \ 'erlang' : '%serlang%serlang%sdrmf',
+       \ 'expect' : '%stcl%stcl%scfp',
+       \ 'fortran': '%sfortran%sfortran%spbceiklmntvfs',
+       \ 'html'   : '%shtml%shtml%saf',
+       \ 'java'   : '%sjava%sjava%spcifm',
+       \ 'javascript': '%sjavascript%sjavascript%sf',
+       \ 'lisp'   : '%slisp%slisp%sf',
+       \ 'lua'    : '%slua%slua%sf',
+       \ 'make'   : '%smake%smake%sm',
+       \ 'pascal' : '%spascal%spascal%sfp',
+       \ 'perl'   : '%sperl%sperl%sclps',
+       \ 'php'    : '%sphp%sphp%scdvf',
+       \ 'python' : '%spython%spython%scmf',
+       \ 'rexx'   : '%srexx%srexx%ss',
+       \ 'ruby'   : '%sruby%sruby%scfFm',
+       \ 'scheme' : '%sscheme%sscheme%ssf',
+       \ 'sh'     : '%ssh%ssh%sf',
+       \ 'csh'    : '%ssh%ssh%sf',
+       \ 'zsh'    : '%ssh%ssh%sf',
+       \ 'slang'  : '%sslang%sslang%snf',
+       \ 'sml'    : '%ssml%ssml%secsrtvf',
+       \ 'sql'    : '%ssql%ssql%scFPrstTvfp',
+       \ 'tcl'    : '%stcl%stcl%scfmp',
+       \ 'vera'   : '%svera%svera%scdefgmpPtTvx',
+       \ 'verilog': '%sverilog%sverilog%smcPertwpvf',
+       \ 'vim'    : '%svim%svim%savf',
+       \ 'yacc'   : '%syacc%syacc%sl',
+       \ }
+
+cal map(s:types, 'printf(v:val, "--language-force=", " --", "-types=")')
+
+if executable('jsctags')
+       cal extend(s:types, { 'javascript': { 'args': '-f -', 'bin': 'jsctags' } })
+en
+
+fu! ctrlp#buffertag#opts()
+       for [ke, va] in items(s:opts)
+               let {va[0]} = exists(s:pref.ke) ? {s:pref.ke} : va[1]
+       endfo
+       " Ctags bin
+       if empty(s:bin)
+               for bin in s:bins | if executable(bin)
+                       let s:bin = bin
+                       brea
+               en | endfo
+       el
+               let s:bin = expand(s:bin, 1)
+       en
+       " Types
+       cal extend(s:types, s:usr_types)
+endf
+" Utilities {{{1
+fu! s:validfile(fname, ftype)
+       if ( !empty(a:fname) || !empty(a:ftype) ) && filereadable(a:fname)
+               \ && index(keys(s:types), a:ftype) >= 0 | retu 1 | en
+       retu 0
+endf
+
+fu! s:exectags(cmd)
+       if exists('+ssl')
+               let [ssl, &ssl] = [&ssl, 0]
+       en
+       if &sh =~ 'cmd\.exe'
+               let [sxq, &sxq, shcf, &shcf] = [&sxq, '"', &shcf, '/s /c']
+       en
+       let output = system(a:cmd)
+       if &sh =~ 'cmd\.exe'
+               let [&sxq, &shcf] = [sxq, shcf]
+       en
+       if exists('+ssl')
+               let &ssl = ssl
+       en
+       retu output
+endf
+
+fu! s:exectagsonfile(fname, ftype)
+       let [ags, ft] = ['-f - --sort=no --excmd=pattern --fields=nKs ', a:ftype]
+       if type(s:types[ft]) == 1
+               let ags .= s:types[ft]
+               let bin = s:bin
+       elsei type(s:types[ft]) == 4
+               let ags = s:types[ft]['args']
+               let bin = expand(s:types[ft]['bin'], 1)
+       en
+       if empty(bin) | retu '' | en
+       let cmd = s:esctagscmd(bin, ags, a:fname)
+       if empty(cmd) | retu '' | en
+       let output = s:exectags(cmd)
+       if v:shell_error || output =~ 'Warning: cannot open' | retu '' | en
+       retu output
+endf
+
+fu! s:esctagscmd(bin, args, ...)
+       if exists('+ssl')
+               let [ssl, &ssl] = [&ssl, 0]
+       en
+       let fname = a:0 ? shellescape(a:1) : ''
+       let cmd = shellescape(a:bin).' '.a:args.' '.fname
+       if &sh =~ 'cmd\.exe'
+               let cmd = substitute(cmd, '[&()@^<>|]', '^\0', 'g')
+       en
+       if exists('+ssl')
+               let &ssl = ssl
+       en
+       if has('iconv')
+               let last = s:enc != &enc ? s:enc : !empty($LANG) ? $LANG : &enc
+               let cmd = iconv(cmd, &enc, last)
+       en
+       retu cmd
+endf
+
+fu! s:process(fname, ftype)
+       if !s:validfile(a:fname, a:ftype) | retu [] | endif
+       let ftime = getftime(a:fname)
+       if has_key(g:ctrlp_buftags, a:fname)
+               \ && g:ctrlp_buftags[a:fname]['time'] >= ftime
+               let lines = g:ctrlp_buftags[a:fname]['lines']
+       el
+               let data = s:exectagsonfile(a:fname, a:ftype)
+               let [raw, lines] = [split(data, '\n\+'), []]
+               for line in raw
+                       if line !~# '^!_TAG_' && len(split(line, ';"')) == 2
+                               let parsed_line = s:parseline(line)
+                               if parsed_line != ''
+                                       cal add(lines, parsed_line)
+                               en
+                       en
+               endfo
+               let cache = { a:fname : { 'time': ftime, 'lines': lines } }
+               cal extend(g:ctrlp_buftags, cache)
+       en
+       retu lines
+endf
+
+fu! s:parseline(line)
+       let vals = matchlist(a:line,
+               \ '\v^([^\t]+)\t(.+)\t[?/]\^?(.{-1,})\$?[?/]\;\"\t(.+)\tline(no)?\:(\d+)')
+       if vals == [] | retu '' | en
+       let [bufnr, bufname] = [bufnr('^'.vals[2].'$'), fnamemodify(vals[2], ':p:t')]
+       retu vals[1].'  '.vals[4].'|'.bufnr.':'.bufname.'|'.vals[6].'| '.vals[3]
+endf
+
+fu! s:syntax()
+       if !ctrlp#nosy()
+               cal ctrlp#hicheck('CtrlPTagKind', 'Title')
+               cal ctrlp#hicheck('CtrlPBufName', 'Directory')
+               cal ctrlp#hicheck('CtrlPTabExtra', 'Comment')
+               sy match CtrlPTagKind '\zs[^\t|]\+\ze|\d\+:[^|]\+|\d\+|'
+               sy match CtrlPBufName '|\d\+:\zs[^|]\+\ze|\d\+|'
+               sy match CtrlPTabExtra '\zs\t.*\ze$' contains=CtrlPBufName,CtrlPTagKind
+       en
+endf
+
+fu! s:chknearby(pat)
+       if match(getline('.'), a:pat) < 0
+               let [int, forw, maxl] = [1, 1, line('$')]
+               wh !search(a:pat, 'W'.( forw ? '' : 'b' ))
+                       if !forw
+                               if int > maxl | brea | en
+                               let int += int
+                       en
+                       let forw = !forw
+               endw
+       en
+endf
+" Public {{{1
+fu! ctrlp#buffertag#init(fname)
+       let bufs = exists('s:btmode') && s:btmode
+               \ ? filter(ctrlp#buffers(), 'filereadable(v:val)')
+               \ : [exists('s:bufname') ? s:bufname : a:fname]
+       let lines = []
+       for each in bufs
+               let bname = fnamemodify(each, ':p')
+               let tftype = get(split(getbufvar('^'.bname.'$', '&ft'), '\.'), 0, '')
+               cal extend(lines, s:process(bname, tftype))
+       endfo
+       cal s:syntax()
+       retu lines
+endf
+
+fu! ctrlp#buffertag#accept(mode, str)
+       let vals = matchlist(a:str,
+               \ '\v^[^\t]+\t+[^\t|]+\|(\d+)\:[^\t|]+\|(\d+)\|\s(.+)$')
+       let bufnr = str2nr(get(vals, 1))
+       if bufnr
+               cal ctrlp#acceptfile(a:mode, bufname(bufnr))
+               exe 'norm!' str2nr(get(vals, 2, line('.'))).'G'
+               cal s:chknearby('\V\C'.get(vals, 3, ''))
+               sil! norm! zvzz
+       en
+endf
+
+fu! ctrlp#buffertag#cmd(mode, ...)
+       let s:btmode = a:mode
+       if a:0 && !empty(a:1)
+               let s:bufname = fnamemodify(a:1, ':p')
+       en
+       retu s:id
+endf
+
+fu! ctrlp#buffertag#exit()
+       unl! s:btmode s:bufname
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/changes.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/changes.vim
new file mode 100644 (file)
index 0000000..c391aad
--- /dev/null
@@ -0,0 +1,95 @@
+" =============================================================================
+" File:          autoload/ctrlp/changes.vim
+" Description:   Change list extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_changes') && g:loaded_ctrlp_changes
+       fini
+en
+let g:loaded_ctrlp_changes = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#changes#init(s:bufnr, s:crbufnr)',
+       \ 'accept': 'ctrlp#changes#accept',
+       \ 'lname': 'changes',
+       \ 'sname': 'chs',
+       \ 'exit': 'ctrlp#changes#exit()',
+       \ 'type': 'tabe',
+       \ 'sort': 0,
+       \ 'nolim': 1,
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:changelist(bufnr)
+       sil! exe 'noa hid b' a:bufnr
+       redi => result
+       sil! changes
+       redi END
+       retu map(split(result, "\n")[1:], 'tr(v:val, "  ", " ")')
+endf
+
+fu! s:process(clines, ...)
+       let [clines, evas] = [[], []]
+       for each in a:clines
+               let parts = matchlist(each, '\v^.\s*\d+\s+(\d+)\s+(\d+)\s(.*)$')
+               if !empty(parts)
+                       if parts[3] == '' | let parts[3] = ' ' | en
+                       cal add(clines, parts[3].'      |'.a:1.':'.a:2.'|'.parts[1].':'.parts[2].'|')
+               en
+       endfo
+       retu reverse(filter(clines, 'count(clines, v:val) == 1'))
+endf
+
+fu! s:syntax()
+       if !ctrlp#nosy()
+               cal ctrlp#hicheck('CtrlPBufName', 'Directory')
+               cal ctrlp#hicheck('CtrlPTabExtra', 'Comment')
+               sy match CtrlPBufName '\t|\d\+:\zs[^|]\+\ze|\d\+:\d\+|$'
+               sy match CtrlPTabExtra '\zs\t.*\ze$' contains=CtrlPBufName
+       en
+endf
+" Public {{{1
+fu! ctrlp#changes#init(original_bufnr, bufnr)
+       let bufnr = exists('s:bufnr') ? s:bufnr : a:bufnr
+       let bufs = exists('s:clmode') && s:clmode ? ctrlp#buffers('id') : [bufnr]
+       cal filter(bufs, 'v:val > 0')
+       let [swb, &swb] = [&swb, '']
+       let lines = []
+       for each in bufs
+               let fnamet = fnamemodify(bufname(each), ':t')
+               cal extend(lines, s:process(s:changelist(each), each, fnamet))
+       endfo
+       sil! exe 'noa hid b' a:original_bufnr
+       let &swb = swb
+       cal ctrlp#syntax()
+       cal s:syntax()
+       retu lines
+endf
+
+fu! ctrlp#changes#accept(mode, str)
+       let info = matchlist(a:str, '\t|\(\d\+\):[^|]\+|\(\d\+\):\(\d\+\)|$')
+       let bufnr = str2nr(get(info, 1))
+       if bufnr
+               cal ctrlp#acceptfile(a:mode, bufname(bufnr))
+               cal cursor(get(info, 2), get(info, 3))
+               sil! norm! zvzz
+       en
+endf
+
+fu! ctrlp#changes#cmd(mode, ...)
+       let s:clmode = a:mode
+       if a:0 && !empty(a:1)
+               let s:bufnr = bufnr('^'.fnamemodify(a:1, ':p').'$')
+       en
+       retu s:id
+endf
+
+fu! ctrlp#changes#exit()
+       unl! s:clmode s:bufnr
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/dir.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/dir.vim
new file mode 100644 (file)
index 0000000..2589a0b
--- /dev/null
@@ -0,0 +1,93 @@
+" =============================================================================
+" File:          autoload/ctrlp/dir.vim
+" Description:   Directory extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_dir') && g:loaded_ctrlp_dir
+       fini
+en
+let [g:loaded_ctrlp_dir, g:ctrlp_newdir] = [1, 0]
+
+let s:ars = ['s:maxdepth', 's:maxfiles', 's:compare_lim', 's:glob', 's:caching']
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#dir#init('.join(s:ars, ', ').')',
+       \ 'accept': 'ctrlp#dir#accept',
+       \ 'lname': 'dirs',
+       \ 'sname': 'dir',
+       \ 'type': 'path',
+       \ 'specinput': 1,
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+let s:dircounts = {}
+" Utilities {{{1
+fu! s:globdirs(dirs, depth)
+       let entries = split(globpath(a:dirs, s:glob), "\n")
+       let [dirs, depth] = [ctrlp#dirnfile(entries)[0], a:depth + 1]
+       cal extend(g:ctrlp_alldirs, dirs)
+       let nr = len(g:ctrlp_alldirs)
+       if !empty(dirs) && !s:max(nr, s:maxfiles) && depth <= s:maxdepth
+               sil! cal ctrlp#progress(nr)
+               cal map(dirs, 'ctrlp#utils#fnesc(v:val, "g", ",")')
+               cal s:globdirs(join(dirs, ','), depth)
+       en
+endf
+
+fu! s:max(len, max)
+       retu a:max && a:len > a:max
+endf
+
+fu! s:nocache()
+       retu !s:caching || ( s:caching > 1 && get(s:dircounts, s:cwd) < s:caching )
+endf
+" Public {{{1
+fu! ctrlp#dir#init(...)
+       let s:cwd = getcwd()
+       for each in range(len(s:ars))
+               let {s:ars[each]} = a:{each + 1}
+       endfo
+       let cadir = ctrlp#utils#cachedir().ctrlp#utils#lash().'dir'
+       let cafile = cadir.ctrlp#utils#lash().ctrlp#utils#cachefile('dir')
+       if g:ctrlp_newdir || s:nocache() || !filereadable(cafile)
+               let [s:initcwd, g:ctrlp_alldirs] = [s:cwd, []]
+               cal s:globdirs(ctrlp#utils#fnesc(s:cwd, 'g', ','), 0)
+               cal ctrlp#rmbasedir(g:ctrlp_alldirs)
+               if len(g:ctrlp_alldirs) <= s:compare_lim
+                       cal sort(g:ctrlp_alldirs, 'ctrlp#complen')
+               en
+               cal ctrlp#utils#writecache(g:ctrlp_alldirs, cadir, cafile)
+               let g:ctrlp_newdir = 0
+       el
+               if !( exists('s:initcwd') && s:initcwd == s:cwd )
+                       let s:initcwd = s:cwd
+                       let g:ctrlp_alldirs = ctrlp#utils#readfile(cafile)
+               en
+       en
+       cal extend(s:dircounts, { s:cwd : len(g:ctrlp_alldirs) })
+       retu g:ctrlp_alldirs
+endf
+
+fu! ctrlp#dir#accept(mode, str)
+       let path = a:mode == 'h' ? getcwd() : s:cwd.ctrlp#utils#lash().a:str
+       if a:mode =~ 't\|v\|h'
+               cal ctrlp#exit()
+       en
+       cal ctrlp#setdir(path, a:mode =~ 't\|h' ? 'chd!' : 'lc!')
+       if a:mode == 'e'
+               sil! cal ctrlp#statusline()
+               cal ctrlp#setlines(s:id)
+               cal ctrlp#recordhist()
+               cal ctrlp#prtclear()
+       en
+endf
+
+fu! ctrlp#dir#id()
+       retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/line.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/line.vim
new file mode 100644 (file)
index 0000000..a2e0dde
--- /dev/null
@@ -0,0 +1,62 @@
+" =============================================================================
+" File:          autoload/ctrlp/line.vim
+" Description:   Line extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_line') && g:loaded_ctrlp_line
+       fini
+en
+let g:loaded_ctrlp_line = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#line#init()',
+       \ 'accept': 'ctrlp#line#accept',
+       \ 'lname': 'lines',
+       \ 'sname': 'lns',
+       \ 'type': 'tabe',
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:syntax()
+       if !ctrlp#nosy()
+               cal ctrlp#hicheck('CtrlPBufName', 'Directory')
+               cal ctrlp#hicheck('CtrlPTabExtra', 'Comment')
+               sy match CtrlPBufName '\t|\zs[^|]\+\ze|\d\+:\d\+|$'
+               sy match CtrlPTabExtra '\zs\t.*\ze$' contains=CtrlPBufName
+       en
+endf
+" Public {{{1
+fu! ctrlp#line#init()
+       let [bufs, lines] = [ctrlp#buffers('id'), []]
+       for bufnr in bufs
+               let [lfb, bufn] = [getbufline(bufnr, 1, '$'), bufname(bufnr)]
+               let lfb = lfb == [] ? ctrlp#utils#readfile(fnamemodify(bufn, ':p')) : lfb
+               cal map(lfb, 'tr(v:val, ''      '', '' '')')
+               let [linenr, len_lfb, buft] = [1, len(lfb), fnamemodify(bufn, ':t')]
+               wh linenr <= len_lfb
+                       let lfb[linenr - 1] .= '        |'.buft.'|'.bufnr.':'.linenr.'|'
+                       let linenr += 1
+               endw
+               cal extend(lines, filter(lfb, 'v:val !~ ''^\s*\t|[^|]\+|\d\+:\d\+|$'''))
+       endfo
+       cal s:syntax()
+       retu lines
+endf
+
+fu! ctrlp#line#accept(mode, str)
+       let info = matchlist(a:str, '\t|[^|]\+|\(\d\+\):\(\d\+\)|$')
+       let bufnr = str2nr(get(info, 1))
+       if bufnr
+               cal ctrlp#acceptfile(a:mode, bufname(bufnr), get(info, 2))
+       en
+endf
+
+fu! ctrlp#line#id()
+       retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/mixed.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/mixed.vim
new file mode 100644 (file)
index 0000000..cf01d10
--- /dev/null
@@ -0,0 +1,83 @@
+" =============================================================================
+" File:          autoload/ctrlp/mixed.vim
+" Description:   Mixing Files + MRU + Buffers
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_mixed') && g:loaded_ctrlp_mixed
+       fini
+en
+let [g:loaded_ctrlp_mixed, g:ctrlp_newmix] = [1, 0]
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#mixed#init(s:compare_lim)',
+       \ 'accept': 'ctrlp#acceptfile',
+       \ 'lname': 'fil + mru + buf',
+       \ 'sname': 'mix',
+       \ 'type': 'path',
+       \ 'opmul': 1,
+       \ 'specinput': 1,
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:newcache(cwd)
+       if g:ctrlp_newmix || !has_key(g:ctrlp_allmixes, 'data') | retu 1 | en
+       retu g:ctrlp_allmixes['cwd'] != a:cwd
+               \ || g:ctrlp_allmixes['filtime'] < getftime(ctrlp#utils#cachefile())
+               \ || g:ctrlp_allmixes['mrutime'] < getftime(ctrlp#mrufiles#cachefile())
+               \ || g:ctrlp_allmixes['bufs'] < len(ctrlp#mrufiles#bufs())
+endf
+
+fu! s:getnewmix(cwd, clim)
+       if g:ctrlp_newmix
+               cal ctrlp#mrufiles#refresh('raw')
+               let g:ctrlp_newcache = 1
+       en
+       let g:ctrlp_lines = copy(ctrlp#files())
+       cal ctrlp#progress('Mixing...')
+       let mrufs = copy(ctrlp#mrufiles#list('raw'))
+       if exists('+ssl') && &ssl
+               cal map(mrufs, 'tr(v:val, "\\", "/")')
+       en
+       let bufs = map(ctrlp#buffers('id'), 'fnamemodify(bufname(v:val), ":p")')
+       let mrufs = bufs + filter(mrufs, 'index(bufs, v:val) < 0')
+       if len(mrufs) > len(g:ctrlp_lines)
+               cal filter(mrufs, 'stridx(v:val, a:cwd)')
+       el
+               let cwd_mrufs = filter(copy(mrufs), '!stridx(v:val, a:cwd)')
+               let cwd_mrufs = ctrlp#rmbasedir(cwd_mrufs)
+               for each in cwd_mrufs
+                       let id = index(g:ctrlp_lines, each)
+                       if id >= 0 | cal remove(g:ctrlp_lines, id) | en
+               endfo
+       en
+       cal map(mrufs, 'fnamemodify(v:val, ":.")')
+       let g:ctrlp_lines = len(mrufs) > len(g:ctrlp_lines)
+               \ ? g:ctrlp_lines + mrufs : mrufs + g:ctrlp_lines
+       if len(g:ctrlp_lines) <= a:clim
+               cal sort(g:ctrlp_lines, 'ctrlp#complen')
+       en
+       let g:ctrlp_allmixes = { 'filtime': getftime(ctrlp#utils#cachefile()),
+               \ 'mrutime': getftime(ctrlp#mrufiles#cachefile()), 'cwd': a:cwd,
+               \ 'bufs': len(ctrlp#mrufiles#bufs()), 'data': g:ctrlp_lines }
+endf
+" Public {{{1
+fu! ctrlp#mixed#init(clim)
+       let cwd = getcwd()
+       if s:newcache(cwd)
+               cal s:getnewmix(cwd, a:clim)
+       el
+               let g:ctrlp_lines = g:ctrlp_allmixes['data']
+       en
+       let g:ctrlp_newmix = 0
+       retu g:ctrlp_lines
+endf
+
+fu! ctrlp#mixed#id()
+       retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/mrufiles.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/mrufiles.vim
new file mode 100644 (file)
index 0000000..10d7813
--- /dev/null
@@ -0,0 +1,129 @@
+" =============================================================================
+" File:          autoload/ctrlp/mrufiles.vim
+" Description:   Most Recently Used Files extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Static variables {{{1
+let [s:mrbs, s:mrufs] = [[], []]
+
+fu! ctrlp#mrufiles#opts()
+       let [pref, opts] = ['g:ctrlp_mruf_', {
+               \ 'max': ['s:max', 250],
+               \ 'include': ['s:in', ''],
+               \ 'exclude': ['s:ex', ''],
+               \ 'case_sensitive': ['s:cseno', 1],
+               \ 'relative': ['s:re', 0],
+               \ }]
+       for [ke, va] in items(opts)
+               let [{va[0]}, {pref.ke}] = [pref.ke, exists(pref.ke) ? {pref.ke} : va[1]]
+       endfo
+endf
+cal ctrlp#mrufiles#opts()
+" Utilities {{{1
+fu! s:excl(fn)
+       retu !empty({s:ex}) && a:fn =~# {s:ex}
+endf
+
+fu! s:mergelists()
+       let diskmrufs = ctrlp#utils#readfile(ctrlp#mrufiles#cachefile())
+       cal filter(diskmrufs, 'index(s:mrufs, v:val) < 0')
+       let mrufs = s:mrufs + diskmrufs
+       retu s:chop(mrufs)
+endf
+
+fu! s:chop(mrufs)
+       if len(a:mrufs) > {s:max} | cal remove(a:mrufs, {s:max}, -1) | en
+       retu a:mrufs
+endf
+
+fu! s:reformat(mrufs)
+       if {s:re}
+               let cwd = exists('+ssl') ? tr(getcwd(), '/', '\') : getcwd()
+               cal filter(a:mrufs, '!stridx(v:val, cwd)')
+       en
+       retu map(a:mrufs, 'fnamemodify(v:val, ":.")')
+endf
+
+fu! s:record(bufnr)
+       if s:locked | retu | en
+       let bufnr = a:bufnr + 0
+       let bufname = bufname(bufnr)
+       if bufnr > 0 && !empty(bufname)
+               cal filter(s:mrbs, 'v:val != bufnr')
+               cal insert(s:mrbs, bufnr)
+               cal s:addtomrufs(bufname)
+       en
+endf
+
+fu! s:addtomrufs(fname)
+       let fn = fnamemodify(a:fname, ':p')
+       let fn = exists('+ssl') ? tr(fn, '/', '\') : fn
+       if ( !empty({s:in}) && fn !~# {s:in} ) || ( !empty({s:ex}) && fn =~# {s:ex} )
+               \ || !empty(getbufvar('^'.fn.'$', '&bt')) || !filereadable(fn) | retu
+       en
+       cal filter(s:mrufs, 'v:val !='.( {s:cseno} ? '#' : '?' ).' fn')
+       cal insert(s:mrufs, fn)
+endf
+
+fu! s:savetofile(mrufs)
+       cal ctrlp#utils#writecache(a:mrufs, s:cadir, s:cafile)
+endf
+" Public {{{1
+fu! ctrlp#mrufiles#refresh(...)
+       let s:mrufs = s:mergelists()
+       cal filter(s:mrufs, '!empty(ctrlp#utils#glob(v:val, 1)) && !s:excl(v:val)')
+       if exists('+ssl')
+               cal map(s:mrufs, 'tr(v:val, "/", "\\")')
+               cal filter(s:mrufs, 'count(s:mrufs, v:val) == 1')
+       en
+       cal s:savetofile(s:mrufs)
+       retu a:0 && a:1 == 'raw' ? [] : s:reformat(copy(s:mrufs))
+endf
+
+fu! ctrlp#mrufiles#remove(files)
+       let s:mrufs = []
+       if a:files != []
+               let s:mrufs = s:mergelists()
+               cal filter(s:mrufs, 'index(a:files, v:val, 0, '.(!{s:cseno}).') < 0')
+       en
+       cal s:savetofile(s:mrufs)
+       retu s:reformat(copy(s:mrufs))
+endf
+
+fu! ctrlp#mrufiles#add(fn)
+       if !empty(a:fn)
+               cal s:addtomrufs(a:fn)
+       en
+endf
+
+fu! ctrlp#mrufiles#list(...)
+       retu a:0 ? a:1 == 'raw' ? s:mergelists() : 0 : s:reformat(s:mergelists())
+endf
+
+fu! ctrlp#mrufiles#bufs()
+       retu s:mrbs
+endf
+
+fu! ctrlp#mrufiles#cachefile()
+       if !exists('s:cadir') || !exists('s:cafile')
+               let s:cadir = ctrlp#utils#cachedir().ctrlp#utils#lash().'mru'
+               let s:cafile = s:cadir.ctrlp#utils#lash().'cache.txt'
+       en
+       retu s:cafile
+endf
+
+fu! ctrlp#mrufiles#init()
+       if !has('autocmd') | retu | en
+       let s:locked = 0
+       aug CtrlPMRUF
+               au!
+               au BufAdd,BufEnter,BufLeave,BufUnload * cal s:record(expand('<abuf>', 1))
+               au QuickFixCmdPre  *vimgrep* let s:locked = 1
+               au QuickFixCmdPost *vimgrep* let s:locked = 0
+               au VimLeavePre * cal s:savetofile(s:mergelists())
+       aug END
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/quickfix.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/quickfix.vim
new file mode 100644 (file)
index 0000000..03ab921
--- /dev/null
@@ -0,0 +1,59 @@
+" =============================================================================
+" File:          autoload/ctrlp/quickfix.vim
+" Description:   Quickfix extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_quickfix') && g:loaded_ctrlp_quickfix
+       fini
+en
+let g:loaded_ctrlp_quickfix = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#quickfix#init()',
+       \ 'accept': 'ctrlp#quickfix#accept',
+       \ 'lname': 'quickfix',
+       \ 'sname': 'qfx',
+       \ 'type': 'line',
+       \ 'sort': 0,
+       \ 'nolim': 1,
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+fu! s:lineout(dict)
+       retu printf('%s|%d:%d| %s', bufname(a:dict['bufnr']), a:dict['lnum'],
+               \ a:dict['col'], matchstr(a:dict['text'], '\s*\zs.*\S'))
+endf
+" Utilities {{{1
+fu! s:syntax()
+       if !ctrlp#nosy()
+               cal ctrlp#hicheck('CtrlPqfLineCol', 'Search')
+               sy match CtrlPqfLineCol '|\zs\d\+:\d\+\ze|'
+       en
+endf
+" Public {{{1
+fu! ctrlp#quickfix#init()
+       cal s:syntax()
+       retu map(getqflist(), 's:lineout(v:val)')
+endf
+
+fu! ctrlp#quickfix#accept(mode, str)
+       let vals = matchlist(a:str, '^\([^|]\+\ze\)|\(\d\+\):\(\d\+\)|')
+       if vals == [] || vals[1] == '' | retu | en
+       cal ctrlp#acceptfile(a:mode, vals[1])
+       let cur_pos = getpos('.')[1:2]
+       if cur_pos != [1, 1] && cur_pos != map(vals[2:3], 'str2nr(v:val)')
+               mark '
+       en
+       cal cursor(vals[2], vals[3])
+       sil! norm! zvzz
+endf
+
+fu! ctrlp#quickfix#id()
+       retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/rtscript.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/rtscript.vim
new file mode 100644 (file)
index 0000000..eed21c6
--- /dev/null
@@ -0,0 +1,59 @@
+" =============================================================================
+" File:          autoload/ctrlp/rtscript.vim
+" Description:   Runtime scripts extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_rtscript') && g:loaded_ctrlp_rtscript
+       fini
+en
+let [g:loaded_ctrlp_rtscript, g:ctrlp_newrts] = [1, 0]
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#rtscript#init(s:caching)',
+       \ 'accept': 'ctrlp#acceptfile',
+       \ 'lname': 'runtime scripts',
+       \ 'sname': 'rts',
+       \ 'type': 'path',
+       \ 'opmul': 1,
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+let s:filecounts = {}
+" Utilities {{{1
+fu! s:nocache()
+       retu g:ctrlp_newrts ||
+               \ !s:caching || ( s:caching > 1 && get(s:filecounts, s:cwd) < s:caching )
+endf
+" Public {{{1
+fu! ctrlp#rtscript#init(caching)
+       let [s:caching, s:cwd] = [a:caching, getcwd()]
+       if s:nocache() ||
+               \ !( exists('g:ctrlp_rtscache') && g:ctrlp_rtscache[0] == &rtp )
+               sil! cal ctrlp#progress('Indexing...')
+               let entries = split(globpath(ctrlp#utils#fnesc(&rtp, 'g'), '**/*.*'), "\n")
+               cal filter(entries, 'count(entries, v:val) == 1')
+               let [entries, echoed] = [ctrlp#dirnfile(entries)[1], 1]
+       el
+               let [entries, results] = g:ctrlp_rtscache[2:3]
+       en
+       if s:nocache() ||
+               \ !( exists('g:ctrlp_rtscache') && g:ctrlp_rtscache[:1] == [&rtp, s:cwd] )
+               if !exists('echoed')
+                       sil! cal ctrlp#progress('Processing...')
+               en
+               let results = map(copy(entries), 'fnamemodify(v:val, '':.'')')
+       en
+       let [g:ctrlp_rtscache, g:ctrlp_newrts] = [[&rtp, s:cwd, entries, results], 0]
+       cal extend(s:filecounts, { s:cwd : len(results) })
+       retu results
+endf
+
+fu! ctrlp#rtscript#id()
+       retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/tag.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/tag.vim
new file mode 100644 (file)
index 0000000..83921a5
--- /dev/null
@@ -0,0 +1,125 @@
+" =============================================================================
+" File:          autoload/ctrlp/tag.vim
+" Description:   Tag file extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_tag') && g:loaded_ctrlp_tag
+       fini
+en
+let g:loaded_ctrlp_tag = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#tag#init()',
+       \ 'accept': 'ctrlp#tag#accept',
+       \ 'lname': 'tags',
+       \ 'sname': 'tag',
+       \ 'enter': 'ctrlp#tag#enter()',
+       \ 'type': 'tabs',
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:findcount(str)
+       let [tg, fname] = split(a:str, '\t\+\ze[^\t]\+$')
+       let tgs = taglist('^'.tg.'$')
+       if len(tgs) < 2
+               retu [1, 1]
+       en
+       let bname = fnamemodify(bufname('%'), ':p')
+       let fname = expand(fnamemodify(simplify(fname), ':s?^[.\/]\+??:p:.'), 1)
+       let [fnd, ct, pos, idx] = [0, 0, 0, 0]
+       wh idx < len(tgs)
+               if bname == fnamemodify(tgs[idx]["filename"], ':p')
+                       cal insert(tgs, remove(tgs, idx))
+                       brea
+               en
+               let idx += 1
+       endw
+       for each in tgs
+               let ct += 1
+               let fulname = fnamemodify(each["filename"], ':p')
+               if stridx(fulname, fname) >= 0
+                       \ && strlen(fname) + stridx(fulname, fname) == strlen(fulname)
+                       let fnd += 1
+                       let pos = ct
+               en
+               if fnd > 1 | brea | en
+       endfo
+       retu [fnd, pos]
+endf
+
+fu! s:filter(tags)
+       let nr = 0
+       wh 0 < 1
+               if a:tags == [] | brea | en
+               if a:tags[nr] =~ '^!' && a:tags[nr] !~# '^!_TAG_'
+                       let nr += 1
+                       con
+               en
+               if a:tags[nr] =~# '^!_TAG_' && len(a:tags) > nr
+                       cal remove(a:tags, nr)
+               el
+                       brea
+               en
+       endw
+       retu a:tags
+endf
+
+fu! s:syntax()
+       if !ctrlp#nosy()
+               cal ctrlp#hicheck('CtrlPTabExtra', 'Comment')
+               sy match CtrlPTabExtra '\zs\t.*\ze$'
+       en
+endf
+" Public {{{1
+fu! ctrlp#tag#init()
+       if empty(s:tagfiles) | retu [] | en
+       let g:ctrlp_alltags = []
+       let tagfiles = sort(filter(s:tagfiles, 'count(s:tagfiles, v:val) == 1'))
+       for each in tagfiles
+               let alltags = s:filter(ctrlp#utils#readfile(each))
+               cal extend(g:ctrlp_alltags, alltags)
+       endfo
+       cal s:syntax()
+       retu g:ctrlp_alltags
+endf
+
+fu! ctrlp#tag#accept(mode, str)
+       cal ctrlp#exit()
+       let str = matchstr(a:str, '^[^\t]\+\t\+[^\t]\+\ze\t')
+       let [tg, fnd] = [split(str, '^[^\t]\+\zs\t')[0], s:findcount(str)]
+       let cmds = {
+               \ 't': ['tab sp', 'tab stj'],
+               \ 'h': ['sp', 'stj'],
+               \ 'v': ['vs', 'vert stj'],
+               \ 'e': ['', 'tj'],
+               \ }
+       let cmd = fnd[0] == 1 ? cmds[a:mode][0] : cmds[a:mode][1]
+       let cmd = a:mode == 'e' && ctrlp#modfilecond(!&aw)
+               \ ? ( cmd == 'tj' ? 'stj' : 'sp' ) : cmd
+       let cmd = a:mode == 't' ? ctrlp#tabcount().cmd : cmd
+       if fnd[0] == 1
+               if cmd != ''
+                       exe cmd
+               en
+               exe fnd[1].'ta' tg
+       el
+               exe cmd tg
+       en
+       cal ctrlp#setlcdir()
+endf
+
+fu! ctrlp#tag#id()
+       retu s:id
+endf
+
+fu! ctrlp#tag#enter()
+       let tfs = tagfiles()
+       let s:tagfiles = tfs != [] ? filter(map(tfs, 'fnamemodify(v:val, ":p")'),
+               \ 'filereadable(v:val)') : []
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/undo.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/undo.vim
new file mode 100644 (file)
index 0000000..dee705e
--- /dev/null
@@ -0,0 +1,154 @@
+" =============================================================================
+" File:          autoload/ctrlp/undo.vim
+" Description:   Undo extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if ( exists('g:loaded_ctrlp_undo') && g:loaded_ctrlp_undo )
+       fini
+en
+let g:loaded_ctrlp_undo = 1
+
+cal add(g:ctrlp_ext_vars, {
+       \ 'init': 'ctrlp#undo#init()',
+       \ 'accept': 'ctrlp#undo#accept',
+       \ 'lname': 'undo',
+       \ 'sname': 'udo',
+       \ 'enter': 'ctrlp#undo#enter()',
+       \ 'exit': 'ctrlp#undo#exit()',
+       \ 'type': 'line',
+       \ 'sort': 0,
+       \ 'nolim': 1,
+       \ })
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+let s:text = map(['second', 'seconds', 'minutes', 'hours', 'days', 'weeks',
+       \ 'months', 'years'], '" ".v:val." ago"')
+" Utilities {{{1
+fu! s:getundo()
+       if exists('*undotree')
+               \ && ( v:version > 703 || ( v:version == 703 && has('patch005') ) )
+               retu [1, undotree()]
+       el
+               redi => result
+               sil! undol
+               redi END
+               retu [0, split(result, "\n")[1:]]
+       en
+endf
+
+fu! s:flatten(tree, cur)
+       let flatdict = {}
+       for each in a:tree
+               let saved = has_key(each, 'save') ? 'saved' : ''
+               let current = each['seq'] == a:cur ? 'current' : ''
+               cal extend(flatdict, { each['seq'] : [each['time'], saved, current] })
+               if has_key(each, 'alt')
+                       cal extend(flatdict, s:flatten(each['alt'], a:cur))
+               en
+       endfo
+       retu flatdict
+endf
+
+fu! s:elapsed(nr)
+       let [text, time] = [s:text, localtime() - a:nr]
+       let mins = time / 60
+       let hrs  = time / 3600
+       let days = time / 86400
+       let wks  = time / 604800
+       let mons = time / 2592000
+       let yrs  = time / 31536000
+       if yrs > 1
+               retu yrs.text[7]
+       elsei mons > 1
+               retu mons.text[6]
+       elsei wks > 1
+               retu wks.text[5]
+       elsei days > 1
+               retu days.text[4]
+       elsei hrs > 1
+               retu hrs.text[3]
+       elsei mins > 1
+               retu mins.text[2]
+       elsei time == 1
+               retu time.text[0]
+       elsei time < 120
+               retu time.text[1]
+       en
+endf
+
+fu! s:syntax()
+       if ctrlp#nosy() | retu | en
+       for [ke, va] in items({'T': 'Directory', 'Br': 'Comment', 'Nr': 'String',
+               \ 'Sv': 'Comment', 'Po': 'Title'})
+               cal ctrlp#hicheck('CtrlPUndo'.ke, va)
+       endfo
+       sy match CtrlPUndoT '\v\d+ \zs[^ ]+\ze|\d+:\d+:\d+'
+       sy match CtrlPUndoBr '\[\|\]'
+       sy match CtrlPUndoNr '\[\d\+\]' contains=CtrlPUndoBr
+       sy match CtrlPUndoSv 'saved'
+       sy match CtrlPUndoPo 'current'
+endf
+
+fu! s:dict2list(dict)
+       for ke in keys(a:dict)
+               let a:dict[ke][0] = s:elapsed(a:dict[ke][0])
+       endfo
+       retu map(keys(a:dict), 'eval(''[v:val, a:dict[v:val]]'')')
+endf
+
+fu! s:compval(...)
+       retu a:2[0] - a:1[0]
+endf
+
+fu! s:format(...)
+       let saved = !empty(a:1[1][1]) ? ' '.a:1[1][1] : ''
+       let current = !empty(a:1[1][2]) ? ' '.a:1[1][2] : ''
+       retu a:1[1][0].' ['.a:1[0].']'.saved.current
+endf
+
+fu! s:formatul(...)
+       let parts = matchlist(a:1,
+               \ '\v^\s+(\d+)\s+\d+\s+([^ ]+\s?[^ ]+|\d+\s\w+\s\w+)(\s*\d*)$')
+       retu parts == [] ? '----'
+               \ : parts[2].' ['.parts[1].']'.( parts[3] != '' ? ' saved' : '' )
+endf
+" Public {{{1
+fu! ctrlp#undo#init()
+       let entries = s:undos[0] ? s:undos[1]['entries'] : s:undos[1]
+       if empty(entries) | retu [] | en
+       if !exists('s:lines')
+               if s:undos[0]
+                       let entries = s:dict2list(s:flatten(entries, s:undos[1]['seq_cur']))
+                       let s:lines = map(sort(entries, 's:compval'), 's:format(v:val)')
+               el
+                       let s:lines = map(reverse(entries), 's:formatul(v:val)')
+               en
+       en
+       cal s:syntax()
+       retu s:lines
+endf
+
+fu! ctrlp#undo#accept(mode, str)
+       let undon = matchstr(a:str, '\[\zs\d\+\ze\]')
+       if empty(undon) | retu | en
+       cal ctrlp#exit()
+       exe 'u' undon
+endf
+
+fu! ctrlp#undo#id()
+       retu s:id
+endf
+
+fu! ctrlp#undo#enter()
+       let s:undos = s:getundo()
+endf
+
+fu! ctrlp#undo#exit()
+       unl! s:lines
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/utils.vim b/vim/vimfiles/bundle/ctrlp/autoload/ctrlp/utils.vim
new file mode 100644 (file)
index 0000000..7a74b7f
--- /dev/null
@@ -0,0 +1,120 @@
+" =============================================================================
+" File:          autoload/ctrlp/utils.vim
+" Description:   Utilities
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Static variables {{{1
+fu! ctrlp#utils#lash()
+       retu &ssl || !exists('+ssl') ? '/' : '\'
+endf
+
+fu! s:lash(...)
+       retu ( a:0 ? a:1 : getcwd() ) !~ '[\/]$' ? s:lash : ''
+endf
+
+fu! ctrlp#utils#opts()
+       let s:lash = ctrlp#utils#lash()
+       let usrhome = $HOME.s:lash($HOME)
+       let cahome = exists('$XDG_CACHE_HOME') ? $XDG_CACHE_HOME : usrhome.'.cache'
+       let cadir = isdirectory(usrhome.'.ctrlp_cache')
+               \ ? usrhome.'.ctrlp_cache' : cahome.s:lash(cahome).'ctrlp'
+       if exists('g:ctrlp_cache_dir')
+               let cadir = expand(g:ctrlp_cache_dir, 1)
+               if isdirectory(cadir.s:lash(cadir).'.ctrlp_cache')
+                       let cadir = cadir.s:lash(cadir).'.ctrlp_cache'
+               en
+       en
+       let s:cache_dir = cadir
+endf
+cal ctrlp#utils#opts()
+
+let s:wig_cond = v:version > 702 || ( v:version == 702 && has('patch051') )
+" Files and Directories {{{1
+fu! ctrlp#utils#cachedir()
+       retu s:cache_dir
+endf
+
+fu! ctrlp#utils#cachefile(...)
+       let [tail, dir] = [a:0 == 1 ? '.'.a:1 : '', a:0 == 2 ? a:1 : getcwd()]
+       let cache_file = substitute(dir, '\([\/]\|^\a\zs:\)', '%', 'g').tail.'.txt'
+       retu a:0 == 1 ? cache_file : s:cache_dir.s:lash(s:cache_dir).cache_file
+endf
+
+fu! ctrlp#utils#readfile(file)
+       if filereadable(a:file)
+               let data = readfile(a:file)
+               if empty(data) || type(data) != 3
+                       unl data
+                       let data = []
+               en
+               retu data
+       en
+       retu []
+endf
+
+fu! ctrlp#utils#mkdir(dir)
+       if exists('*mkdir') && !isdirectory(a:dir)
+               sil! cal mkdir(a:dir, 'p')
+       en
+       retu a:dir
+endf
+
+fu! ctrlp#utils#writecache(lines, ...)
+       if isdirectory(ctrlp#utils#mkdir(a:0 ? a:1 : s:cache_dir))
+               sil! cal writefile(a:lines, a:0 >= 2 ? a:2 : ctrlp#utils#cachefile())
+       en
+endf
+
+fu! ctrlp#utils#glob(...)
+       let path = ctrlp#utils#fnesc(a:1, 'g')
+       retu s:wig_cond ? glob(path, a:2) : glob(path)
+endf
+
+fu! ctrlp#utils#globpath(...)
+       retu call('globpath', s:wig_cond ? a:000 : a:000[:1])
+endf
+
+fu! ctrlp#utils#fnesc(path, type, ...)
+       if exists('*fnameescape')
+               if exists('+ssl')
+                       if a:type == 'c'
+                               let path = escape(a:path, '%#')
+                       elsei a:type == 'f'
+                               let path = fnameescape(a:path)
+                       elsei a:type == 'g'
+                               let path = escape(a:path, '?*')
+                       en
+                       let path = substitute(path, '[', '[[]', 'g')
+               el
+                       let path = fnameescape(a:path)
+               en
+       el
+               if exists('+ssl')
+                       if a:type == 'c'
+                               let path = escape(a:path, '%#')
+                       elsei a:type == 'f'
+                               let path = escape(a:path, " \t\n%#*?|<\"")
+                       elsei a:type == 'g'
+                               let path = escape(a:path, '?*')
+                       en
+                       let path = substitute(path, '[', '[[]', 'g')
+               el
+                       let path = escape(a:path, " \t\n*?[{`$\\%#'\"|!<")
+               en
+       en
+       retu a:0 ? escape(path, a:1) : path
+endf
+
+fu! ctrlp#utils#dircompl(...)
+       let [hsl, str] = [match(a:1, '[\/]'), '']
+       let par = substitute(a:1, '[^\/]*$', '', '')
+       let path = !hsl ? par : hsl > 0 ? getcwd().s:lash().par : getcwd()
+       for dir in split(globpath(ctrlp#utils#fnesc(path, 'g', ','), '*/'), '\n')
+               let str .= par.split(dir, '[\/]')[-1]."\n"
+       endfo
+       retu str
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/doc/ctrlp.txt b/vim/vimfiles/bundle/ctrlp/doc/ctrlp.txt
new file mode 100644 (file)
index 0000000..464a6ef
--- /dev/null
@@ -0,0 +1,1395 @@
+*ctrlp.txt*       Fuzzy file, buffer, mru, tag, ... finder. v1.78
+*CtrlP* *ControlP* *'ctrlp'* *'ctrl-p'*
+===============================================================================
+#                                                                             #
+#          :::::::: ::::::::::: :::::::::  :::             :::::::::          #
+#         :+:    :+:    :+:     :+:    :+: :+:             :+:    :+:         #
+#         +:+           +:+     +:+    +:+ +:+             +:+    +:+         #
+#         +#+           +#+     +#++:++#:  +#+             +#++:++#+          #
+#         +#+           +#+     +#+    +#+ +#+             +#+                #
+#         #+#    #+#    #+#     #+#    #+# #+#             #+#                #
+#          ########     ###     ###    ### ##########      ###                #
+#                                                                             #
+===============================================================================
+CONTENTS                                                       *ctrlp-contents*
+
+    1. Intro........................................|ctrlp-intro|
+    2. Options......................................|ctrlp-options|
+    3. Commands.....................................|ctrlp-commands|
+    4. Mappings.....................................|ctrlp-mappings|
+    5. Input Formats................................|ctrlp-input-formats|
+    6. Extensions...................................|ctrlp-extensions|
+
+===============================================================================
+INTRO                                                             *ctrlp-intro*
+
+Full path fuzzy file, buffer, mru, tag, ... finder with an intuitive interface.
+Written in pure Vimscript for MacVim, gVim and Vim version 7.0+. Has full
+support for Vim's |regexp| as search pattern, built-in MRU files monitoring,
+project's root finder, and more.
+
+To enable optional extensions (tag, dir, rtscript...), see |ctrlp-extensions|.
+
+===============================================================================
+OPTIONS                                                         *ctrlp-options*
+
+Overview:~
+
+  |loaded_ctrlp|................Disable the plugin.
+  |ctrlp_map|...................Default mapping.
+  |ctrlp_cmd|...................Default command used for the default mapping.
+  |ctrlp_by_filename|...........Default to filename mode or not.
+  |ctrlp_regexp|................Default to regexp mode or not.
+  |ctrlp_match_window_bottom|...Where to show the match window.
+  |ctrlp_match_window_reversed|.Sort order in the match window.
+  |ctrlp_max_height|............Max height of the match window.
+  |ctrlp_switch_buffer|.........Jump to an open buffer if already opened.
+  |ctrlp_reuse_window|..........Reuse special windows (help, quickfix, etc).
+  |ctrlp_tabpage_position|......Where to put the new tab page.
+  |ctrlp_working_path_mode|.....How to set CtrlP's local working directory.
+  |ctrlp_root_markers|..........Additional, high priority root markers.
+  |ctrlp_use_caching|...........Use per-session caching or not.
+  |ctrlp_clear_cache_on_exit|...Keep cache after exiting Vim or not.
+  |ctrlp_cache_dir|.............Location of the cache directory.
+  |ctrlp_show_hidden|...........Ignore dotfiles and dotdirs or not.
+  |ctrlp_custom_ignore|.........Hide stuff when using |globpath()|.
+  |ctrlp_max_files|.............Number of files to scan initially.
+  |ctrlp_max_depth|.............Directory depth to recurse into when scanning.
+  |ctrlp_user_command|..........Use an external scanner.
+  |ctrlp_max_history|...........Number of entries saved in the prompt history.
+  |ctrlp_open_new_file|.........How to open a file created by <c-y>.
+  |ctrlp_open_multiple_files|...How to open files selected by <c-z>.
+  |ctrlp_arg_map|...............Intercept <c-y> and <c-o> or not.
+  |ctrlp_follow_symlinks|.......Follow symbolic links or not.
+  |ctrlp_lazy_update|...........Only update when typing has stopped.
+  |ctrlp_default_input|.........Seed the prompt with an initial string.
+  |ctrlp_abbrev|................Input abbreviations.
+  |ctrlp_key_loop|..............Use input looping for multi-byte input.
+  |ctrlp_use_migemo|............Use Migemo patterns for Japanese filenames.
+  |ctrlp_prompt_mappings|.......Change the mappings inside the prompt.
+
+  MRU mode:
+  |ctrlp_mruf_max|..............Max MRU entries to remember.
+  |ctrlp_mruf_exclude|..........Files that shouldn't be remembered.
+  |ctrlp_mruf_include|..........Files to be remembered.
+  |ctrlp_mruf_relative|.........Show only MRU files in the working directory.
+  |ctrlp_mruf_default_order|....Disable sorting.
+  |ctrlp_mruf_case_sensitive|...MRU files are case sensitive or not.
+
+  Advanced options:
+  |ctrlp_open_func|.............Use custom file opening functions.
+  |ctrlp_status_func|...........Change CtrlP's two statuslines.
+  |ctrlp_buffer_func|...........Call custom functions in the CtrlP buffer.
+  |ctrlp_match_func|............Replace the built-in matching algorithm.
+
+-------------------------------------------------------------------------------
+Detailed descriptions and default values:~
+
+                                                                *'g:ctrlp_map'*
+Use this option to change the mapping to invoke CtrlP in |Normal| mode: >
+  let g:ctrlp_map = '<c-p>'
+<
+
+                                                                *'g:ctrlp_cmd'*
+Set the default opening command to use when pressing the above mapping: >
+  let g:ctrlp_cmd = 'CtrlP'
+<
+
+                                                             *'g:loaded_ctrlp'*
+Use this to disable the plugin completely: >
+  let g:loaded_ctrlp = 1
+<
+
+                                                        *'g:ctrlp_by_filename'*
+Set this to 1 to set searching by filename (as opposed to full path) as the
+default: >
+  let g:ctrlp_by_filename = 0
+<
+Can be toggled on/off by pressing <c-d> inside the prompt.
+
+                                                             *'g:ctrlp_regexp'*
+Set this to 1 to set regexp search as the default: >
+  let g:ctrlp_regexp = 0
+<
+Can be toggled on/off by pressing <c-r> inside the prompt.
+
+                                                *'g:ctrlp_match_window_bottom'*
+Set this to 0 to show the match window at the top of the screen: >
+  let g:ctrlp_match_window_bottom = 1
+<
+
+                                              *'g:ctrlp_match_window_reversed'*
+Change the listing order of the files in the match window. The default setting
+(1) is from bottom to top: >
+  let g:ctrlp_match_window_reversed = 1
+<
+
+                                                         *'g:ctrlp_max_height'*
+Set the maximum height of the match window: >
+  let g:ctrlp_max_height = 10
+<
+
+                                                      *'g:ctrlp_switch_buffer'*
+When opening a file, if it's already open in a window somewhere, CtrlP will try
+to jump to it instead of opening a new instance: >
+  let g:ctrlp_switch_buffer = 'Et'
+<
+  e - jump when <cr> is pressed, but only to windows in the current tab.
+  t - jump when <c-t> is pressed, but only to windows in another tab.
+  v - like "e", but jump when <c-v> is pressed.
+  h - like "e", but jump when <c-x> is pressed.
+  E, T, V, H - like "e", "t", "v", and "h", but jump to windows anywhere.
+  0 or <empty> - disable this feature.
+
+                                                       *'g:ctrlp_reuse_window'*
+When opening a file with <cr>, CtrlP avoids opening it in windows created by
+plugins, help and quickfix. Use this to setup some exceptions: >
+  let g:ctrlp_reuse_window = 'netrw'
+<
+Acceptable values are partial name, filetype or buftype of the special buffers.
+Use regexp to specify the pattern.
+Example: >
+  let g:ctrlp_reuse_window = 'netrw\|help\|quickfix'
+<
+
+                                                   *'g:ctrlp_tabpage_position'*
+Where to put the new tab page when opening one: >
+  let g:ctrlp_tabpage_position = 'ac'
+<
+  a - after.
+  b - before.
+  c - the current tab page.
+  l - the last tab page.
+  f - the first tab page.
+
+                                                  *'g:ctrlp_working_path_mode'*
+When starting up, CtrlP sets its local working directory according to this
+variable: >
+  let g:ctrlp_working_path_mode = 'ra'
+<
+  c - the directory of the current file.
+  a - like "c", but only applies when the current working directory outside of
+      CtrlP isn't a direct ancestor of the directory of the current file.
+  r - the nearest ancestor that contains one of these directories or files:
+      .git .hg .svn .bzr _darcs
+  w - begin finding a root from the current working directory outside of CtrlP
+      instead of from the directory of the current file (default). Only applies
+      when "r" is also present.
+  0 or <empty> - disable this feature.
+
+Note #1: if "a" or "c" is included with "r", use the behavior of "a" or "c" (as
+a fallback) when a root can't be found.
+
+Note #2: you can use a |b:var| to set this option on a per buffer basis.
+
+                                                       *'g:ctrlp_root_markers'*
+Use this to set your own root markers in addition to the default ones (.git,
+.hg, .svn, .bzr, and _darcs). Your markers will take precedence: >
+  let g:ctrlp_root_markers = ['']
+<
+Note: you can use a |b:var| to set this option on a per buffer basis.
+
+                                                        *'g:ctrlp_use_caching'*
+Enable/Disable per-session caching: >
+  let g:ctrlp_use_caching = 1
+<
+  0 - Disable caching.
+  1 - Enable caching.
+  n - When bigger than 1, disable caching and use the number as the limit to
+      enable caching again.
+
+Note: you can quickly purge the cache by pressing <F5> while inside CtrlP.
+
+                                                *'g:ctrlp_clear_cache_on_exit'*
+Set this to 0 to enable cross-session caching by not deleting the cache files
+upon exiting Vim: >
+  let g:ctrlp_clear_cache_on_exit = 1
+<
+
+                                                          *'g:ctrlp_cache_dir'*
+Set the directory to store the cache files: >
+  let g:ctrlp_cache_dir = $HOME.'/.cache/ctrlp'
+<
+
+                                                        *'g:ctrlp_show_hidden'*
+Set this to 1 if you want CtrlP to scan for dotfiles and dotdirs: >
+  let g:ctrlp_show_hidden = 0
+<
+Note: does not apply when a command defined with |g:ctrlp_user_command| is
+being used.
+
+                                                           *'ctrlp-wildignore'*
+You can use Vim's |'wildignore'| to exclude files and directories from the
+results.
+Examples: >
+  " Excluding version control directories
+  set wildignore+=*/.git/*,*/.hg/*,*/.svn/*        " Linux/MacOSX
+  set wildignore+=*\\.git\\*,*\\.hg\\*,*\\.svn\\*  " Windows ('noshellslash')
+<
+Note #1: the `*/` in front of each directory glob is required.
+
+Note #2: |wildignore| influences the result of |expand()|, |globpath()| and
+|glob()| which many plugins use to find stuff on the system (e.g. VCS related
+plugins look for .git/, .hg/,... some other plugins look for external *.exe
+tools on Windows). So be a little mindful of what you put in your |wildignore|.
+
+                                                      *'g:ctrlp_custom_ignore'*
+In addition to |'wildignore'|, use this for files and directories you want only
+CtrlP to not show. Use regexp to specify the patterns: >
+  let g:ctrlp_custom_ignore = ''
+<
+Examples: >
+  let g:ctrlp_custom_ignore = '\v[\/]\.(git|hg|svn)$'
+  let g:ctrlp_custom_ignore = {
+    \ 'dir':  '\v[\/]\.(git|hg|svn)$',
+    \ 'file': '\v\.(exe|so|dll)$',
+    \ 'link': 'SOME_BAD_SYMBOLIC_LINKS',
+    \ }
+  let g:ctrlp_custom_ignore = {
+    \ 'file': '\v(\.cpp|\.h|\.hh|\.cxx)@<!$'
+    \ }
+<
+Note #1: by default, |wildignore| and |g:ctrlp_custom_ignore| only apply when
+|globpath()| is used to scan for files, thus these options do not apply when a
+command defined with |g:ctrlp_user_command| is being used.
+
+Note #2: when changing the option's variable type, remember to |:unlet| it
+first or restart Vim to avoid the "E706: Variable type mismatch" error.
+
+                                                          *'g:ctrlp_max_files'*
+The maximum number of files to scan, set to 0 for no limit: >
+  let g:ctrlp_max_files = 10000
+<
+Note: does not apply when a command defined with |g:ctrlp_user_command| is
+being used.
+
+                                                          *'g:ctrlp_max_depth'*
+The maximum depth of a directory tree to recurse into: >
+  let g:ctrlp_max_depth = 40
+<
+Note: does not apply when a command defined with |g:ctrlp_user_command| is
+being used.
+
+                                                       *'g:ctrlp_user_command'*
+Specify an external tool to use for listing files instead of using Vim's
+|globpath()|. Use %s in place of the target directory: >
+  let g:ctrlp_user_command = ''
+<
+Examples: >
+  let g:ctrlp_user_command = 'find %s -type f'       " MacOSX/Linux
+  let g:ctrlp_user_command = 'dir %s /-n /b /s /a-d' " Windows
+<
+You can also use 'grep', 'findstr' or something else to filter the results.
+Examples: >
+  let g:ctrlp_user_command =
+    \ 'find %s -type f | grep -v -P "\.jpg$|/tmp/"'          " MacOSX/Linux
+  let g:ctrlp_user_command =
+    \ 'dir %s /-n /b /s /a-d | findstr /v /l ".jpg \\tmp\\"' " Windows
+<
+Use a version control listing command when inside a repository, this is faster
+when scanning large projects: >
+  let g:ctrlp_user_command = [root_marker, listing_command, fallback_command]
+  let g:ctrlp_user_command = {
+    \ 'types': {
+      \ 1: [root_marker_1, listing_command_1],
+      \ n: [root_marker_n, listing_command_n],
+      \ },
+    \ 'fallback': fallback_command,
+    \ 'ignore': 0 or 1
+    \ }
+<
+Some examples: >
+  " Single VCS, listing command does not list untracked files:
+  let g:ctrlp_user_command = ['.git', 'cd %s && git ls-files']
+  let g:ctrlp_user_command = ['.hg', 'hg --cwd %s locate -I .']
+
+  " Multiple VCS's:
+  let g:ctrlp_user_command = {
+    \ 'types': {
+      \ 1: ['.git', 'cd %s && git ls-files'],
+      \ 2: ['.hg', 'hg --cwd %s locate -I .'],
+      \ },
+    \ 'fallback': 'find %s -type f'
+    \ }
+
+  " Single VCS, listing command lists untracked files (slower):
+  let g:ctrlp_user_command =
+    \ ['.git', 'cd %s && git ls-files . -co --exclude-standard']
+
+  let g:ctrlp_user_command =
+    \ ['.hg', 'hg --cwd %s status -numac -I . $(hg root)'] " MacOSX/Linux
+
+  let g:ctrlp_user_command = ['.hg', 'for /f "tokens=1" %%a in (''hg root'') '
+    \ . 'do hg --cwd %s status -numac -I . %%a']           " Windows
+<
+Note #1: if the fallback_command is empty or the 'fallback' key is not defined,
+|globpath()| will then be used when scanning outside of a repository.
+
+Note #2: unless the |Dictionary| format is used and 'ignore' is defined and set
+to 1, the |wildignore| and |g:ctrlp_custom_ignore| options do not apply when
+these custom commands are being used. When not present, 'ignore' is set to 0 by
+default to retain the performance advantage of using external commands.
+
+Note #3: when changing the option's variable type, remember to |:unlet| it
+first or restart Vim to avoid the "E706: Variable type mismatch" error.
+
+Note #4: you can use a |b:var| to set this option on a per buffer basis.
+
+                                                        *'g:ctrlp_max_history'*
+The maximum number of input strings you want CtrlP to remember. The default
+value mirrors Vim's global |'history'| option: >
+  let g:ctrlp_max_history = &history
+<
+Set to 0 to disable prompt's history. Browse the history with <c-n> and <c-p>.
+
+                                                      *'g:ctrlp_open_new_file'*
+Use this option to specify how the newly created file is to be opened when
+pressing <c-y>: >
+  let g:ctrlp_open_new_file = 'v'
+<
+  t - in a new tab.
+  h - in a new horizontal split.
+  v - in a new vertical split.
+  r - in the current window.
+
+                                                *'g:ctrlp_open_multiple_files'*
+If non-zero, this will enable opening multiple files with <c-z> and <c-o>: >
+  let g:ctrlp_open_multiple_files = 'v'
+<
+Example: >
+  let g:ctrlp_open_multiple_files = '2vjr'
+<
+For the number:
+  - If given, it'll be used as the maximum number of windows or tabs to create
+    when opening the files (the rest will be opened as hidden buffers).
+  - If not given, <c-o> will open all files, each in a new window or new tab.
+
+For the letters:
+  t - each file in a new tab.
+  h - each file in a new horizontal split.
+  v - each file in a new vertical split.
+  i - all files as hidden buffers.
+  j - after opening, jump to the first opened tab or window.
+  r - open the first file in the current window, then the remaining files in
+      new splits or new tabs depending on which of "h", "v" and "t" is also
+      present.
+
+                                                            *'g:ctrlp_arg_map'*
+When this is set to 1, the <c-o> and <c-y> mappings will accept one extra key
+as an argument to override their default behavior: >
+  let g:ctrlp_arg_map = 0
+<
+Pressing <c-o> or <c-y> will then prompt for a keypress. The key can be:
+  t - open in tab(s)
+  h - open in horizontal split(s)
+  v - open in vertical split(s)
+  i - open as hidden buffers (for <c-o> only)
+  c - clear the marked files (for <c-o> only)
+  r - open in the current window (for <c-y> only)
+  <esc>, <c-c>, <c-u> - cancel and go back to the prompt.
+  <cr> - use the default behavior specified with |g:ctrlp_open_new_file| and
+  |g:ctrlp_open_multiple_files|.
+
+                                                    *'g:ctrlp_follow_symlinks'*
+If non-zero, CtrlP will follow symbolic links when listing files: >
+  let g:ctrlp_follow_symlinks = 0
+<
+  0 - don't follow symbolic links.
+  1 - follow but ignore looped internal symlinks to avoid duplicates.
+  2 - follow all symlinks indiscriminately.
+
+Note: does not apply when a command defined with |g:ctrlp_user_command| is
+being used.
+
+                                                        *'g:ctrlp_lazy_update'*
+Set this to 1 to enable the lazy-update feature: only update the match window
+after typing's been stopped for a certain amount of time: >
+  let g:ctrlp_lazy_update = 0
+<
+If is 1, update after 250ms. If bigger than 1, the number will be used as the
+delay time in milliseconds.
+
+                                                      *'g:ctrlp_default_input'*
+Set this to 1 to enable seeding the prompt with the current file's relative
+path: >
+  let g:ctrlp_default_input = 0
+<
+Instead of 1 or 0, if the value of the option is a string, it'll be used as-is
+as the default input: >
+  let g:ctrlp_default_input = 'anystring'
+<
+
+                                                             *'g:ctrlp_abbrev'*
+Define input abbreviations that can be expanded (either internally or visibly)
+in the prompt: >
+  let g:ctrlp_abbrev = {}
+<
+Examples: >
+  let g:ctrlp_abbrev = {
+    \ 'gmode': 'i',
+    \ 'abbrevs': [
+      \ {
+        \ 'pattern': '^cd b',
+        \ 'expanded': '@cd ~/.vim/bundle',
+        \ 'mode': 'pfrz',
+      \ },
+      \ {
+        \ 'pattern': '\(^@.\+\|\\\@<!:.\+\)\@<! ',
+        \ 'expanded': '.\{-}',
+        \ 'mode': 'pfr',
+      \ },
+      \ {
+        \ 'pattern': '\\\@<!:.\+\zs\\\@<! ',
+        \ 'expanded': '\ ',
+        \ 'mode': 'pfz',
+      \ },
+      \ ]
+    \ }
+<
+The 'pattern' string is regexp matched against the entered input. The expansion
+is as if the 'expanded' string was typed into the prompt.
+
+For 'gmode' (optional):
+  i - expand internally (default).
+  t - insert the expanded results into the prompt as you type.
+  k - insert the expanded results when a non-keyword character is typed. Only
+      applies when "t" is also present.
+
+For 'mode' (of each entry; optional):
+  f - only in filename mode.
+  p - only in full path mode.
+  r - only in regexp mode.
+  z - only in fuzzy mode.
+  n - only when creating a new file with <c-y> (use the expanded string in the
+      new filename).
+  c - only when auto-completing directory names with <tab> (expand the pattern
+      immediately before doing the auto-completion).
+  <empty> or not defined - always enable.
+
+Note: the abbrev entries are evaluated in sequence, so a later entry can be
+evaluated against the expanded result of a previous entry; this includes itself
+when 'gmode' is "t".
+
+                                                           *'g:ctrlp_key_loop'*
+An experimental feature. Set this to 1 to enable input looping for the typing
+of multi-byte characters: >
+  let g:ctrlp_key_loop = 0
+<
+Note #1: when set, this option resets the |g:ctrlp_lazy_update| option.
+
+Note #2: you can toggle this feature inside the prompt with a custom mapping: >
+  let g:ctrlp_prompt_mappings = { 'ToggleKeyLoop()': ['<F3>'] }
+<
+
+                                                         *'g:ctrlp_use_migemo'*
+Set this to 1 to use Migemo Pattern for Japanese filenames. Migemo Search only
+works in regexp mode. To split the pattern, separate words with space: >
+  let g:ctrlp_use_migemo = 0
+<
+
+                                                    *'g:ctrlp_prompt_mappings'*
+Use this to customize the mappings inside CtrlP's prompt to your liking. You
+only need to keep the lines that you've changed the values (inside []): >
+  let g:ctrlp_prompt_mappings = {
+    \ 'PrtBS()':              ['<bs>', '<c-]>'],
+    \ 'PrtDelete()':          ['<del>'],
+    \ 'PrtDeleteWord()':      ['<c-w>'],
+    \ 'PrtClear()':           ['<c-u>'],
+    \ 'PrtSelectMove("j")':   ['<c-j>', '<down>'],
+    \ 'PrtSelectMove("k")':   ['<c-k>', '<up>'],
+    \ 'PrtSelectMove("t")':   ['<Home>', '<kHome>'],
+    \ 'PrtSelectMove("b")':   ['<End>', '<kEnd>'],
+    \ 'PrtSelectMove("u")':   ['<PageUp>', '<kPageUp>'],
+    \ 'PrtSelectMove("d")':   ['<PageDown>', '<kPageDown>'],
+    \ 'PrtHistory(-1)':       ['<c-n>'],
+    \ 'PrtHistory(1)':        ['<c-p>'],
+    \ 'AcceptSelection("e")': ['<cr>', '<2-LeftMouse>'],
+    \ 'AcceptSelection("h")': ['<c-x>', '<c-cr>', '<c-s>'],
+    \ 'AcceptSelection("t")': ['<c-t>'],
+    \ 'AcceptSelection("v")': ['<c-v>', '<RightMouse>'],
+    \ 'ToggleFocus()':        ['<s-tab>'],
+    \ 'ToggleRegex()':        ['<c-r>'],
+    \ 'ToggleByFname()':      ['<c-d>'],
+    \ 'ToggleType(1)':        ['<c-f>', '<c-up>'],
+    \ 'ToggleType(-1)':       ['<c-b>', '<c-down>'],
+    \ 'PrtExpandDir()':       ['<tab>'],
+    \ 'PrtInsert("c")':       ['<MiddleMouse>', '<insert>'],
+    \ 'PrtInsert()':          ['<c-\>'],
+    \ 'PrtCurStart()':        ['<c-a>'],
+    \ 'PrtCurEnd()':          ['<c-e>'],
+    \ 'PrtCurLeft()':         ['<c-h>', '<left>', '<c-^>'],
+    \ 'PrtCurRight()':        ['<c-l>', '<right>'],
+    \ 'PrtClearCache()':      ['<F5>'],
+    \ 'PrtDeleteEnt()':       ['<F7>'],
+    \ 'CreateNewFile()':      ['<c-y>'],
+    \ 'MarkToOpen()':         ['<c-z>'],
+    \ 'OpenMulti()':          ['<c-o>'],
+    \ 'PrtExit()':            ['<esc>', '<c-c>', '<c-g>'],
+    \ }
+<
+Note: if pressing <bs> moves the cursor one character to the left instead of
+deleting a character for you, add this to your |.vimrc| to disable the plugin's
+default <c-h> mapping: >
+  let g:ctrlp_prompt_mappings = { 'PrtCurLeft()': ['<left>', '<c-^>'] }
+<
+
+----------------------------------------
+MRU mode options:~
+
+                                                           *'g:ctrlp_mruf_max'*
+Specify the number of recently opened files you want CtrlP to remember: >
+  let g:ctrlp_mruf_max = 250
+<
+
+                                                       *'g:ctrlp_mruf_exclude'*
+Files you don't want CtrlP to remember. Use regexp to specify the patterns: >
+  let g:ctrlp_mruf_exclude = ''
+<
+Examples: >
+  let g:ctrlp_mruf_exclude = '/tmp/.*\|/temp/.*' " MacOSX/Linux
+  let g:ctrlp_mruf_exclude = '^C:\\dev\\tmp\\.*' " Windows
+<
+
+                                                       *'g:ctrlp_mruf_include'*
+And if you want CtrlP to only remember some files, specify them here: >
+  let g:ctrlp_mruf_include = ''
+<
+Example: >
+  let g:ctrlp_mruf_include = '\.py$\|\.rb$'
+<
+
+                                                      *'g:ctrlp_mruf_relative'*
+Set this to 1 to show only MRU files in the current working directory: >
+  let g:ctrlp_mruf_relative = 0
+<
+
+                                                 *'g:ctrlp_mruf_default_order'*
+Set this to 1 to disable sorting when searching in MRU mode: >
+  let g:ctrlp_mruf_default_order = 0
+<
+
+                                                *'g:ctrlp_mruf_case_sensitive'*
+Match this with your file system case-sensitivity setting to avoid duplicate
+MRU entries: >
+  let g:ctrlp_mruf_case_sensitive = 1
+<
+
+----------------------------------------
+Advanced options:~
+
+                                                          *'g:ctrlp_open_func'*
+Define a custom function to open the selected file: >
+  let g:ctrlp_open_func = {}
+<
+Example: >
+  let g:ctrlp_open_func = {
+    \ 'files'     : 'Function_Name_1',
+    \ 'buffers'   : 'Function_Name_2',
+    \ 'mru files' : 'Function_Name_3',
+    \ }
+<
+Structure of the functions: >
+  function! Function_Name(action, line)
+    " Arguments:
+    " |
+    " +- a:action : The opening action:
+    " |             + 'e' : user pressed <cr>  (default)
+    " |             + 'h' : user pressed <c-x> (default)
+    " |             + 'v' : user pressed <c-v> (default)
+    " |             + 't' : user pressed <c-t> (default)
+    " |             + 'x' : user used the <c-o> console dialog (default) and
+    " |                     chose "e[x]ternal".
+    " |
+    " +- a:line   : The selected line.
+
+  endfunction
+<
+Note: does not apply when opening multiple files with <c-z> and <c-o>.
+
+Example: open HTML files in the default web browser when <c-t> is pressed and
+in Vim otherwise >
+  function! HTMLOpenFunc(action, line)
+    if a:action =~ '^[tx]$' && fnamemodify(a:line, ':e') =~? '^html\?$'
+
+      " Get the filename
+      let filename = fnameescape(fnamemodify(a:line, ':p'))
+
+      " Close CtrlP
+      call ctrlp#exit()
+
+      " Open the file
+      silent! execute '!xdg-open' filename
+
+    elseif a:action == 'x' && fnamemodify(a:line, ':e') !~? '^html\?$'
+
+      " Not a HTML file, simulate pressing <c-o> again and wait for new input
+      call feedkeys("\<c-o>")
+
+    else
+
+      " Use CtrlP's default file opening function
+      call call('ctrlp#acceptfile', [a:action, a:line])
+
+    endif
+  endfunction
+
+  let g:ctrlp_open_func = { 'files': 'HTMLOpenFunc' }
+<
+
+                                                        *'g:ctrlp_status_func'*
+Use this to customize the statuslines for the CtrlP window: >
+  let g:ctrlp_status_func = {}
+<
+Example: >
+  let g:ctrlp_status_func = {
+    \ 'main': 'Function_Name_1',
+    \ 'prog': 'Function_Name_2',
+    \ }
+<
+Structure of the functions: >
+  " Main statusline
+  function! Function_Name_1(focus, byfname, regex, prev, item, next, marked)
+    " Arguments:
+    " |
+    " +- a:focus   : The focus of the prompt: "prt" or "win".
+    " |
+    " +- a:byfname : In filename mode or in full path mode: "file" or "path".
+    " |
+    " +- a:regex   : In regex mode: 1 or 0.
+    " |
+    " +- a:prev    : The previous search mode.
+    " |
+    " +- a:item    : The current search mode.
+    " |
+    " +- a:next    : The next search mode.
+    " |
+    " +- a:marked  : The number of marked files, or a comma separated list of
+    "                the marked filenames.
+
+    return full_statusline
+  endfunction
+
+  " Progress statusline
+  function! Function_Name_2(str)
+    " a:str : Either the number of files scanned so far, or a string indicating
+    "         the current directory is being scanned with a user_command.
+
+    return full_statusline
+  endfunction
+<
+See https://gist.github.com/1610859 for a working example.
+
+                                                        *'g:ctrlp_buffer_func'*
+Specify the functions that will be called after entering and before exiting the
+CtrlP buffer: >
+  let g:ctrlp_buffer_func = {}
+<
+Example: >
+  let g:ctrlp_buffer_func = {
+    \ 'enter': 'Function_Name_1',
+    \ 'exit':  'Function_Name_2',
+    \ }
+<
+
+                                                         *'g:ctrlp_match_func'*
+Set an external fuzzy matching function for CtrlP to use: >
+  let g:ctrlp_match_func = {}
+<
+Example: >
+  let g:ctrlp_match_func = { 'match': 'Function_Name' }
+<
+Structure of the function: >
+  function! Function_Name(items, str, limit, mmode, ispath, crfile, regex)
+    " Arguments:
+    " |
+    " +- a:items  : The full list of items to search in.
+    " |
+    " +- a:str    : The string entered by the user.
+    " |
+    " +- a:limit  : The max height of the match window. Can be used to limit
+    " |             the number of items to return.
+    " |
+    " +- a:mmode  : The match mode. Can be one of these strings:
+    " |             + "full-line": match the entire line.
+    " |             + "filename-only": match only the filename.
+    " |             + "first-non-tab": match until the first tab char.
+    " |             + "until-last-tab": match until the last tab char.
+    " |
+    " +- a:ispath : Is 1 when searching in file, buffer, mru, mixed, dir, and
+    " |             rtscript modes. Is 0 otherwise.
+    " |
+    " +- a:crfile : The file in the current window. Should be excluded from the
+    " |             results when a:ispath == 1.
+    " |
+    " +- a:regex  : In regex mode: 1 or 0.
+
+    return list_of_matched_items
+  endfunction
+<
+
+===============================================================================
+COMMANDS                                                       *ctrlp-commands*
+
+                                                                       *:CtrlP*
+:CtrlP [starting-directory]
+   Open CtrlP in find file mode.
+
+   If no argument is given, the value of |g:ctrlp_working_path_mode| will be
+   used to determine the starting directory.
+
+   You can use <tab> to auto-complete the [starting-directory] when typing it.
+
+                                                                 *:CtrlPBuffer*
+:CtrlPBuffer
+   Open CtrlP in find buffer mode.
+
+                                                                    *:CtrlPMRU*
+:CtrlPMRU
+   Open CtrlP in find Most-Recently-Used file mode.
+
+                                                               *:CtrlPLastMode*
+:CtrlPLastMode [--dir]
+   Open CtrlP in the last mode used. When having the "--dir" argument, also
+   reuse the last working directory.
+
+                                                                   *:CtrlPRoot*
+:CtrlPRoot
+    This acts like |:CtrlP| with |g:ctrlp_working_path_mode| = 'r' and ignores
+    the variable's current value.
+
+                                                             *:CtrlPClearCache*
+:CtrlPClearCache
+   Flush the cache for the current working directory. The same as pressing <F5>
+   inside CtrlP.
+   To enable or disable caching, use the |g:ctrlp_use_caching| option.
+
+                                                         *:CtrlPClearAllCaches*
+:CtrlPClearAllCaches
+   Delete all the cache files saved in |g:ctrlp_cache_dir| location.
+
+-------------------------------------------------------------------------------
+For commands provided by bundled extensions, see |ctrlp-extensions|.
+
+===============================================================================
+MAPPINGS                                                       *ctrlp-mappings*
+
+                                                                *'ctrlp-<c-p>'*
+<c-p>
+   Default |Normal| mode mapping to open the CtrlP prompt in find file mode.
+
+----------------------------------------
+Once inside the prompt:~
+
+  <c-d>
+    Toggle between full-path search and filename only search.
+    Note: in filename mode, the prompt's base is '>d>' instead of '>>>'
+
+  <c-r>                                                    *'ctrlp-fullregexp'*
+    Toggle between the string mode and full regexp mode.
+    Note: in full regexp mode, the prompt's base is 'r>>' instead of '>>>'
+
+    See also: |input-formats| (guide) and |g:ctrlp_regexp_search| (option).
+
+  <c-f>, 'forward'
+  <c-up>
+    Scroll to the 'next' search mode in the sequence.
+
+  <c-b>, 'backward'
+  <c-down>
+    Scroll to the 'previous' search mode in the sequence.
+
+  <tab>                                                *'ctrlp-autocompletion'*
+    Auto-complete directory names under the current working directory inside
+    the prompt.
+
+  <s-tab>
+    Toggle the focus between the match window and the prompt.
+
+  <esc>,
+  <c-c>
+    Exit CtrlP.
+
+Moving:~
+
+  <c-j>,
+  <down>
+    Move selection down.
+
+  <c-k>,
+  <up>
+    Move selection up.
+
+  <c-a>
+    Move the cursor to the 'start' of the prompt.
+
+  <c-e>
+    Move the cursor to the 'end' of the prompt.
+
+  <c-h>,
+  <left>,
+  <c-^>
+    Move the cursor one character to the 'left'.
+
+  <c-l>,
+  <right>
+    Move the cursor one character to the 'right'.
+
+Editing:~
+
+  <c-]>,
+  <bs>
+    Delete the preceding character.
+
+  <del>
+    Delete the current character.
+
+  <c-w>
+    Delete a preceding inner word.
+
+  <c-u>
+    Clear the input field.
+
+Browsing input history:~
+
+  <c-n>
+    Next string in the prompt's history.
+
+  <c-p>
+    Previous string in the prompt's history.
+
+Opening/Creating a file:~
+
+  <cr>
+    Open the selected file in the 'current' window if possible.
+
+  <c-t>
+    Open the selected file in a new 'tab'.
+
+  <c-v>
+    Open the selected file in a 'vertical' split.
+
+  <c-x>,
+  <c-cr>,
+  <c-s>
+    Open the selected file in a 'horizontal' split.
+
+  <c-y>
+    Create a new file and its parent directories.
+
+Opening multiple files:~
+
+  <c-z>
+    - Mark/unmark a file to be opened with <c-o>.
+    - Mark/unmark a file to create a new file in its directory using <c-y>.
+
+  <c-o>
+    - Open files marked by <c-z>.
+    - When no file has been marked by <c-z>, open a console dialog with the
+      following options:
+
+      Open the selected file:
+        t - in a tab page.
+        v - in a vertical split.
+        h - in a horizontal split.
+        r - in the current window.
+        i - as a hidden buffer.
+        x - (optional) with the function defined in |g:ctrlp_open_func|.
+
+      Other options (not shown):
+        a - mark all files in the match window.
+        d - change CtrlP's local working directory to the selected file's
+            directory and switch to find file mode.
+
+Function keys:~
+
+  <F5>
+    - Refresh the match window and purge the cache for the current directory.
+    - Remove deleted files from the MRU list.
+
+  <F7>
+    - Wipe the MRU list.
+    - Delete MRU entries marked by <c-z>.
+
+Pasting:~
+
+  <Insert>,                                                   *'ctrlp-pasting'*
+  <MiddleMouse>
+    Paste the clipboard content into the prompt.
+
+  <c-\>
+    Open a console dialog to paste <cword>, <cfile>, the content of the search
+    register, the last visual selection, the clipboard or any register into the
+    prompt.
+
+Choose your own mappings with |g:ctrlp_prompt_mappings|.
+
+----------------------------------------
+When inside the match window (press <s-tab> to switch):~
+
+  a-z
+  0-9
+  ~^-=;`',.+!@#$%&_(){}[]
+    Cycle through the lines which have the matching first character.
+
+===============================================================================
+INPUT FORMATS                                             *ctrlp-input-formats*
+
+Formats for inputting in the prompt:~
+
+a)  Simple string.
+
+    E.g. 'abc' is understood internally as 'a[^a]\{-}b[^b]\{-}c'
+
+b)  When in regexp mode, the input string's treated as a Vim's regexp |pattern|
+    without any modification.
+
+    E.g. 'abc\d*efg' will be read as 'abc\d*efg'.
+
+    See |ctrlp-fullregexp| (keymap) and |g:ctrlp_regexp_search| (option) for
+    how to enable regexp mode.
+
+c)  End the string with a colon ':' followed by a Vim command to execute that
+    command after opening the file. If you need to use ':' literally, escape it
+    with a backslash: '\:'. When opening multiple files, the command will be
+    executed on each opening file.
+
+    E.g. Use ':45' to jump to line 45.
+
+         Use ':/any\:string' to jump to the first instance of 'any:string'.
+
+         Use ':+setf\ myfiletype|50' to set the filetype to 'myfiletype', then
+         jump to line 50.
+
+         Use ':diffthis' when opening multiple files to run |:diffthis| on the
+         first 4 files.
+
+    See also: Vim's |++opt| and |+cmd|.
+
+d)  Submit two dots '..' to go upward the directory tree by 1 level. To go up
+    multiple levels, use one extra dot for each extra level:
+>
+         Raw input    Interpreted as
+         ..           ../
+         ...          ../../
+         ....         ../../../
+<
+    Note: if the parent directories are large and uncached, this can be slow.
+
+    You can also use '@cd path/' to change CtrlP's local working directory.
+    Use '@cd %:h' to change to the directory of the current file.
+
+e)  Similarly, submit '/' or '\' to find and go to the project's root.
+
+    If the project is large, using a VCS listing command to look for files
+    might help speeding up the intial scan (see |g:ctrlp_user_command| for more
+    details).
+
+    Note: d) and e) only work in file, directory and mixed modes.
+
+f)  Type the name of a non-existent file and press <c-y> to create it. Mark a
+    file with <c-z> to create the new file in the same directory as the marked
+    file.
+
+    E.g. Using 'newdir/newfile.txt' will create a directory named 'newdir' as
+         well as a file named 'newfile.txt'.
+
+         If an entry 'some/old/dirs/oldfile.txt' is marked with <c-z>, then
+         'newdir' and 'newfile.txt' will be created under 'some/old/dirs'. The
+         final path will then be 'some/old/dirs/newdir/newfile.txt'.
+
+    Note: use '\' in place of '/' on Windows (if |'shellslash'| is not set).
+
+g)  In filename mode (toggle with <c-d>), you can use one primary pattern and
+    one refining pattern separated by a semicolon. Both patterns work like (a),
+    or (b) when in regexp mode.
+
+h)  Submit ? to open this help file.
+
+===============================================================================
+EXTENSIONS                                                   *ctrlp-extensions*
+
+Extensions are optional. To enable an extension, add its name to the variable
+g:ctrlp_extensions: >
+  let g:ctrlp_extensions = ['tag', 'buffertag', 'quickfix', 'dir', 'rtscript',
+                          \ 'undo', 'line', 'changes', 'mixed', 'bookmarkdir']
+<
+The order of the items will be the order they appear on the statusline and when
+using <c-f>, <c-b>.
+
+Available extensions:~
+
+                                                                    *:CtrlPTag*
+  * Tag mode:~
+    - Name: 'tag'
+    - Command: ":CtrlPTag"
+    - Search for a tag within a generated central tags file, and jump to the
+      definition. Use the Vim's option |'tags'| to specify the names and the
+      locations of the tags file(s).
+      E.g. set tags+=doc/tags
+
+                                                                 *:CtrlPBufTag*
+                                                              *:CtrlPBufTagAll*
+  * Buffer Tag mode:~
+    - Name: 'buffertag'
+    - Commands: ":CtrlPBufTag [buffer]",
+                ":CtrlPBufTagAll".
+    - Search for a tag within the current buffer or all listed buffers and jump
+      to the definition. Requires |exuberant_ctags| or compatible programs.
+
+                                                               *:CtrlPQuickfix*
+  * Quickfix mode:~
+    - Name: 'quickfix'
+    - Command: ":CtrlPQuickfix"
+    - Search for an entry in the current quickfix errors and jump to it.
+
+                                                                    *:CtrlPDir*
+  * Directory mode:~
+    - Name: 'dir'
+    - Command: ":CtrlPDir [starting-directory]"
+    - Search for a directory and change the working directory to it.
+    - Mappings:
+      + <cr> change the local working directory for CtrlP and keep it open.
+      + <c-t> change the global working directory (exit).
+      + <c-v> change the local working directory for the current window (exit).
+      + <c-x> change the global working directory to CtrlP's current local
+        working directory (exit).
+
+                                                                    *:CtrlPRTS*
+  * Runtime script mode:~
+    - Name: 'rtscript'
+    - Command: ":CtrlPRTS"
+    - Search for files (vimscripts, docs, snippets...) in runtimepath.
+
+                                                                   *:CtrlPUndo*
+  * Undo mode:~
+    - Name: 'undo'
+    - Command: ":CtrlPUndo"
+    - Browse undo history.
+
+                                                                   *:CtrlPLine*
+  * Line mode:~
+    - Name: 'line'
+    - Command: ":CtrlPLine"
+    - Search for a line in all listed buffers.
+
+                                                                 *:CtrlPChange*
+                                                              *:CtrlPChangeAll*
+  * Change list mode:~
+    - Name: 'changes'
+    - Commands: ":CtrlPChange [buffer]",
+                ":CtrlPChangeAll".
+    - Search for and jump to a recent change in the current buffer or in all
+      listed buffers.
+
+                                                                  *:CtrlPMixed*
+  * Mixed mode:~
+    - Name: 'mixed'
+    - Command: ":CtrlPMixed"
+    - Search in files, buffers and MRU files at the same time.
+
+                                                            *:CtrlPBookmarkDir*
+                                                         *:CtrlPBookmarkDirAdd*
+  * BookmarkDir mode:~
+    - Name: 'bookmarkdir'
+    - Commands: ":CtrlPBookmarkDir",
+                ":CtrlPBookmarkDirAdd [directory]".
+    - Search for a bookmarked directory and change the working directory to it.
+    - Mappings:
+      + <cr> change the local working directory for CtrlP, keep it open and
+        switch to find file mode.
+      + <c-x> change the global working directory (exit).
+      + <c-v> change the local working directory for the current window (exit).
+      + <F7>
+        - Wipe bookmark list.
+        - Delete entries marked by <c-z>.
+
+----------------------------------------
+Buffer Tag mode options:~
+
+                                                   *'g:ctrlp_buftag_ctags_bin'*
+If ctags isn't in your $PATH, use this to set its location: >
+  let g:ctrlp_buftag_ctags_bin = ''
+<
+
+                                                   *'g:ctrlp_buftag_systemenc'*
+Match this with your OS's encoding (not Vim's). The default value mirrors Vim's
+global |'encoding'| option: >
+  let g:ctrlp_buftag_systemenc = &encoding
+<
+
+                                                       *'g:ctrlp_buftag_types'*
+Use this to set the arguments for ctags, jsctags... for a given filetype: >
+  let g:ctrlp_buftag_types = ''
+<
+Examples: >
+  let g:ctrlp_buftag_types = {
+    \ 'erlang'     : '--language-force=erlang --erlang-types=drmf',
+    \ 'javascript' : {
+      \ 'bin': 'jsctags',
+      \ 'args': '-f -',
+      \ },
+    \ }
+<
+
+===============================================================================
+CUSTOMIZATION                                             *ctrlp-customization*
+
+Highlighting:~
+  * For the CtrlP buffer:
+    CtrlPNoEntries : the message when no match is found (Error)
+    CtrlPMatch     : the matched pattern (Identifier)
+    CtrlPLinePre   : the line prefix '>' in the match window
+    CtrlPPrtBase   : the prompt's base (Comment)
+    CtrlPPrtText   : the prompt's text (|hl-Normal|)
+    CtrlPPrtCursor : the prompt's cursor when moving over the text (Constant)
+
+  * In extensions:
+    CtrlPTabExtra  : the part of each line that's not matched against (Comment)
+    CtrlPBufName   : the buffer name an entry belongs to (|hl-Directory|)
+    CtrlPTagKind   : the kind of the tag in buffer-tag mode (|hl-Title|)
+    CtrlPqfLineCol : the line and column numbers in quickfix mode (Comment)
+    CtrlPUndoT     : the elapsed time in undo mode (|hl-Directory|)
+    CtrlPUndoBr    : the square brackets [] in undo mode (Comment)
+    CtrlPUndoNr    : the undo number inside [] in undo mode (String)
+    CtrlPUndoSv    : the point where the file was saved (Comment)
+    CtrlPUndoPo    : the current position in the undo tree (|hl-Title|)
+    CtrlPBookmark  : the name of the bookmark (Identifier)
+
+Statuslines:~
+  * Highlight groups:
+    CtrlPMode1 : 'file' or 'path', and the current mode (Character)
+    CtrlPMode2 : 'prt' or 'win', 'regex', the working directory (|hl-LineNr|)
+    CtrlPStats : the scanning status (Function)
+
+  For rebuilding the statuslines, see |g:ctrlp_status_func|.
+
+===============================================================================
+MISCELLANEOUS CONFIGS                             *ctrlp-miscellaneous-configs*
+
+* Using |wildignore| for |g:ctrlp_user_command|:
+>
+  function! s:wig2cmd()
+    " Change wildignore into space or | separated groups
+    " e.g. .aux .out .toc .jpg .bmp .gif
+    " or   .aux$\|.out$\|.toc$\|.jpg$\|.bmp$\|.gif$
+    let pats = ['[*\/]*\([?_.0-9A-Za-z]\+\)\([*\/]*\)\(\\\@<!,\|$\)','\\\@<!,']
+    let subs = has('win32') || has('win64') ? ['\1\3', ' '] : ['\1\2\3', '\\|']
+    let expr = substitute(&wig, pats[0], subs[0], 'g')
+    let expr = substitute(expr, pats[1], subs[1], 'g')
+    let expr = substitute(expr, '\\,', ',', 'g')
+
+    " Set the user_command option
+    let g:ctrlp_user_command = has('win32') || has('win64')
+      \ ? 'dir %s /-n /b /s /a-d | findstr /V /l "'.expr.'"'
+      \ : 'find %s -type f | grep -v "'.expr .'"'
+  endfunction
+
+  call s:wig2cmd()
+<
+(submitted by Rich Alesi <github.com/ralesi>)
+
+* A standalone function to set the working directory to the project's root, or
+  to the parent directory of the current file if a root can't be found:
+>
+  function! s:setcwd()
+    let cph = expand('%:p:h', 1)
+    if cph =~ '^.\+://' | retu | en
+    for mkr in ['.git/', '.hg/', '.svn/', '.bzr/', '_darcs/', '.vimprojects']
+      let wd = call('find'.(mkr =~ '/$' ? 'dir' : 'file'), [mkr, cph.';'])
+      if wd != '' | let &acd = 0 | brea | en
+    endfo
+    exe 'lc!' fnameescape(wd == '' ? cph : substitute(wd, mkr.'$', '.', ''))
+  endfunction
+
+  autocmd BufEnter * call s:setcwd()
+<
+(requires Vim 7.1.299+)
+
+* Using a |count| to invoke different commands using the same mapping:
+>
+  let g:ctrlp_cmd = 'exe "CtrlP".get(["", "Buffer", "MRU"], v:count)'
+<
+
+===============================================================================
+CREDITS                                                         *ctrlp-credits*
+
+Developed by Kien Nguyen <github.com/kien>.
+
+Project's homepage:   http://kien.github.com/ctrlp.vim
+Git repository:       https://github.com/kien/ctrlp.vim
+Mercurial repository: https://bitbucket.org/kien/ctrlp.vim
+
+-------------------------------------------------------------------------------
+Thanks to everyone that has submitted ideas, bug reports or helped debugging on
+gibhub, bitbucket, and through email.
+
+Special thanks:~
+
+    * Woojong Koh <github.com/wjkoh>
+    * Simon Ruderich
+    * Yasuhiro Matsumoto <github.com/mattn>
+    * Ken Earley <github.com/kenearley>
+    * Kyo Nagashima <github.com/hail2u>
+    * Zak Johnson <github.com/zakj>
+    * Diego Viola <github.com/diegoviola>
+    * Piet Delport <github.com/pjdelport>
+    * Thibault Duplessis <github.com/ornicar>
+    * Kent Sibilev <github.com/datanoise>
+    * Tacahiroy <github.com/tacahiroy>
+    * Luca Pette <github.com/lucapette>
+    * Seth Fowler <github.com/sfowler>
+    * Lowe Thiderman <github.com/thiderman>
+    * Christopher Fredén <github.com/icetan>
+    * Zahary Karadjov <github.com/zah>
+
+===============================================================================
+CHANGELOG                                                     *ctrlp-changelog*
+
+    + New options: |g:ctrlp_abbrev|,
+                   |g:ctrlp_key_loop|,
+                   |g:ctrlp_open_func|,
+                   |g:ctrlp_tabpage_position|
+    + Rename:
+        *g:ctrlp_dotfiles* -> |g:ctrlp_show_hidden|.
+    + Change |g:ctrlp_switch_buffer|'s and |g:ctrlp_working_path_mode|'s type
+      (old values still work).
+    + New key for |g:ctrlp_user_command| when it's a Dictionary: 'ignore'.
+
+Before 2012/06/15~
+
+    + New value for |g:ctrlp_follow_symlinks|: 2.
+    + New value for |g:ctrlp_open_multiple_files|: 'j'.
+    + Allow using <c-t>, <c-x>, <c-v> to open files marked by <c-z>.
+    + Extend '..' (|ctrlp-input-formats| (d))
+    + New input format: '@cd' (|ctrlp-input-formats| (d))
+
+Before 2012/04/30~
+
+    + New option: |g:ctrlp_mruf_default_order|
+    + New feature: Bookmarked directories extension.
+    + New commands: |:CtrlPBookmarkDir|
+                    |:CtrlPBookmarkDirAdd|
+
+Before 2012/04/15~
+
+    + New option: |g:ctrlp_buffer_func|, callback functions for CtrlP buffer.
+    + Remove: g:ctrlp_mruf_last_entered, make it a default for MRU mode.
+    + New commands: |:CtrlPLastMode|, open CtrlP in the last mode used.
+                    |:CtrlPMixed|, search in files, buffers and MRU files.
+
+Before 2012/03/31~
+
+    + New options: |g:ctrlp_default_input|, default input when entering CtrlP.
+                   |g:ctrlp_match_func|, allow using a custom fuzzy matcher.
+    + Rename:
+        *ClearCtrlPCache* -> |CtrlPClearCache|
+        *ClearAllCtrlPCaches* -> |CtrlPClearAllCaches|
+        *ResetCtrlP* -> |CtrlPReload|
+
+Before 2012/03/02~
+
+    + Rename:
+        *g:ctrlp_regexp_search* -> |g:ctrlp_regexp|,
+        *g:ctrlp_dont_split* -> |g:ctrlp_reuse_window|,
+        *g:ctrlp_jump_to_buffer* -> |g:ctrlp_switch_buffer|.
+    + Rename and tweak:
+        *g:ctrlp_open_multi* -> |g:ctrlp_open_multiple_files|.
+    + Deprecate *g:ctrlp_highlight_match*
+    + Extend |g:ctrlp_user_command| to support multiple commands.
+    + New option: |g:ctrlp_mruf_last_entered| change MRU to Recently-Entered.
+
+Before 2012/01/15~
+
+    + New mapping: Switch <tab> and <s-tab>. <tab> is now used for completion
+                   of directory names under the current working directory.
+    + New options: |g:ctrlp_arg_map| for <c-y>, <c-o> to accept an argument.
+                   |g:ctrlp_status_func| custom statusline.
+                   |g:ctrlp_mruf_relative| show only MRU files inside cwd.
+    + Extend g:ctrlp_open_multi with new optional values: tr, hr, vr.
+    + Extend |g:ctrlp_custom_ignore| to specifically filter dir, file and link.
+
+Before 2012/01/05~
+
+    + New feature: Buffer Tag extension.
+    + New commands: |:CtrlPBufTag|, |:CtrlPBufTagAll|.
+    + New options: |g:ctrlp_cmd|,
+                   |g:ctrlp_custom_ignore|
+
+Before 2011/11/30~
+
+    + New features: Tag, Quickfix and Directory extensions.
+    + New commands: |:CtrlPTag|, |:CtrlPQuickfix|, |:CtrlPDir|.
+    + New options: |g:ctrlp_use_migemo|,
+                   |g:ctrlp_lazy_update|,
+                   |g:ctrlp_follow_symlinks|
+
+Before 2011/11/13~
+
+    + New special input: '/' and '\' find root (|ctrlp-input-formats| (e))
+    + Remove ctrlp#SetWorkingPath().
+    + Remove *g:ctrlp_mru_files* and make MRU mode permanent.
+    + Extend g:ctrlp_open_multi, add new ways to open files.
+    + New option: g:ctrlp_dont_split,
+                  |g:ctrlp_mruf_case_sensitive|
+
+Before 2011/10/30~
+
+    + New feature: Support for custom extensions.
+                   <F5> also removes non-existent files from MRU list.
+    + New option: g:ctrlp_jump_to_buffer
+
+Before 2011/10/12~
+
+    + New features: Open multiple files.
+                    Pass Vim's |++opt| and |+cmd| to the opening file
+                    (|ctrlp-input-formats| (c))
+                    Auto-complete each dir for |:CtrlP| [starting-directory]
+    + New mappings: <c-z> mark/unmark a file to be opened with <c-o>.
+                    <c-o> open all marked files.
+    + New option: g:ctrlp_open_multi
+    + Remove *g:ctrlp_persistent_input* *g:ctrlp_live_update* and <c-^>.
+
+Before 2011/09/29~
+
+    + New mappings: <c-n>, <c-p> next/prev string in the input history.
+                    <c-y> create a new file and its parent dirs.
+    + New options: |g:ctrlp_open_new_file|,
+                   |g:ctrlp_max_history|
+    + Added a new open-in-horizontal-split mapping: <c-x>
+
+Before 2011/09/19~
+
+    + New command: ResetCtrlP
+    + New options: |g:ctrlp_max_files|,
+                   |g:ctrlp_max_depth|,
+                   g:ctrlp_live_update
+    + New mapping: <c-^>
+
+Before 2011/09/12~
+
+    + Ability to cycle through matched lines in the match window.
+    + Extend the behavior of g:ctrlp_persistent_input
+    + Extend the behavior of |:CtrlP|
+    + New options: |g:ctrlp_dotfiles|,
+                   |g:ctrlp_clear_cache_on_exit|,
+                   g:ctrlp_highlight_match,
+                   |g:ctrlp_user_command|
+    + New special input: '..' (|ctrlp-input-formats| (d))
+    + New mapping: <F5>.
+    + New commands: |:CtrlPCurWD|,
+                    |:CtrlPCurFile|,
+                    |:CtrlPRoot|
+
+    + New feature: Search in most recently used (MRU) files
+    + New mapping: <c-b>.
+    + Extended the behavior of <c-f>.
+    + New options: g:ctrlp_mru_files,
+                   |g:ctrlp_mruf_max|,
+                   |g:ctrlp_mruf_exclude|,
+                   |g:ctrlp_mruf_include|
+    + New command: |:CtrlPMRU|
+
+First public release: 2011/09/06~
+
+===============================================================================
+vim:ft=help:et:ts=2:sw=2:sts=2:norl
diff --git a/vim/vimfiles/bundle/ctrlp/doc/tags b/vim/vimfiles/bundle/ctrlp/doc/tags
new file mode 100644 (file)
index 0000000..ee1ee8f
--- /dev/null
@@ -0,0 +1,98 @@
+'ctrl-p'       ctrlp.txt       /*'ctrl-p'*
+'ctrlp'        ctrlp.txt       /*'ctrlp'*
+'ctrlp-<c-p>'  ctrlp.txt       /*'ctrlp-<c-p>'*
+'ctrlp-autocompletion' ctrlp.txt       /*'ctrlp-autocompletion'*
+'ctrlp-fullregexp'     ctrlp.txt       /*'ctrlp-fullregexp'*
+'ctrlp-pasting'        ctrlp.txt       /*'ctrlp-pasting'*
+'ctrlp-wildignore'     ctrlp.txt       /*'ctrlp-wildignore'*
+'g:ctrlp_abbrev'       ctrlp.txt       /*'g:ctrlp_abbrev'*
+'g:ctrlp_arg_map'      ctrlp.txt       /*'g:ctrlp_arg_map'*
+'g:ctrlp_buffer_func'  ctrlp.txt       /*'g:ctrlp_buffer_func'*
+'g:ctrlp_buftag_ctags_bin'     ctrlp.txt       /*'g:ctrlp_buftag_ctags_bin'*
+'g:ctrlp_buftag_systemenc'     ctrlp.txt       /*'g:ctrlp_buftag_systemenc'*
+'g:ctrlp_buftag_types' ctrlp.txt       /*'g:ctrlp_buftag_types'*
+'g:ctrlp_by_filename'  ctrlp.txt       /*'g:ctrlp_by_filename'*
+'g:ctrlp_cache_dir'    ctrlp.txt       /*'g:ctrlp_cache_dir'*
+'g:ctrlp_clear_cache_on_exit'  ctrlp.txt       /*'g:ctrlp_clear_cache_on_exit'*
+'g:ctrlp_cmd'  ctrlp.txt       /*'g:ctrlp_cmd'*
+'g:ctrlp_custom_ignore'        ctrlp.txt       /*'g:ctrlp_custom_ignore'*
+'g:ctrlp_default_input'        ctrlp.txt       /*'g:ctrlp_default_input'*
+'g:ctrlp_follow_symlinks'      ctrlp.txt       /*'g:ctrlp_follow_symlinks'*
+'g:ctrlp_key_loop'     ctrlp.txt       /*'g:ctrlp_key_loop'*
+'g:ctrlp_lazy_update'  ctrlp.txt       /*'g:ctrlp_lazy_update'*
+'g:ctrlp_map'  ctrlp.txt       /*'g:ctrlp_map'*
+'g:ctrlp_match_func'   ctrlp.txt       /*'g:ctrlp_match_func'*
+'g:ctrlp_match_window_bottom'  ctrlp.txt       /*'g:ctrlp_match_window_bottom'*
+'g:ctrlp_match_window_reversed'        ctrlp.txt       /*'g:ctrlp_match_window_reversed'*
+'g:ctrlp_max_depth'    ctrlp.txt       /*'g:ctrlp_max_depth'*
+'g:ctrlp_max_files'    ctrlp.txt       /*'g:ctrlp_max_files'*
+'g:ctrlp_max_height'   ctrlp.txt       /*'g:ctrlp_max_height'*
+'g:ctrlp_max_history'  ctrlp.txt       /*'g:ctrlp_max_history'*
+'g:ctrlp_mruf_case_sensitive'  ctrlp.txt       /*'g:ctrlp_mruf_case_sensitive'*
+'g:ctrlp_mruf_default_order'   ctrlp.txt       /*'g:ctrlp_mruf_default_order'*
+'g:ctrlp_mruf_exclude' ctrlp.txt       /*'g:ctrlp_mruf_exclude'*
+'g:ctrlp_mruf_include' ctrlp.txt       /*'g:ctrlp_mruf_include'*
+'g:ctrlp_mruf_max'     ctrlp.txt       /*'g:ctrlp_mruf_max'*
+'g:ctrlp_mruf_relative'        ctrlp.txt       /*'g:ctrlp_mruf_relative'*
+'g:ctrlp_open_func'    ctrlp.txt       /*'g:ctrlp_open_func'*
+'g:ctrlp_open_multiple_files'  ctrlp.txt       /*'g:ctrlp_open_multiple_files'*
+'g:ctrlp_open_new_file'        ctrlp.txt       /*'g:ctrlp_open_new_file'*
+'g:ctrlp_prompt_mappings'      ctrlp.txt       /*'g:ctrlp_prompt_mappings'*
+'g:ctrlp_regexp'       ctrlp.txt       /*'g:ctrlp_regexp'*
+'g:ctrlp_reuse_window' ctrlp.txt       /*'g:ctrlp_reuse_window'*
+'g:ctrlp_root_markers' ctrlp.txt       /*'g:ctrlp_root_markers'*
+'g:ctrlp_show_hidden'  ctrlp.txt       /*'g:ctrlp_show_hidden'*
+'g:ctrlp_status_func'  ctrlp.txt       /*'g:ctrlp_status_func'*
+'g:ctrlp_switch_buffer'        ctrlp.txt       /*'g:ctrlp_switch_buffer'*
+'g:ctrlp_tabpage_position'     ctrlp.txt       /*'g:ctrlp_tabpage_position'*
+'g:ctrlp_use_caching'  ctrlp.txt       /*'g:ctrlp_use_caching'*
+'g:ctrlp_use_migemo'   ctrlp.txt       /*'g:ctrlp_use_migemo'*
+'g:ctrlp_user_command' ctrlp.txt       /*'g:ctrlp_user_command'*
+'g:ctrlp_working_path_mode'    ctrlp.txt       /*'g:ctrlp_working_path_mode'*
+'g:loaded_ctrlp'       ctrlp.txt       /*'g:loaded_ctrlp'*
+:CtrlP ctrlp.txt       /*:CtrlP*
+:CtrlPBookmarkDir      ctrlp.txt       /*:CtrlPBookmarkDir*
+:CtrlPBookmarkDirAdd   ctrlp.txt       /*:CtrlPBookmarkDirAdd*
+:CtrlPBufTag   ctrlp.txt       /*:CtrlPBufTag*
+:CtrlPBufTagAll        ctrlp.txt       /*:CtrlPBufTagAll*
+:CtrlPBuffer   ctrlp.txt       /*:CtrlPBuffer*
+:CtrlPChange   ctrlp.txt       /*:CtrlPChange*
+:CtrlPChangeAll        ctrlp.txt       /*:CtrlPChangeAll*
+:CtrlPClearAllCaches   ctrlp.txt       /*:CtrlPClearAllCaches*
+:CtrlPClearCache       ctrlp.txt       /*:CtrlPClearCache*
+:CtrlPDir      ctrlp.txt       /*:CtrlPDir*
+:CtrlPLastMode ctrlp.txt       /*:CtrlPLastMode*
+:CtrlPLine     ctrlp.txt       /*:CtrlPLine*
+:CtrlPMRU      ctrlp.txt       /*:CtrlPMRU*
+:CtrlPMixed    ctrlp.txt       /*:CtrlPMixed*
+:CtrlPQuickfix ctrlp.txt       /*:CtrlPQuickfix*
+:CtrlPRTS      ctrlp.txt       /*:CtrlPRTS*
+:CtrlPRoot     ctrlp.txt       /*:CtrlPRoot*
+:CtrlPTag      ctrlp.txt       /*:CtrlPTag*
+:CtrlPUndo     ctrlp.txt       /*:CtrlPUndo*
+ClearAllCtrlPCaches    ctrlp.txt       /*ClearAllCtrlPCaches*
+ClearCtrlPCache        ctrlp.txt       /*ClearCtrlPCache*
+ControlP       ctrlp.txt       /*ControlP*
+CtrlP  ctrlp.txt       /*CtrlP*
+ResetCtrlP     ctrlp.txt       /*ResetCtrlP*
+ctrlp-changelog        ctrlp.txt       /*ctrlp-changelog*
+ctrlp-commands ctrlp.txt       /*ctrlp-commands*
+ctrlp-contents ctrlp.txt       /*ctrlp-contents*
+ctrlp-credits  ctrlp.txt       /*ctrlp-credits*
+ctrlp-customization    ctrlp.txt       /*ctrlp-customization*
+ctrlp-extensions       ctrlp.txt       /*ctrlp-extensions*
+ctrlp-input-formats    ctrlp.txt       /*ctrlp-input-formats*
+ctrlp-intro    ctrlp.txt       /*ctrlp-intro*
+ctrlp-mappings ctrlp.txt       /*ctrlp-mappings*
+ctrlp-miscellaneous-configs    ctrlp.txt       /*ctrlp-miscellaneous-configs*
+ctrlp-options  ctrlp.txt       /*ctrlp-options*
+ctrlp.txt      ctrlp.txt       /*ctrlp.txt*
+g:ctrlp_dont_split     ctrlp.txt       /*g:ctrlp_dont_split*
+g:ctrlp_dotfiles       ctrlp.txt       /*g:ctrlp_dotfiles*
+g:ctrlp_highlight_match        ctrlp.txt       /*g:ctrlp_highlight_match*
+g:ctrlp_jump_to_buffer ctrlp.txt       /*g:ctrlp_jump_to_buffer*
+g:ctrlp_live_update    ctrlp.txt       /*g:ctrlp_live_update*
+g:ctrlp_mru_files      ctrlp.txt       /*g:ctrlp_mru_files*
+g:ctrlp_open_multi     ctrlp.txt       /*g:ctrlp_open_multi*
+g:ctrlp_persistent_input       ctrlp.txt       /*g:ctrlp_persistent_input*
+g:ctrlp_regexp_search  ctrlp.txt       /*g:ctrlp_regexp_search*
diff --git a/vim/vimfiles/bundle/ctrlp/plugin/ctrlp.vim b/vim/vimfiles/bundle/ctrlp/plugin/ctrlp.vim
new file mode 100644 (file)
index 0000000..68cae86
--- /dev/null
@@ -0,0 +1,69 @@
+" =============================================================================
+" File:          plugin/ctrlp.vim
+" Description:   Fuzzy file, buffer, mru, tag, etc finder.
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+" GetLatestVimScripts: 3736 1 :AutoInstall: ctrlp.zip
+
+if ( exists('g:loaded_ctrlp') && g:loaded_ctrlp ) || v:version < 700 || &cp
+       fini
+en
+let g:loaded_ctrlp = 1
+
+let [g:ctrlp_lines, g:ctrlp_allfiles, g:ctrlp_alltags, g:ctrlp_alldirs,
+       \ g:ctrlp_allmixes, g:ctrlp_buftags, g:ctrlp_ext_vars, g:ctrlp_builtins]
+       \ = [[], [], [], [], {}, {}, [], 2]
+
+if !exists('g:ctrlp_map') | let g:ctrlp_map = '<c-p>' | en
+if !exists('g:ctrlp_cmd') | let g:ctrlp_cmd = 'CtrlP' | en
+
+com! -n=? -com=custom,ctrlp#utils#dircompl CtrlP
+       \ cal ctrlp#init(0, { 'dir': <q-args> })
+
+com! -n=? -com=custom,ctrlp#utils#dircompl CtrlPMRUFiles
+       \ cal ctrlp#init(2, { 'dir': <q-args> })
+
+com! -bar CtrlPBuffer   cal ctrlp#init(1)
+com! -n=? CtrlPLastMode cal ctrlp#init(-1, { 'args': <q-args> })
+
+com! -bar CtrlPClearCache     cal ctrlp#clr()
+com! -bar CtrlPClearAllCaches cal ctrlp#clra()
+
+com! -bar ClearCtrlPCache     cal ctrlp#clr()
+com! -bar ClearAllCtrlPCaches cal ctrlp#clra()
+
+com! -bar CtrlPCurWD   cal ctrlp#init(0, { 'mode': '' })
+com! -bar CtrlPCurFile cal ctrlp#init(0, { 'mode': 'c' })
+com! -bar CtrlPRoot    cal ctrlp#init(0, { 'mode': 'r' })
+
+if g:ctrlp_map != '' && !hasmapto(':<c-u>'.g:ctrlp_cmd.'<cr>', 'n')
+       exe 'nn <silent>' g:ctrlp_map ':<c-u>'.g:ctrlp_cmd.'<cr>'
+en
+
+cal ctrlp#mrufiles#init()
+
+com! -bar CtrlPTag      cal ctrlp#init(ctrlp#tag#id())
+com! -bar CtrlPQuickfix cal ctrlp#init(ctrlp#quickfix#id())
+
+com! -n=? -com=custom,ctrlp#utils#dircompl CtrlPDir
+       \ cal ctrlp#init(ctrlp#dir#id(), { 'dir': <q-args> })
+
+com! -n=? -com=buffer CtrlPBufTag
+       \ cal ctrlp#init(ctrlp#buffertag#cmd(0, <q-args>))
+
+com! -bar CtrlPBufTagAll cal ctrlp#init(ctrlp#buffertag#cmd(1))
+com! -bar CtrlPRTS       cal ctrlp#init(ctrlp#rtscript#id())
+com! -bar CtrlPUndo      cal ctrlp#init(ctrlp#undo#id())
+com! -bar CtrlPLine      cal ctrlp#init(ctrlp#line#id())
+
+com! -n=? -com=buffer CtrlPChange
+       \ cal ctrlp#init(ctrlp#changes#cmd(0, <q-args>))
+
+com! -bar CtrlPChangeAll   cal ctrlp#init(ctrlp#changes#cmd(1))
+com! -bar CtrlPMixed       cal ctrlp#init(ctrlp#mixed#id())
+com! -bar CtrlPBookmarkDir cal ctrlp#init(ctrlp#bookmarkdir#id())
+
+com! -n=? -com=custom,ctrlp#utils#dircompl CtrlPBookmarkDirAdd
+       \ cal ctrlp#call('ctrlp#bookmarkdir#add', <q-args>)
+
+" vim:ts=2:sw=2:sts=2
diff --git a/vim/vimfiles/bundle/ctrlp/readme.md b/vim/vimfiles/bundle/ctrlp/readme.md
new file mode 100644 (file)
index 0000000..2525b83
--- /dev/null
@@ -0,0 +1,86 @@
+# ctrlp.vim
+Full path fuzzy __file__, __buffer__, __mru__, __tag__, __...__ finder for Vim.
+
+* Written in pure Vimscript for MacVim, gVim and Vim 7.0+.
+* Full support for Vim's regexp as search patterns.
+* Built-in Most Recently Used (MRU) files monitoring.
+* Built-in project's root finder.
+* Open multiple files at once.
+* Create new files and directories.
+* [Extensible][2].
+
+![ctrlp][1]
+
+## Basic Usage
+* Run `:CtrlP` or `:CtrlP [starting-directory]` to invoke CtrlP in find file mode.
+* Run `:CtrlPBuffer` or `:CtrlPMRU` to invoke CtrlP in find buffer or find MRU file mode.
+* Run `:CtrlPMixed` to search in Files, Buffers and MRU files at the same time.
+
+Check `:help ctrlp-commands` and `:help ctrlp-extensions` for other commands.
+
+##### Once CtrlP is open:
+* Press `<F5>` to purge the cache for the current directory to get new files, remove deleted files and apply new ignore options.
+* Press `<c-f>` and `<c-b>` to cycle between modes.
+* Press `<c-d>` to switch to filename only search instead of full path.
+* Press `<c-r>` to switch to regexp mode.
+* Use `<c-n>`, `<c-p>` to select the next/previous string in the prompt's history.
+* Use `<c-y>` to create a new file and its parent directories.
+* Use `<c-z>` to mark/unmark multiple files and `<c-o>` to open them.
+
+Run `:help ctrlp-mappings` or submit `?` in CtrlP for more mapping help.
+
+* Submit two or more dots `..` to go up the directory tree by one or multiple levels.
+* End the input string with a colon `:` followed by a command to execute it on the opening file(s):  
+Use `:25` to jump to line 25.  
+Use `:diffthis` when opening multiple files to run `:diffthis` on the first 4 files.
+
+## Basic Options
+* Change the default mapping and the default command to invoke CtrlP:
+
+    ```vim
+    let g:ctrlp_map = '<c-p>'
+    let g:ctrlp_cmd = 'CtrlP'
+    ```
+
+* When invoked, unless a starting directory is specified, CtrlP will set its local working directory according to this variable:
+
+    ```vim
+    let g:ctrlp_working_path_mode = 'ra'
+    ```
+
+    `'c'` - the directory of the current file.  
+    `'r'` - the nearest ancestor that contains one of these directories or files: `.git` `.hg` `.svn` `.bzr` `_darcs`  
+    `'a'` - like c, but only if the current working directory outside of CtrlP is not a direct ancestor of the directory of the current file.  
+    `0` or `''` (empty string) - disable this feature.
+
+    Define additional root markers with the `g:ctrlp_root_markers` option.
+
+* Exclude files and directories using Vim's `wildignore` and CtrlP's own `g:ctrlp_custom_ignore`:
+
+    ```vim
+    set wildignore+=*/tmp/*,*.so,*.swp,*.zip     " MacOSX/Linux
+    set wildignore+=*\\tmp\\*,*.swp,*.zip,*.exe  " Windows
+
+    let g:ctrlp_custom_ignore = '\v[\/]\.(git|hg|svn)$'
+    let g:ctrlp_custom_ignore = {
+      \ 'dir':  '\v[\/]\.(git|hg|svn)$',
+      \ 'file': '\v\.(exe|so|dll)$',
+      \ 'link': 'some_bad_symbolic_links',
+      \ }
+    ```
+
+* Use a custom file listing command:
+
+    ```vim
+    let g:ctrlp_user_command = 'find %s -type f'        " MacOSX/Linux
+    let g:ctrlp_user_command = 'dir %s /-n /b /s /a-d'  " Windows
+    ```
+
+Check `:help ctrlp-options` for other options.
+
+## Installation
+Use your favorite method or check the homepage for a [quick installation guide][3].
+
+[1]: http://i.imgur.com/yIynr.png
+[2]: https://github.com/kien/ctrlp.vim/tree/extensions
+[3]: http://kien.github.com/ctrlp.vim#installation
diff --git a/vim/vimfiles/bundle/tagbar/README b/vim/vimfiles/bundle/tagbar/README
new file mode 100644 (file)
index 0000000..c95f2c4
--- /dev/null
@@ -0,0 +1,7 @@
+Tagbar is a vim plugin for browsing the tags of source code files. It provides
+a sidebar that displays the ctags-generated tags of the current file, ordered
+by their scope. This means that for example methods in C++ are displayed under
+the class they are defined in.
+
+Check out the homepage at http://majutsushi.github.com/tagbar/ for more
+information.
diff --git a/vim/vimfiles/bundle/tagbar/autoload/tagbar.vim b/vim/vimfiles/bundle/tagbar/autoload/tagbar.vim
new file mode 100644 (file)
index 0000000..2b7587e
--- /dev/null
@@ -0,0 +1,3668 @@
+" ============================================================================
+" File:        tagbar.vim
+" Description: List the current file's tags in a sidebar, ordered by class etc
+" Author:      Jan Larres <jan@majutsushi.net>
+" Licence:     Vim licence
+" Website:     http://majutsushi.github.com/tagbar/
+" Version:     2.4.1
+" Note:        This plugin was heavily inspired by the 'Taglist' plugin by
+"              Yegappan Lakshmanan and uses a small amount of code from it.
+"
+" Original taglist copyright notice:
+"              Permission is hereby granted to use and distribute this code,
+"              with or without modifications, provided that this copyright
+"              notice is copied with it. Like anything else that's free,
+"              taglist.vim is provided *as is* and comes with no warranty of
+"              any kind, either expressed or implied. In no event will the
+"              copyright holder be liable for any damamges resulting from the
+"              use of this software.
+" ============================================================================
+
+scriptencoding utf-8
+
+" Initialization {{{1
+
+" If another plugin calls an autoloaded Tagbar function on startup before the
+" plugin/tagbar.vim file got loaded, load it explicitly
+if exists(':Tagbar') == 0
+    runtime plugin/tagbar.vim
+endif
+
+" Basic init {{{2
+
+redir => s:ftype_out
+silent filetype
+redir END
+if s:ftype_out !~# 'detection:ON'
+    echomsg 'Tagbar: Filetype detection is turned off, skipping plugin'
+    unlet s:ftype_out
+    finish
+endif
+unlet s:ftype_out
+
+let s:icon_closed = g:tagbar_iconchars[0]
+let s:icon_open   = g:tagbar_iconchars[1]
+
+let s:type_init_done      = 0
+let s:autocommands_done   = 0
+let s:autocommands_enabled = 0
+" 0: not checked yet; 1: checked and found; 2: checked and not found
+let s:checked_ctags       = 0
+let s:checked_ctags_types = 0
+let s:ctags_types         = {}
+
+let s:new_window      = 1
+let s:is_maximized    = 0
+let s:short_help      = 1
+let s:window_expanded = 0
+let s:nearby_disabled = 0
+
+" Script-local variable needed since compare functions can't
+" take extra arguments
+let s:compare_typeinfo = {}
+
+
+let s:visibility_symbols = {
+    \ 'public'    : '+',
+    \ 'protected' : '#',
+    \ 'private'   : '-'
+\ }
+
+let g:loaded_tagbar = 1
+
+let s:last_highlight_tline = 0
+let s:debug = 0
+let s:debug_file = ''
+
+" s:Init() {{{2
+function! s:Init(silent) abort
+    if s:checked_ctags == 2 && a:silent
+        return 0
+    elseif s:checked_ctags != 1
+        if !s:CheckForExCtags(a:silent)
+            return 0
+        endif
+    endif
+
+    if !s:checked_ctags_types
+        call s:GetSupportedFiletypes()
+    endif
+
+    if !s:type_init_done
+        call s:InitTypes()
+    endif
+
+    if !s:autocommands_done
+        call s:CreateAutocommands()
+        call s:AutoUpdate(fnamemodify(expand('%'), ':p'), 0)
+    endif
+
+    return 1
+endfunction
+
+" s:InitTypes() {{{2
+function! s:InitTypes() abort
+    call s:LogDebugMessage('Initializing types')
+
+    let s:known_types = {}
+
+    " Ant {{{3
+    let type_ant = s:TypeInfo.New()
+    let type_ant.ctagstype = 'ant'
+    let type_ant.kinds     = [
+        \ {'short' : 'p', 'long' : 'projects', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'targets',  'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.ant = type_ant
+    " Asm {{{3
+    let type_asm = s:TypeInfo.New()
+    let type_asm.ctagstype = 'asm'
+    let type_asm.kinds     = [
+        \ {'short' : 'm', 'long' : 'macros',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'types',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'd', 'long' : 'defines', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'l', 'long' : 'labels',  'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.asm = type_asm
+    " ASP {{{3
+    let type_aspvbs = s:TypeInfo.New()
+    let type_aspvbs.ctagstype = 'asp'
+    let type_aspvbs.kinds     = [
+        \ {'short' : 'd', 'long' : 'constants',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'classes',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'subroutines', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',   'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.aspvbs = type_aspvbs
+    " Awk {{{3
+    let type_awk = s:TypeInfo.New()
+    let type_awk.ctagstype = 'awk'
+    let type_awk.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.awk = type_awk
+    " Basic {{{3
+    let type_basic = s:TypeInfo.New()
+    let type_basic.ctagstype = 'basic'
+    let type_basic.kinds     = [
+        \ {'short' : 'c', 'long' : 'constants',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'g', 'long' : 'enumerations', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'l', 'long' : 'labels',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'types',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',    'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.basic = type_basic
+    " BETA {{{3
+    let type_beta = s:TypeInfo.New()
+    let type_beta.ctagstype = 'beta'
+    let type_beta.kinds     = [
+        \ {'short' : 'f', 'long' : 'fragments', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'slots',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'patterns',  'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.beta = type_beta
+    " C {{{3
+    let type_c = s:TypeInfo.New()
+    let type_c.ctagstype = 'c'
+    let type_c.kinds     = [
+        \ {'short' : 'd', 'long' : 'macros',      'fold' : 1, 'stl' : 0},
+        \ {'short' : 'p', 'long' : 'prototypes',  'fold' : 1, 'stl' : 0},
+        \ {'short' : 'g', 'long' : 'enums',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'enumerators', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 't', 'long' : 'typedefs',    'fold' : 0, 'stl' : 0},
+        \ {'short' : 's', 'long' : 'structs',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'u', 'long' : 'unions',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'members',     'fold' : 0, 'stl' : 0},
+        \ {'short' : 'v', 'long' : 'variables',   'fold' : 0, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'functions',   'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_c.sro        = '::'
+    let type_c.kind2scope = {
+        \ 'g' : 'enum',
+        \ 's' : 'struct',
+        \ 'u' : 'union'
+    \ }
+    let type_c.scope2kind = {
+        \ 'enum'   : 'g',
+        \ 'struct' : 's',
+        \ 'union'  : 'u'
+    \ }
+    let s:known_types.c = type_c
+    " C++ {{{3
+    let type_cpp = s:TypeInfo.New()
+    let type_cpp.ctagstype = 'c++'
+    let type_cpp.kinds     = [
+        \ {'short' : 'd', 'long' : 'macros',      'fold' : 1, 'stl' : 0},
+        \ {'short' : 'p', 'long' : 'prototypes',  'fold' : 1, 'stl' : 0},
+        \ {'short' : 'g', 'long' : 'enums',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'enumerators', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 't', 'long' : 'typedefs',    'fold' : 0, 'stl' : 0},
+        \ {'short' : 'n', 'long' : 'namespaces',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'classes',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'structs',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'u', 'long' : 'unions',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'members',     'fold' : 0, 'stl' : 0},
+        \ {'short' : 'v', 'long' : 'variables',   'fold' : 0, 'stl' : 0}
+    \ ]
+    let type_cpp.sro        = '::'
+    let type_cpp.kind2scope = {
+        \ 'g' : 'enum',
+        \ 'n' : 'namespace',
+        \ 'c' : 'class',
+        \ 's' : 'struct',
+        \ 'u' : 'union'
+    \ }
+    let type_cpp.scope2kind = {
+        \ 'enum'      : 'g',
+        \ 'namespace' : 'n',
+        \ 'class'     : 'c',
+        \ 'struct'    : 's',
+        \ 'union'     : 'u'
+    \ }
+    let s:known_types.cpp = type_cpp
+    " C# {{{3
+    let type_cs = s:TypeInfo.New()
+    let type_cs.ctagstype = 'c#'
+    let type_cs.kinds     = [
+        \ {'short' : 'd', 'long' : 'macros',      'fold' : 1, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'fields',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 'g', 'long' : 'enums',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'enumerators', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 't', 'long' : 'typedefs',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'n', 'long' : 'namespaces',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'i', 'long' : 'interfaces',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'classes',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'structs',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'E', 'long' : 'events',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'methods',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'properties',  'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_cs.sro        = '.'
+    let type_cs.kind2scope = {
+        \ 'n' : 'namespace',
+        \ 'i' : 'interface',
+        \ 'c' : 'class',
+        \ 's' : 'struct',
+        \ 'g' : 'enum'
+    \ }
+    let type_cs.scope2kind = {
+        \ 'namespace' : 'n',
+        \ 'interface' : 'i',
+        \ 'class'     : 'c',
+        \ 'struct'    : 's',
+        \ 'enum'      : 'g'
+    \ }
+    let s:known_types.cs = type_cs
+    " COBOL {{{3
+    let type_cobol = s:TypeInfo.New()
+    let type_cobol.ctagstype = 'cobol'
+    let type_cobol.kinds     = [
+        \ {'short' : 'd', 'long' : 'data items',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'file descriptions', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'g', 'long' : 'group items',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'paragraphs',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'P', 'long' : 'program ids',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'sections',          'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.cobol = type_cobol
+    " DOS Batch {{{3
+    let type_dosbatch = s:TypeInfo.New()
+    let type_dosbatch.ctagstype = 'dosbatch'
+    let type_dosbatch.kinds     = [
+        \ {'short' : 'l', 'long' : 'labels',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.dosbatch = type_dosbatch
+    " Eiffel {{{3
+    let type_eiffel = s:TypeInfo.New()
+    let type_eiffel.ctagstype = 'eiffel'
+    let type_eiffel.kinds     = [
+        \ {'short' : 'c', 'long' : 'classes',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'features', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_eiffel.sro        = '.' " Not sure, is nesting even possible?
+    let type_eiffel.kind2scope = {
+        \ 'c' : 'class',
+        \ 'f' : 'feature'
+    \ }
+    let type_eiffel.scope2kind = {
+        \ 'class'   : 'c',
+        \ 'feature' : 'f'
+    \ }
+    let s:known_types.eiffel = type_eiffel
+    " Erlang {{{3
+    let type_erlang = s:TypeInfo.New()
+    let type_erlang.ctagstype = 'erlang'
+    let type_erlang.kinds     = [
+        \ {'short' : 'm', 'long' : 'modules',            'fold' : 0, 'stl' : 1},
+        \ {'short' : 'd', 'long' : 'macro definitions',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'r', 'long' : 'record definitions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_erlang.sro        = '.' " Not sure, is nesting even possible?
+    let type_erlang.kind2scope = {
+        \ 'm' : 'module'
+    \ }
+    let type_erlang.scope2kind = {
+        \ 'module' : 'm'
+    \ }
+    let s:known_types.erlang = type_erlang
+    " Flex {{{3
+    " Vim doesn't support Flex out of the box, this is based on rough
+    " guesses and probably requires
+    " http://www.vim.org/scripts/script.php?script_id=2909
+    " Improvements welcome!
+    let type_as = s:TypeInfo.New()
+    let type_as.ctagstype = 'flex'
+    let type_as.kinds     = [
+        \ {'short' : 'v', 'long' : 'global variables', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 'c', 'long' : 'classes',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'methods',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'properties',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'x', 'long' : 'mxtags',           'fold' : 0, 'stl' : 0}
+    \ ]
+    let type_as.sro        = '.'
+    let type_as.kind2scope = {
+        \ 'c' : 'class'
+    \ }
+    let type_as.scope2kind = {
+        \ 'class' : 'c'
+    \ }
+    let s:known_types.mxml = type_as
+    let s:known_types.actionscript = type_as
+    " Fortran {{{3
+    let type_fortran = s:TypeInfo.New()
+    let type_fortran.ctagstype = 'fortran'
+    let type_fortran.kinds     = [
+        \ {'short' : 'm', 'long' : 'modules',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'programs',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'k', 'long' : 'components', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'derived types and structures', 'fold' : 0,
+         \ 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'common blocks', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'b', 'long' : 'block data',    'fold' : 0, 'stl' : 0},
+        \ {'short' : 'e', 'long' : 'entry points',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'subroutines',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'l', 'long' : 'labels',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'n', 'long' : 'namelists',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',     'fold' : 0, 'stl' : 0}
+    \ ]
+    let type_fortran.sro        = '.' " Not sure, is nesting even possible?
+    let type_fortran.kind2scope = {
+        \ 'm' : 'module',
+        \ 'p' : 'program',
+        \ 'f' : 'function',
+        \ 's' : 'subroutine'
+    \ }
+    let type_fortran.scope2kind = {
+        \ 'module'     : 'm',
+        \ 'program'    : 'p',
+        \ 'function'   : 'f',
+        \ 'subroutine' : 's'
+    \ }
+    let s:known_types.fortran = type_fortran
+    " HTML {{{3
+    let type_html = s:TypeInfo.New()
+    let type_html.ctagstype = 'html'
+    let type_html.kinds     = [
+        \ {'short' : 'f', 'long' : 'JavaScript funtions', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'a', 'long' : 'named anchors',       'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.html = type_html
+    " Java {{{3
+    let type_java = s:TypeInfo.New()
+    let type_java.ctagstype = 'java'
+    let type_java.kinds     = [
+        \ {'short' : 'p', 'long' : 'packages',       'fold' : 1, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'fields',         'fold' : 0, 'stl' : 0},
+        \ {'short' : 'g', 'long' : 'enum types',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'enum constants', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 'i', 'long' : 'interfaces',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'classes',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'methods',        'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_java.sro        = '.'
+    let type_java.kind2scope = {
+        \ 'g' : 'enum',
+        \ 'i' : 'interface',
+        \ 'c' : 'class'
+    \ }
+    let type_java.scope2kind = {
+        \ 'enum'      : 'g',
+        \ 'interface' : 'i',
+        \ 'class'     : 'c'
+    \ }
+    let s:known_types.java = type_java
+    " JavaScript {{{3
+    " JavaScript is weird -- it does have scopes, but ctags doesn't seem to
+    " properly generate the information for them, instead it simply uses the
+    " complete name. So ctags has to be fixed before I can do anything here.
+    " Alternatively jsctags/doctorjs will be used if available.
+    let type_javascript = s:TypeInfo.New()
+    let type_javascript.ctagstype = 'javascript'
+    let jsctags = s:CheckFTCtags('jsctags', 'javascript')
+    if jsctags != ''
+        let type_javascript.kinds = [
+            \ {'short' : 'v', 'long' : 'variables', 'fold' : 0, 'stl' : 0},
+            \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1}
+        \ ]
+        let type_javascript.sro        = '.'
+        let type_javascript.kind2scope = {
+            \ 'v' : 'namespace',
+            \ 'f' : 'namespace'
+        \ }
+        let type_javascript.scope2kind = {
+            \ 'namespace' : 'v'
+        \ }
+        let type_javascript.ctagsbin   = jsctags
+        let type_javascript.ctagsargs  = '-f -'
+    else
+        let type_javascript.kinds = [
+            \ {'short' : 'v', 'long' : 'global variables', 'fold' : 0, 'stl' : 0},
+            \ {'short' : 'c', 'long' : 'classes',          'fold' : 0, 'stl' : 1},
+            \ {'short' : 'p', 'long' : 'properties',       'fold' : 0, 'stl' : 0},
+            \ {'short' : 'm', 'long' : 'methods',          'fold' : 0, 'stl' : 1},
+            \ {'short' : 'f', 'long' : 'functions',        'fold' : 0, 'stl' : 1}
+        \ ]
+    endif
+    let s:known_types.javascript = type_javascript
+    " Lisp {{{3
+    let type_lisp = s:TypeInfo.New()
+    let type_lisp.ctagstype = 'lisp'
+    let type_lisp.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.lisp = type_lisp
+    let s:known_types.clojure = type_lisp
+    " Lua {{{3
+    let type_lua = s:TypeInfo.New()
+    let type_lua.ctagstype = 'lua'
+    let type_lua.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.lua = type_lua
+    " Make {{{3
+    let type_make = s:TypeInfo.New()
+    let type_make.ctagstype = 'make'
+    let type_make.kinds     = [
+        \ {'short' : 'm', 'long' : 'macros', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.make = type_make
+    " Matlab {{{3
+    let type_matlab = s:TypeInfo.New()
+    let type_matlab.ctagstype = 'matlab'
+    let type_matlab.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.matlab = type_matlab
+    " Ocaml {{{3
+    let type_ocaml = s:TypeInfo.New()
+    let type_ocaml.ctagstype = 'ocaml'
+    let type_ocaml.kinds     = [
+        \ {'short' : 'M', 'long' : 'modules or functors', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'global variables',    'fold' : 0, 'stl' : 0},
+        \ {'short' : 'c', 'long' : 'classes',             'fold' : 0, 'stl' : 1},
+        \ {'short' : 'C', 'long' : 'constructors',        'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'methods',             'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'exceptions',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'type names',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'r', 'long' : 'structure fields',    'fold' : 0, 'stl' : 0}
+    \ ]
+    let type_ocaml.sro        = '.' " Not sure, is nesting even possible?
+    let type_ocaml.kind2scope = {
+        \ 'M' : 'Module',
+        \ 'c' : 'class',
+        \ 't' : 'type'
+    \ }
+    let type_ocaml.scope2kind = {
+        \ 'Module' : 'M',
+        \ 'class'  : 'c',
+        \ 'type'   : 't'
+    \ }
+    let s:known_types.ocaml = type_ocaml
+    " Pascal {{{3
+    let type_pascal = s:TypeInfo.New()
+    let type_pascal.ctagstype = 'pascal'
+    let type_pascal.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'procedures', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.pascal = type_pascal
+    " Perl {{{3
+    let type_perl = s:TypeInfo.New()
+    let type_perl.ctagstype = 'perl'
+    let type_perl.kinds     = [
+        \ {'short' : 'p', 'long' : 'packages',    'fold' : 1, 'stl' : 0},
+        \ {'short' : 'c', 'long' : 'constants',   'fold' : 0, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'formats',     'fold' : 0, 'stl' : 0},
+        \ {'short' : 'l', 'long' : 'labels',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'subroutines', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.perl = type_perl
+    " PHP {{{3
+    let type_php = s:TypeInfo.New()
+    let type_php.ctagstype = 'php'
+    let type_php.kinds     = [
+        \ {'short' : 'i', 'long' : 'interfaces',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'classes',              'fold' : 0, 'stl' : 1},
+        \ {'short' : 'd', 'long' : 'constant definitions', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'functions',            'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',            'fold' : 0, 'stl' : 0},
+        \ {'short' : 'j', 'long' : 'javascript functions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.php = type_php
+    " Python {{{3
+    let type_python = s:TypeInfo.New()
+    let type_python.ctagstype = 'python'
+    let type_python.kinds     = [
+        \ {'short' : 'i', 'long' : 'imports',   'fold' : 1, 'stl' : 0},
+        \ {'short' : 'c', 'long' : 'classes',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'members',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables', 'fold' : 0, 'stl' : 0}
+    \ ]
+    let type_python.sro        = '.'
+    let type_python.kind2scope = {
+        \ 'c' : 'class',
+        \ 'f' : 'function',
+        \ 'm' : 'function'
+    \ }
+    let type_python.scope2kind = {
+        \ 'class'    : 'c',
+        \ 'function' : 'f'
+    \ }
+    let s:known_types.python = type_python
+    " REXX {{{3
+    let type_rexx = s:TypeInfo.New()
+    let type_rexx.ctagstype = 'rexx'
+    let type_rexx.kinds     = [
+        \ {'short' : 's', 'long' : 'subroutines', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.rexx = type_rexx
+    " Ruby {{{3
+    let type_ruby = s:TypeInfo.New()
+    let type_ruby.ctagstype = 'ruby'
+    let type_ruby.kinds     = [
+        \ {'short' : 'm', 'long' : 'modules',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'classes',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'methods',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'F', 'long' : 'singleton methods', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_ruby.sro        = '.'
+    let type_ruby.kind2scope = {
+        \ 'c' : 'class',
+        \ 'm' : 'class'
+    \ }
+    let type_ruby.scope2kind = {
+        \ 'class' : 'c'
+    \ }
+    let s:known_types.ruby = type_ruby
+    " Scheme {{{3
+    let type_scheme = s:TypeInfo.New()
+    let type_scheme.ctagstype = 'scheme'
+    let type_scheme.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'sets',      'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.scheme = type_scheme
+    " Shell script {{{3
+    let type_sh = s:TypeInfo.New()
+    let type_sh.ctagstype = 'sh'
+    let type_sh.kinds     = [
+        \ {'short' : 'f', 'long' : 'functions', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.sh = type_sh
+    let s:known_types.csh = type_sh
+    let s:known_types.zsh = type_sh
+    " SLang {{{3
+    let type_slang = s:TypeInfo.New()
+    let type_slang.ctagstype = 'slang'
+    let type_slang.kinds     = [
+        \ {'short' : 'n', 'long' : 'namespaces', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',  'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.slang = type_slang
+    " SML {{{3
+    let type_sml = s:TypeInfo.New()
+    let type_sml.ctagstype = 'sml'
+    let type_sml.kinds     = [
+        \ {'short' : 'e', 'long' : 'exception declarations', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'function definitions',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'functor definitions',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'signature declarations', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 'r', 'long' : 'structure declarations', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 't', 'long' : 'type definitions',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'value bindings',         'fold' : 0, 'stl' : 0}
+    \ ]
+    let s:known_types.sml = type_sml
+    " SQL {{{3
+    " The SQL ctags parser seems to be buggy for me, so this just uses the
+    " normal kinds even though scopes should be available. Improvements
+    " welcome!
+    let type_sql = s:TypeInfo.New()
+    let type_sql.ctagstype = 'sql'
+    let type_sql.kinds     = [
+        \ {'short' : 'P', 'long' : 'packages',               'fold' : 1, 'stl' : 1},
+        \ {'short' : 'd', 'long' : 'prototypes',             'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'cursors',                'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',              'fold' : 0, 'stl' : 1},
+        \ {'short' : 'F', 'long' : 'record fields',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'L', 'long' : 'block label',            'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'procedures',             'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'subtypes',               'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'tables',                 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'T', 'long' : 'triggers',               'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',              'fold' : 0, 'stl' : 1},
+        \ {'short' : 'i', 'long' : 'indexes',                'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'events',                 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'U', 'long' : 'publications',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'R', 'long' : 'services',               'fold' : 0, 'stl' : 1},
+        \ {'short' : 'D', 'long' : 'domains',                'fold' : 0, 'stl' : 1},
+        \ {'short' : 'V', 'long' : 'views',                  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'n', 'long' : 'synonyms',               'fold' : 0, 'stl' : 1},
+        \ {'short' : 'x', 'long' : 'MobiLink Table Scripts', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'y', 'long' : 'MobiLink Conn Scripts',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'z', 'long' : 'MobiLink Properties',    'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.sql = type_sql
+    " Tcl {{{3
+    let type_tcl = s:TypeInfo.New()
+    let type_tcl.ctagstype = 'tcl'
+    let type_tcl.kinds     = [
+        \ {'short' : 'c', 'long' : 'classes',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'methods',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'procedures', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.tcl = type_tcl
+    " LaTeX {{{3
+    let type_tex = s:TypeInfo.New()
+    let type_tex.ctagstype = 'tex'
+    let type_tex.kinds     = [
+        \ {'short' : 'i', 'long' : 'includes',       'fold' : 1, 'stl' : 0},
+        \ {'short' : 'p', 'long' : 'parts',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'chapters',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 's', 'long' : 'sections',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'u', 'long' : 'subsections',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'b', 'long' : 'subsubsections', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 'P', 'long' : 'paragraphs',     'fold' : 0, 'stl' : 0},
+        \ {'short' : 'G', 'long' : 'subparagraphs',  'fold' : 0, 'stl' : 0},
+        \ {'short' : 'l', 'long' : 'labels',         'fold' : 0, 'stl' : 0}
+    \ ]
+    let type_tex.sro        = '""'
+    let type_tex.kind2scope = {
+        \ 'p' : 'part',
+        \ 'c' : 'chapter',
+        \ 's' : 'section',
+        \ 'u' : 'subsection',
+        \ 'b' : 'subsubsection'
+    \ }
+    let type_tex.scope2kind = {
+        \ 'part'          : 'p',
+        \ 'chapter'       : 'c',
+        \ 'section'       : 's',
+        \ 'subsection'    : 'u',
+        \ 'subsubsection' : 'b'
+    \ }
+    let type_tex.sort = 0
+    let s:known_types.tex = type_tex
+    " Vala {{{3
+    " Vala is supported by the ctags fork provided by Anjuta, so only add the
+    " type if the fork is used to prevent error messages otherwise
+    if has_key(s:ctags_types, 'vala') || executable('anjuta-tags')
+        let type_vala = s:TypeInfo.New()
+        let type_vala.ctagstype = 'vala'
+        let type_vala.kinds     = [
+            \ {'short' : 'e', 'long' : 'Enumerations',       'fold' : 0, 'stl' : 1},
+            \ {'short' : 'v', 'long' : 'Enumeration values', 'fold' : 0, 'stl' : 0},
+            \ {'short' : 's', 'long' : 'Structures',         'fold' : 0, 'stl' : 1},
+            \ {'short' : 'i', 'long' : 'Interfaces',         'fold' : 0, 'stl' : 1},
+            \ {'short' : 'd', 'long' : 'Delegates',          'fold' : 0, 'stl' : 1},
+            \ {'short' : 'c', 'long' : 'Classes',            'fold' : 0, 'stl' : 1},
+            \ {'short' : 'p', 'long' : 'Properties',         'fold' : 0, 'stl' : 0},
+            \ {'short' : 'f', 'long' : 'Fields',             'fold' : 0, 'stl' : 0},
+            \ {'short' : 'm', 'long' : 'Methods',            'fold' : 0, 'stl' : 1},
+            \ {'short' : 'E', 'long' : 'Error domains',      'fold' : 0, 'stl' : 1},
+            \ {'short' : 'r', 'long' : 'Error codes',        'fold' : 0, 'stl' : 1},
+            \ {'short' : 'S', 'long' : 'Signals',            'fold' : 0, 'stl' : 1}
+        \ ]
+        let type_vala.sro = '.'
+        " 'enum' doesn't seem to be used as a scope, but it can't hurt to have
+        " it here
+        let type_vala.kind2scope = {
+            \ 's' : 'struct',
+            \ 'i' : 'interface',
+            \ 'c' : 'class',
+            \ 'e' : 'enum'
+        \ }
+        let type_vala.scope2kind = {
+            \ 'struct'    : 's',
+            \ 'interface' : 'i',
+            \ 'class'     : 'c',
+            \ 'enum'      : 'e'
+        \ }
+        let s:known_types.vala = type_vala
+    endif
+    if !has_key(s:ctags_types, 'vala') && executable('anjuta-tags')
+        let s:known_types.vala.ctagsbin = 'anjuta-tags'
+    endif
+    " Vera {{{3
+    " Why are variables 'virtual'?
+    let type_vera = s:TypeInfo.New()
+    let type_vera.ctagstype = 'vera'
+    let type_vera.kinds     = [
+        \ {'short' : 'd', 'long' : 'macros',      'fold' : 1, 'stl' : 0},
+        \ {'short' : 'g', 'long' : 'enums',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'T', 'long' : 'typedefs',    'fold' : 0, 'stl' : 0},
+        \ {'short' : 'c', 'long' : 'classes',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'enumerators', 'fold' : 0, 'stl' : 0},
+        \ {'short' : 'm', 'long' : 'members',     'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'tasks',       'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',   'fold' : 0, 'stl' : 0},
+        \ {'short' : 'p', 'long' : 'programs',    'fold' : 0, 'stl' : 1}
+    \ ]
+    let type_vera.sro        = '.' " Nesting doesn't seem to be possible
+    let type_vera.kind2scope = {
+        \ 'g' : 'enum',
+        \ 'c' : 'class',
+        \ 'v' : 'virtual'
+    \ }
+    let type_vera.scope2kind = {
+        \ 'enum'      : 'g',
+        \ 'class'     : 'c',
+        \ 'virtual'   : 'v'
+    \ }
+    let s:known_types.vera = type_vera
+    " Verilog {{{3
+    let type_verilog = s:TypeInfo.New()
+    let type_verilog.ctagstype = 'verilog'
+    let type_verilog.kinds     = [
+        \ {'short' : 'c', 'long' : 'constants',           'fold' : 0, 'stl' : 0},
+        \ {'short' : 'e', 'long' : 'events',              'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',           'fold' : 0, 'stl' : 1},
+        \ {'short' : 'm', 'long' : 'modules',             'fold' : 0, 'stl' : 1},
+        \ {'short' : 'n', 'long' : 'net data types',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'ports',               'fold' : 0, 'stl' : 1},
+        \ {'short' : 'r', 'long' : 'register data types', 'fold' : 0, 'stl' : 1},
+        \ {'short' : 't', 'long' : 'tasks',               'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.verilog = type_verilog
+    " VHDL {{{3
+    " The VHDL ctags parser unfortunately doesn't generate proper scopes
+    let type_vhdl = s:TypeInfo.New()
+    let type_vhdl.ctagstype = 'vhdl'
+    let type_vhdl.kinds     = [
+        \ {'short' : 'P', 'long' : 'packages',   'fold' : 1, 'stl' : 0},
+        \ {'short' : 'c', 'long' : 'constants',  'fold' : 0, 'stl' : 0},
+        \ {'short' : 't', 'long' : 'types',      'fold' : 0, 'stl' : 1},
+        \ {'short' : 'T', 'long' : 'subtypes',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'r', 'long' : 'records',    'fold' : 0, 'stl' : 1},
+        \ {'short' : 'e', 'long' : 'entities',   'fold' : 0, 'stl' : 1},
+        \ {'short' : 'f', 'long' : 'functions',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'p', 'long' : 'procedures', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.vhdl = type_vhdl
+    " Vim {{{3
+    let type_vim = s:TypeInfo.New()
+    let type_vim.ctagstype = 'vim'
+    let type_vim.kinds     = [
+        \ {'short' : 'n', 'long' : 'vimball filenames',  'fold' : 0, 'stl' : 1},
+        \ {'short' : 'v', 'long' : 'variables',          'fold' : 1, 'stl' : 0},
+        \ {'short' : 'f', 'long' : 'functions',          'fold' : 0, 'stl' : 1},
+        \ {'short' : 'a', 'long' : 'autocommand groups', 'fold' : 1, 'stl' : 1},
+        \ {'short' : 'c', 'long' : 'commands',           'fold' : 0, 'stl' : 0},
+        \ {'short' : 'm', 'long' : 'maps',               'fold' : 1, 'stl' : 0}
+    \ ]
+    let s:known_types.vim = type_vim
+    " YACC {{{3
+    let type_yacc = s:TypeInfo.New()
+    let type_yacc.ctagstype = 'yacc'
+    let type_yacc.kinds     = [
+        \ {'short' : 'l', 'long' : 'labels', 'fold' : 0, 'stl' : 1}
+    \ ]
+    let s:known_types.yacc = type_yacc
+    " }}}3
+
+    call s:LoadUserTypeDefs()
+
+    for type in values(s:known_types)
+        call s:CreateTypeKinddict(type)
+    endfor
+
+    let s:type_init_done = 1
+endfunction
+
+" s:LoadUserTypeDefs() {{{2
+function! s:LoadUserTypeDefs(...) abort
+    if a:0 > 0
+        let type = a:1
+
+        call s:LogDebugMessage("Initializing user type '" . type . "'")
+
+        let defdict = {}
+        let defdict[type] = g:tagbar_type_{type}
+    else
+        call s:LogDebugMessage('Initializing user types')
+
+        let defdict = tagbar#getusertypes()
+    endif
+
+    " Transform the 'kind' definitions into dictionary format
+    for def in values(defdict)
+        if has_key(def, 'kinds')
+            let kinds = def.kinds
+            let def.kinds = []
+            for kind in kinds
+                let kindlist = split(kind, ':')
+                let kinddict = {'short' : kindlist[0], 'long' : kindlist[1]}
+                if len(kindlist) == 4
+                    let kinddict.fold = kindlist[2]
+                    let kinddict.stl  = kindlist[3]
+                elseif len(kindlist) == 3
+                    let kinddict.fold = kindlist[2]
+                    let kinddict.stl  = 1
+                else
+                    let kinddict.fold = 0
+                    let kinddict.stl  = 1
+                endif
+                call add(def.kinds, kinddict)
+            endfor
+        endif
+
+        " If the user only specified one of kind2scope and scope2kind use it
+        " to generate the other one
+        if has_key(def, 'kind2scope') && !has_key(def, 'scope2kind')
+            let def.scope2kind = {}
+            for [key, value] in items(def.kind2scope)
+                let def.scope2kind[value] = key
+            endfor
+        elseif has_key(def, 'scope2kind') && !has_key(def, 'kind2scope')
+            let def.kind2scope = {}
+            for [key, value] in items(def.scope2kind)
+                let def.kind2scope[value] = key
+            endfor
+        endif
+    endfor
+    unlet! key value
+
+    for [key, value] in items(defdict)
+        if !has_key(s:known_types, key) ||
+         \ (has_key(value, 'replace') && value.replace)
+            let s:known_types[key] = s:TypeInfo.New(value)
+        else
+            call extend(s:known_types[key], value)
+        endif
+    endfor
+
+    if a:0 > 0
+        call s:CreateTypeKinddict(s:known_types[type])
+    endif
+endfunction
+
+" s:CreateTypeKinddict() {{{2
+function! s:CreateTypeKinddict(type) abort
+    " Create a dictionary of the kind order for fast access in sorting
+    " functions
+    let i = 0
+    for kind in a:type.kinds
+        let a:type.kinddict[kind.short] = i
+        let i += 1
+    endfor
+endfunction
+
+" s:RestoreSession() {{{2
+" Properly restore Tagbar after a session got loaded
+function! s:RestoreSession() abort
+    call s:LogDebugMessage('Restoring session')
+
+    let curfile = fnamemodify(bufname('%'), ':p')
+
+    let tagbarwinnr = bufwinnr('__Tagbar__')
+    if tagbarwinnr == -1
+        " Tagbar wasn't open in the saved session, nothing to do
+        return
+    else
+        let in_tagbar = 1
+        if winnr() != tagbarwinnr
+            call s:winexec(tagbarwinnr . 'wincmd w')
+            let in_tagbar = 0
+        endif
+    endif
+
+    let s:last_autofocus = 0
+
+    call s:Init(0)
+
+    call s:InitWindow(g:tagbar_autoclose)
+
+    call s:AutoUpdate(curfile, 0)
+
+    if !in_tagbar
+        call s:winexec('wincmd p')
+    endif
+endfunction
+
+" s:MapKeys() {{{2
+function! s:MapKeys() abort
+    call s:LogDebugMessage('Mapping keys')
+
+    nnoremap <script> <silent> <buffer> <2-LeftMouse>
+                                              \ :call <SID>JumpToTag(0)<CR>
+    nnoremap <script> <silent> <buffer> <LeftRelease>
+                                 \ <LeftRelease>:call <SID>CheckMouseClick()<CR>
+
+    inoremap <script> <silent> <buffer> <2-LeftMouse>
+                                              \ <C-o>:call <SID>JumpToTag(0)<CR>
+    inoremap <script> <silent> <buffer> <LeftRelease>
+                            \ <LeftRelease><C-o>:call <SID>CheckMouseClick()<CR>
+
+    nnoremap <script> <silent> <buffer> <CR>    :call <SID>JumpToTag(0)<CR>
+    nnoremap <script> <silent> <buffer> p       :call <SID>JumpToTag(1)<CR>
+    nnoremap <script> <silent> <buffer> <Space> :call <SID>ShowPrototype(0)<CR>
+
+    nnoremap <script> <silent> <buffer> +        :call <SID>OpenFold()<CR>
+    nnoremap <script> <silent> <buffer> <kPlus>  :call <SID>OpenFold()<CR>
+    nnoremap <script> <silent> <buffer> zo       :call <SID>OpenFold()<CR>
+    nnoremap <script> <silent> <buffer> -        :call <SID>CloseFold()<CR>
+    nnoremap <script> <silent> <buffer> <kMinus> :call <SID>CloseFold()<CR>
+    nnoremap <script> <silent> <buffer> zc       :call <SID>CloseFold()<CR>
+    nnoremap <script> <silent> <buffer> o        :call <SID>ToggleFold()<CR>
+    nnoremap <script> <silent> <buffer> za       :call <SID>ToggleFold()<CR>
+
+    nnoremap <script> <silent> <buffer> *    :call <SID>SetFoldLevel(99, 1)<CR>
+    nnoremap <script> <silent> <buffer> <kMultiply>
+                                           \ :call <SID>SetFoldLevel(99, 1)<CR>
+    nnoremap <script> <silent> <buffer> zR   :call <SID>SetFoldLevel(99, 1)<CR>
+    nnoremap <script> <silent> <buffer> =    :call <SID>SetFoldLevel(0, 1)<CR>
+    nnoremap <script> <silent> <buffer> zM   :call <SID>SetFoldLevel(0, 1)<CR>
+
+    nnoremap <script> <silent> <buffer> <C-N>
+                                        \ :call <SID>GotoNextToplevelTag(1)<CR>
+    nnoremap <script> <silent> <buffer> <C-P>
+                                        \ :call <SID>GotoNextToplevelTag(-1)<CR>
+
+    nnoremap <script> <silent> <buffer> s    :call <SID>ToggleSort()<CR>
+    nnoremap <script> <silent> <buffer> x    :call <SID>ZoomWindow()<CR>
+    nnoremap <script> <silent> <buffer> q    :call <SID>CloseWindow()<CR>
+    nnoremap <script> <silent> <buffer> <F1> :call <SID>ToggleHelp()<CR>
+endfunction
+
+" s:CreateAutocommands() {{{2
+function! s:CreateAutocommands() abort
+    call s:LogDebugMessage('Creating autocommands')
+
+    augroup TagbarAutoCmds
+        autocmd!
+        autocmd BufEnter   __Tagbar__ nested call s:QuitIfOnlyWindow()
+        autocmd CursorHold __Tagbar__ call s:ShowPrototype(1)
+
+        autocmd BufReadPost,BufWritePost * call
+                    \ s:AutoUpdate(fnamemodify(expand('<afile>'), ':p'), 1)
+        autocmd BufEnter,CursorHold,FileType * call
+                    \ s:AutoUpdate(fnamemodify(expand('<afile>'), ':p'), 0)
+        autocmd BufDelete,BufUnload,BufWipeout * call
+                    \ s:known_files.rm(fnamemodify(expand('<afile>'), ':p'))
+
+        autocmd VimEnter * call s:CorrectFocusOnStartup()
+    augroup END
+
+    let s:autocommands_done = 1
+    let s:autocommands_enabled = 1
+endfunction
+
+" s:PauseAutocommands() {{{2
+" Toggle autocommands 
+function! s:PauseAutocommands() abort
+    if s:autocommands_enabled == 1
+        autocmd! TagbarAutoCmds
+        let s:autocommands_enabled = 0
+    else
+        call s:CreateAutocommands()
+        call s:AutoUpdate(fnamemodify(expand('%'), ':p'), 0)
+    endif
+endfunction
+
+" s:CheckForExCtags() {{{2
+" Test whether the ctags binary is actually Exuberant Ctags and not GNU ctags
+" (or something else)
+function! s:CheckForExCtags(silent) abort
+    call s:LogDebugMessage('Checking for Exuberant Ctags')
+
+    if !exists('g:tagbar_ctags_bin')
+        let ctagsbins  = []
+        let ctagsbins += ['ctags-exuberant'] " Debian
+        let ctagsbins += ['exuberant-ctags']
+        let ctagsbins += ['exctags'] " FreeBSD, NetBSD
+        let ctagsbins += ['/usr/local/bin/ctags'] " Homebrew
+        let ctagsbins += ['/opt/local/bin/ctags'] " Macports
+        let ctagsbins += ['ectags'] " OpenBSD
+        let ctagsbins += ['ctags']
+        let ctagsbins += ['ctags.exe']
+        let ctagsbins += ['tags']
+        for ctags in ctagsbins
+            if executable(ctags)
+                let g:tagbar_ctags_bin = ctags
+                break
+            endif
+        endfor
+        if !exists('g:tagbar_ctags_bin')
+            if !a:silent
+                echoerr 'Tagbar: Exuberant ctags not found!'
+                echomsg 'Please download Exuberant Ctags from ctags.sourceforge.net'
+                      \ 'and install it in a directory in your $PATH'
+                      \ 'or set g:tagbar_ctags_bin.'
+            endif
+            let s:checked_ctags = 2
+            return 0
+        endif
+    else
+        " reset 'wildignore' temporarily in case *.exe is included in it
+        let wildignore_save = &wildignore
+        set wildignore&
+
+        let g:tagbar_ctags_bin = expand(g:tagbar_ctags_bin)
+
+        let &wildignore = wildignore_save
+
+        if !executable(g:tagbar_ctags_bin)
+            if !a:silent
+                echoerr "Tagbar: Exuberant ctags not found at " .
+                      \ "'" . g:tagbar_ctags_bin . "'!"
+                echomsg 'Please check your g:tagbar_ctags_bin setting.'
+            endif
+            let s:checked_ctags = 2
+            return 0
+        endif
+    endif
+
+    let ctags_cmd = s:EscapeCtagsCmd(g:tagbar_ctags_bin, '--version')
+    if ctags_cmd == ''
+        let s:checked_ctags = 2
+        return 0
+    endif
+
+    let ctags_output = s:ExecuteCtags(ctags_cmd)
+
+    if v:shell_error || ctags_output !~# 'Exuberant Ctags'
+        if !a:silent
+            echoerr 'Tagbar: Ctags doesn''t seem to be Exuberant Ctags!'
+            echomsg 'GNU ctags will NOT WORK.'
+                  \ 'Please download Exuberant Ctags from ctags.sourceforge.net'
+                  \ 'and install it in a directory in your $PATH'
+                  \ 'or set g:tagbar_ctags_bin.'
+            echomsg 'Executed command: "' . ctags_cmd . '"'
+            if !empty(ctags_output)
+                echomsg 'Command output:'
+                for line in split(ctags_output, '\n')
+                    echomsg line
+                endfor
+            endif
+        endif
+        let s:checked_ctags = 2
+        return 0
+    elseif !s:CheckExCtagsVersion(ctags_output)
+        if !a:silent
+            echoerr 'Tagbar: Exuberant Ctags is too old!'
+            echomsg 'You need at least version 5.5 for Tagbar to work.'
+                \ 'Please download a newer version from ctags.sourceforge.net.'
+            echomsg 'Executed command: "' . ctags_cmd . '"'
+            if !empty(ctags_output)
+                echomsg 'Command output:'
+                for line in split(ctags_output, '\n')
+                    echomsg line
+                endfor
+            endif
+        endif
+        let s:checked_ctags = 2
+        return 0
+    else
+        let s:checked_ctags = 1
+        return 1
+    endif
+endfunction
+
+" s:CheckExCtagsVersion() {{{2
+function! s:CheckExCtagsVersion(output) abort
+    call s:LogDebugMessage('Checking Exuberant Ctags version')
+
+    if a:output =~ 'Exuberant Ctags Development'
+        return 1
+    endif
+
+    let matchlist = matchlist(a:output, '\vExuberant Ctags (\d+)\.(\d+)')
+    let major     = matchlist[1]
+    let minor     = matchlist[2]
+
+    return major >= 6 || (major == 5 && minor >= 5)
+endfunction
+
+" s:CheckFTCtags() {{{2
+function! s:CheckFTCtags(bin, ftype) abort
+    if executable(a:bin)
+        return a:bin
+    endif
+
+    if exists('g:tagbar_type_' . a:ftype)
+        execute 'let userdef = ' . 'g:tagbar_type_' . a:ftype
+        if has_key(userdef, 'ctagsbin')
+            return userdef.ctagsbin
+        else
+            return ''
+        endif
+    endif
+
+    return ''
+endfunction
+
+" s:GetSupportedFiletypes() {{{2
+function! s:GetSupportedFiletypes() abort
+    call s:LogDebugMessage('Getting filetypes sypported by Exuberant Ctags')
+
+    let ctags_cmd = s:EscapeCtagsCmd(g:tagbar_ctags_bin, '--list-languages')
+    if ctags_cmd == ''
+        return
+    endif
+
+    let ctags_output = s:ExecuteCtags(ctags_cmd)
+
+    if v:shell_error
+        " this shouldn't happen as potential problems would have already been
+        " caught by the previous ctags checking
+        return
+    endif
+
+    let types = split(ctags_output, '\n\+')
+
+    for type in types
+        let s:ctags_types[tolower(type)] = 1
+    endfor
+
+    let s:checked_ctags_types = 1
+endfunction
+
+" Prototypes {{{1
+" Base tag {{{2
+let s:BaseTag = {}
+
+" s:BaseTag.New() {{{3
+function! s:BaseTag.New(name) abort dict
+    let newobj = copy(self)
+
+    call newobj._init(a:name)
+
+    return newobj
+endfunction
+
+" s:BaseTag._init() {{{3
+function! s:BaseTag._init(name) abort dict
+    let self.name          = a:name
+    let self.fields        = {}
+    let self.fields.line   = 0
+    let self.fields.column = 1
+    let self.prototype     = ''
+    let self.path          = ''
+    let self.fullpath      = a:name
+    let self.depth         = 0
+    let self.parent        = {}
+    let self.tline         = -1
+    let self.fileinfo      = {}
+    let self.typeinfo      = {}
+endfunction
+
+" s:BaseTag.isNormalTag() {{{3
+function! s:BaseTag.isNormalTag() abort dict
+    return 0
+endfunction
+
+" s:BaseTag.isPseudoTag() {{{3
+function! s:BaseTag.isPseudoTag() abort dict
+    return 0
+endfunction
+
+" s:BaseTag.isKindheader() {{{3
+function! s:BaseTag.isKindheader() abort dict
+    return 0
+endfunction
+
+" s:BaseTag.getPrototype() {{{3
+function! s:BaseTag.getPrototype(short) abort dict
+    return self.prototype
+endfunction
+
+" s:BaseTag._getPrefix() {{{3
+function! s:BaseTag._getPrefix() abort dict
+    let fileinfo = self.fileinfo
+
+    if has_key(self, 'children') && !empty(self.children)
+        if fileinfo.tagfolds[self.fields.kind][self.fullpath]
+            let prefix = s:icon_closed
+        else
+            let prefix = s:icon_open
+        endif
+    else
+        let prefix = ' '
+    endif
+    " Visibility is called 'access' in the ctags output
+    if g:tagbar_show_visibility
+        if has_key(self.fields, 'access')
+            let prefix .= get(s:visibility_symbols, self.fields.access, ' ')
+        else
+            let prefix .= ' '
+        endif
+    endif
+
+    return prefix
+endfunction
+
+" s:BaseTag.initFoldState() {{{3
+function! s:BaseTag.initFoldState() abort dict
+    let fileinfo = self.fileinfo
+
+    if s:known_files.has(fileinfo.fpath) &&
+     \ has_key(fileinfo, '_tagfolds_old') &&
+     \ has_key(fileinfo._tagfolds_old[self.fields.kind], self.fullpath)
+        " The file has been updated and the tag was there before, so copy its
+        " old fold state
+        let fileinfo.tagfolds[self.fields.kind][self.fullpath] =
+                    \ fileinfo._tagfolds_old[self.fields.kind][self.fullpath]
+    elseif self.depth >= fileinfo.foldlevel
+        let fileinfo.tagfolds[self.fields.kind][self.fullpath] = 1
+    else
+        let fileinfo.tagfolds[self.fields.kind][self.fullpath] =
+                    \ fileinfo.kindfolds[self.fields.kind]
+    endif
+endfunction
+
+" s:BaseTag.getClosedParentTline() {{{3
+function! s:BaseTag.getClosedParentTline() abort dict
+    let tagline  = self.tline
+    let fileinfo = self.fileinfo
+
+    " Find the first closed parent, starting from the top of the hierarchy.
+    let parents   = []
+    let curparent = self.parent
+    while !empty(curparent)
+        call add(parents, curparent)
+        let curparent = curparent.parent
+    endwhile
+    for parent in reverse(parents)
+        if parent.isFolded()
+            let tagline = parent.tline
+            break
+        endif
+    endfor
+
+    return tagline
+endfunction
+
+" s:BaseTag.isFoldable() {{{3
+function! s:BaseTag.isFoldable() abort dict
+    return has_key(self, 'children') && !empty(self.children)
+endfunction
+
+" s:BaseTag.isFolded() {{{3
+function! s:BaseTag.isFolded() abort dict
+    return self.fileinfo.tagfolds[self.fields.kind][self.fullpath]
+endfunction
+
+" s:BaseTag.openFold() {{{3
+function! s:BaseTag.openFold() abort dict
+    if self.isFoldable()
+        let self.fileinfo.tagfolds[self.fields.kind][self.fullpath] = 0
+    endif
+endfunction
+
+" s:BaseTag.closeFold() {{{3
+function! s:BaseTag.closeFold() abort dict
+    let newline = line('.')
+
+    if !empty(self.parent) && self.parent.isKindheader()
+        " Tag is child of generic 'kind'
+        call self.parent.closeFold()
+        let newline = self.parent.tline
+    elseif self.isFoldable() && !self.isFolded()
+        " Tag is parent of a scope and is not folded
+        let self.fileinfo.tagfolds[self.fields.kind][self.fullpath] = 1
+        let newline = self.tline
+    elseif !empty(self.parent)
+        " Tag is normal child, so close parent
+        let parent = self.parent
+        let self.fileinfo.tagfolds[parent.fields.kind][parent.fullpath] = 1
+        let newline = parent.tline
+    endif
+
+    return newline
+endfunction
+
+" s:BaseTag.setFolded() {{{3
+function! s:BaseTag.setFolded(folded) abort dict
+    let self.fileinfo.tagfolds[self.fields.kind][self.fullpath] = a:folded
+endfunction
+
+" s:BaseTag.openParents() {{{3
+function! s:BaseTag.openParents() abort dict
+    let parent = self.parent
+
+    while !empty(parent)
+        call parent.openFold()
+        let parent = parent.parent
+    endwhile
+endfunction
+
+" Normal tag {{{2
+let s:NormalTag = copy(s:BaseTag)
+
+" s:NormalTag.isNormalTag() {{{3
+function! s:NormalTag.isNormalTag() abort dict
+    return 1
+endfunction
+
+" s:NormalTag.strfmt() {{{3
+function! s:NormalTag.strfmt() abort dict
+    let fileinfo = self.fileinfo
+    let typeinfo = self.typeinfo
+
+    let suffix = get(self.fields, 'signature', '')
+    if has_key(self.fields, 'type')
+        let suffix .= ' : ' . self.fields.type
+    elseif has_key(typeinfo, 'kind2scope') &&
+         \ has_key(typeinfo.kind2scope, self.fields.kind)
+        let suffix .= ' : ' . typeinfo.kind2scope[self.fields.kind]
+    endif
+
+    return self._getPrefix() . self.name . suffix . "\n"
+endfunction
+
+" s:NormalTag.str() {{{3
+function! s:NormalTag.str(longsig, full) abort dict
+    if a:full && self.path != ''
+        let str = self.path . self.typeinfo.sro . self.name
+    else
+        let str = self.name
+    endif
+
+    if has_key(self.fields, 'signature')
+        if a:longsig
+            let str .= self.fields.signature
+        else
+            let str .= '()'
+        endif
+    endif
+
+    return str
+endfunction
+
+" s:NormalTag.getPrototype() {{{3
+function! s:NormalTag.getPrototype(short) abort dict
+    if self.prototype != ''
+        let prototype = self.prototype
+    else
+        let bufnr = self.fileinfo.bufnr
+
+        let line = getbufline(bufnr, self.fields.line)[0]
+        let list = split(line, '\zs')
+
+        let start = index(list, '(')
+        if start == -1
+            return substitute(line, '^\s\+', '', '')
+        endif
+
+        let opening = count(list, '(', 0, start)
+        let closing = count(list, ')', 0, start)
+        if closing >= opening
+            return substitute(line, '^\s\+', '', '')
+        endif
+
+        let balance = opening - closing
+
+        let prototype = line
+        let curlinenr = self.fields.line + 1
+        while balance > 0
+            let curline = getbufline(bufnr, curlinenr)[0]
+            let curlist = split(curline, '\zs')
+            let balance += count(curlist, '(')
+            let balance -= count(curlist, ')')
+            let prototype .= "\n" . curline
+            let curlinenr += 1
+        endwhile
+
+        let self.prototype = prototype
+    endif
+
+    if a:short
+        " join all lines and remove superfluous spaces
+        let prototype = substitute(prototype, '^\s\+', '', '')
+        let prototype = substitute(prototype, '\_s\+', ' ', 'g')
+        let prototype = substitute(prototype, '(\s\+', '(', 'g')
+        let prototype = substitute(prototype, '\s\+)', ')', 'g')
+        " Avoid hit-enter prompts
+        let maxlen = &columns - 12
+        if len(prototype) > maxlen
+            let prototype = prototype[:maxlen - 1 - 3]
+            let prototype .= '...'
+        endif
+    endif
+
+    return prototype
+endfunction
+
+" Pseudo tag {{{2
+let s:PseudoTag = copy(s:BaseTag)
+
+" s:PseudoTag.isPseudoTag() {{{3
+function! s:PseudoTag.isPseudoTag() abort dict
+    return 1
+endfunction
+
+" s:PseudoTag.strfmt() {{{3
+function! s:PseudoTag.strfmt() abort dict
+    let fileinfo = self.fileinfo
+    let typeinfo = self.typeinfo
+
+    let suffix = get(self.fields, 'signature', '')
+    if has_key(typeinfo.kind2scope, self.fields.kind)
+        let suffix .= ' : ' . typeinfo.kind2scope[self.fields.kind]
+    endif
+
+    return self._getPrefix() . self.name . '*' . suffix
+endfunction
+
+" Kind header {{{2
+let s:KindheaderTag = copy(s:BaseTag)
+
+" s:KindheaderTag.isKindheader() {{{3
+function! s:KindheaderTag.isKindheader() abort dict
+    return 1
+endfunction
+
+" s:KindheaderTag.getPrototype() {{{3
+function! s:KindheaderTag.getPrototype(short) abort dict
+    return self.name . ': ' .
+         \ self.numtags . ' ' . (self.numtags > 1 ? 'tags' : 'tag')
+endfunction
+
+" s:KindheaderTag.isFoldable() {{{3
+function! s:KindheaderTag.isFoldable() abort dict
+    return 1
+endfunction
+
+" s:KindheaderTag.isFolded() {{{3
+function! s:KindheaderTag.isFolded() abort dict
+    return self.fileinfo.kindfolds[self.short]
+endfunction
+
+" s:KindheaderTag.openFold() {{{3
+function! s:KindheaderTag.openFold() abort dict
+    let self.fileinfo.kindfolds[self.short] = 0
+endfunction
+
+" s:KindheaderTag.closeFold() {{{3
+function! s:KindheaderTag.closeFold() abort dict
+    let self.fileinfo.kindfolds[self.short] = 1
+    return line('.')
+endfunction
+
+" s:KindheaderTag.toggleFold() {{{3
+function! s:KindheaderTag.toggleFold() abort dict
+    let fileinfo = s:known_files.getCurrent()
+
+    let fileinfo.kindfolds[self.short] = !fileinfo.kindfolds[self.short]
+endfunction
+
+" Type info {{{2
+let s:TypeInfo = {}
+
+" s:TypeInfo.New() {{{3
+function! s:TypeInfo.New(...) abort dict
+    let newobj = copy(self)
+
+    let newobj.kinddict = {}
+
+    if a:0 > 0
+        call extend(newobj, a:1)
+    endif
+
+    return newobj
+endfunction
+
+" s:TypeInfo.getKind() {{{3
+function! s:TypeInfo.getKind(kind) abort dict
+    let idx = self.kinddict[a:kind]
+    return self.kinds[idx]
+endfunction
+
+" File info {{{2
+let s:FileInfo = {}
+
+" s:FileInfo.New() {{{3
+function! s:FileInfo.New(fname, ftype) abort dict
+    let newobj = copy(self)
+
+    " The complete file path
+    let newobj.fpath = a:fname
+
+    let newobj.bufnr = bufnr(a:fname)
+
+    " File modification time
+    let newobj.mtime = getftime(a:fname)
+
+    " The vim file type
+    let newobj.ftype = a:ftype
+
+    " List of the tags that are present in the file, sorted according to the
+    " value of 'g:tagbar_sort'
+    let newobj.tags = []
+
+    " Dictionary of the tags, indexed by line number in the file
+    let newobj.fline = {}
+
+    " Dictionary of the tags, indexed by line number in the tagbar
+    let newobj.tline = {}
+
+    " Dictionary of the folding state of 'kind's, indexed by short name
+    let newobj.kindfolds = {}
+    let typeinfo = s:known_types[a:ftype]
+    let newobj.typeinfo = typeinfo
+    " copy the default fold state from the type info
+    for kind in typeinfo.kinds
+        let newobj.kindfolds[kind.short] =
+                    \ g:tagbar_foldlevel == 0 ? 1 : kind.fold
+    endfor
+
+    " Dictionary of dictionaries of the folding state of individual tags,
+    " indexed by kind and full path
+    let newobj.tagfolds = {}
+    for kind in typeinfo.kinds
+        let newobj.tagfolds[kind.short] = {}
+    endfor
+
+    " The current foldlevel of the file
+    let newobj.foldlevel = g:tagbar_foldlevel
+
+    return newobj
+endfunction
+
+" s:FileInfo.reset() {{{3
+" Reset stuff that gets regenerated while processing a file and save the old
+" tag folds
+function! s:FileInfo.reset() abort dict
+    let self.mtime = getftime(self.fpath)
+    let self.tags  = []
+    let self.fline = {}
+    let self.tline = {}
+
+    let self._tagfolds_old = self.tagfolds
+    let self.tagfolds = {}
+
+    let typeinfo = s:known_types[self.ftype]
+    for kind in typeinfo.kinds
+        let self.tagfolds[kind.short] = {}
+    endfor
+endfunction
+
+" s:FileInfo.clearOldFolds() {{{3
+function! s:FileInfo.clearOldFolds() abort dict
+    if exists('self._tagfolds_old')
+        unlet self._tagfolds_old
+    endif
+endfunction
+
+" s:FileInfo.sortTags() {{{3
+function! s:FileInfo.sortTags() abort dict
+    if has_key(s:compare_typeinfo, 'sort')
+        if s:compare_typeinfo.sort
+            call s:SortTags(self.tags, 's:CompareByKind')
+        else
+            call s:SortTags(self.tags, 's:CompareByLine')
+        endif
+    elseif g:tagbar_sort
+        call s:SortTags(self.tags, 's:CompareByKind')
+    else
+        call s:SortTags(self.tags, 's:CompareByLine')
+    endif
+endfunction
+
+" s:FileInfo.openKindFold() {{{3
+function! s:FileInfo.openKindFold(kind) abort dict
+    let self.kindfolds[a:kind.short] = 0
+endfunction
+
+" s:FileInfo.closeKindFold() {{{3
+function! s:FileInfo.closeKindFold(kind) abort dict
+    let self.kindfolds[a:kind.short] = 1
+endfunction
+
+" Known files {{{2
+let s:known_files = {
+    \ '_current' : {},
+    \ '_files'   : {}
+\ }
+
+" s:known_files.getCurrent() {{{3
+function! s:known_files.getCurrent() abort dict
+    return self._current
+endfunction
+
+" s:known_files.setCurrent() {{{3
+function! s:known_files.setCurrent(fileinfo) abort dict
+    let self._current = a:fileinfo
+endfunction
+
+" s:known_files.get() {{{3
+function! s:known_files.get(fname) abort dict
+    return get(self._files, a:fname, {})
+endfunction
+
+" s:known_files.put() {{{3
+" Optional second argument is the filename
+function! s:known_files.put(fileinfo, ...) abort dict
+    if a:0 == 1
+        let self._files[a:1] = a:fileinfo
+    else
+        let fname = a:fileinfo.fpath
+        let self._files[fname] = a:fileinfo
+    endif
+endfunction
+
+" s:known_files.has() {{{3
+function! s:known_files.has(fname) abort dict
+    return has_key(self._files, a:fname)
+endfunction
+
+" s:known_files.rm() {{{3
+function! s:known_files.rm(fname) abort dict
+    if s:known_files.has(a:fname)
+        call remove(self._files, a:fname)
+    endif
+endfunction
+
+" Window management {{{1
+" s:ToggleWindow() {{{2
+function! s:ToggleWindow() abort
+    call s:LogDebugMessage('ToggleWindow called')
+
+    let tagbarwinnr = bufwinnr("__Tagbar__")
+    if tagbarwinnr != -1
+        call s:CloseWindow()
+        return
+    endif
+
+    call s:OpenWindow('')
+
+    call s:LogDebugMessage('ToggleWindow finished')
+endfunction
+
+" s:OpenWindow() {{{2
+function! s:OpenWindow(flags) abort
+    call s:LogDebugMessage("OpenWindow called with flags: '" . a:flags . "'")
+
+    let autofocus = a:flags =~# 'f'
+    let jump      = a:flags =~# 'j'
+    let autoclose = a:flags =~# 'c'
+
+    let curfile = fnamemodify(bufname('%'), ':p')
+    let curline = line('.')
+
+    " If the tagbar window is already open check jump flag
+    " Also set the autoclose flag if requested
+    let tagbarwinnr = bufwinnr('__Tagbar__')
+    if tagbarwinnr != -1
+        if winnr() != tagbarwinnr && jump
+            call s:winexec(tagbarwinnr . 'wincmd w')
+            call s:HighlightTag(1, 1, curline)
+        endif
+        call s:LogDebugMessage("OpenWindow finished, Tagbar already open")
+        return
+    endif
+
+    " This is only needed for the CorrectFocusOnStartup() function
+    let s:last_autofocus = autofocus
+
+    if !s:Init(0)
+        return 0
+    endif
+
+    " Expand the Vim window to accomodate for the Tagbar window if requested
+    if g:tagbar_expand && !s:window_expanded && has('gui_running')
+        let &columns += g:tagbar_width + 1
+        let s:window_expanded = 1
+    endif
+
+    let eventignore_save = &eventignore
+    set eventignore=all
+
+    let openpos = g:tagbar_left ? 'topleft vertical ' : 'botright vertical '
+    exe 'silent keepalt ' . openpos . g:tagbar_width . 'split ' . '__Tagbar__'
+
+    let &eventignore = eventignore_save
+
+    call s:InitWindow(autoclose)
+
+    call s:AutoUpdate(curfile, 0)
+    call s:HighlightTag(1, 1, curline)
+
+    if !(g:tagbar_autoclose || autofocus || g:tagbar_autofocus)
+        call s:winexec('wincmd p')
+    endif
+
+    call s:LogDebugMessage('OpenWindow finished')
+endfunction
+
+" s:InitWindow() {{{2
+function! s:InitWindow(autoclose) abort
+    call s:LogDebugMessage('InitWindow called with autoclose: ' . a:autoclose)
+
+    setlocal filetype=tagbar
+
+    setlocal noreadonly " in case the "view" mode is used
+    setlocal buftype=nofile
+    setlocal bufhidden=hide
+    setlocal noswapfile
+    setlocal nobuflisted
+    setlocal nomodifiable
+    setlocal nolist
+    setlocal nonumber
+    setlocal nowrap
+    setlocal winfixwidth
+    setlocal textwidth=0
+    setlocal nospell
+
+    if exists('+relativenumber')
+        setlocal norelativenumber
+    endif
+
+    setlocal nofoldenable
+    setlocal foldcolumn=0
+    " Reset fold settings in case a plugin set them globally to something
+    " expensive. Apparently 'foldexpr' gets executed even if 'foldenable' is
+    " off, and then for every appended line (like with :put).
+    setlocal foldmethod&
+    setlocal foldexpr&
+
+    " Earlier versions have a bug in local, evaluated statuslines
+    if v:version > 701 || (v:version == 701 && has('patch097'))
+        setlocal statusline=%!TagbarGenerateStatusline()
+    else
+        setlocal statusline=Tagbar
+    endif
+
+    let s:new_window = 1
+
+    let w:autoclose = a:autoclose
+
+    if has('balloon_eval')
+        setlocal balloonexpr=TagbarBalloonExpr()
+        set ballooneval
+    endif
+
+    let cpoptions_save = &cpoptions
+    set cpoptions&vim
+
+    if !hasmapto('JumpToTag', 'n')
+        call s:MapKeys()
+    endif
+
+    let &cpoptions = cpoptions_save
+
+    call s:LogDebugMessage('InitWindow finished')
+endfunction
+
+" s:CloseWindow() {{{2
+function! s:CloseWindow() abort
+    call s:LogDebugMessage('CloseWindow called')
+
+    let tagbarwinnr = bufwinnr('__Tagbar__')
+    if tagbarwinnr == -1
+        return
+    endif
+
+    let tagbarbufnr = winbufnr(tagbarwinnr)
+
+    if winnr() == tagbarwinnr
+        if winbufnr(2) != -1
+            " Other windows are open, only close the tagbar one
+
+            let curfile = s:known_files.getCurrent()
+
+            call s:winexec('close')
+
+            " Try to jump to the correct window after closing
+            call s:winexec('wincmd p')
+
+            if !empty(curfile)
+                let filebufnr = bufnr(curfile.fpath)
+
+                if bufnr('%') != filebufnr
+                    let filewinnr = bufwinnr(filebufnr)
+                    if filewinnr != -1
+                        call s:winexec(filewinnr . 'wincmd w')
+                    endif
+                endif
+            endif
+        endif
+    else
+        " Go to the tagbar window, close it and then come back to the
+        " original window
+        let curbufnr = bufnr('%')
+        call s:winexec(tagbarwinnr . 'wincmd w')
+        close
+        " Need to jump back to the original window only if we are not
+        " already in that window
+        let winnum = bufwinnr(curbufnr)
+        if winnr() != winnum
+            call s:winexec(winnum . 'wincmd w')
+        endif
+    endif
+
+    " If the Vim window has been expanded, and Tagbar is not open in any other
+    " tabpages, shrink the window again
+    if s:window_expanded
+        let tablist = []
+        for i in range(tabpagenr('$'))
+            call extend(tablist, tabpagebuflist(i + 1))
+        endfor
+
+        if index(tablist, tagbarbufnr) == -1
+            let &columns -= g:tagbar_width + 1
+            let s:window_expanded = 0
+        endif
+    endif
+
+    call s:LogDebugMessage('CloseWindow finished')
+endfunction
+
+" s:ZoomWindow() {{{2
+function! s:ZoomWindow() abort
+    if s:is_maximized
+        execute 'vert resize ' . g:tagbar_width
+        let s:is_maximized = 0
+    else
+        vert resize
+        let s:is_maximized = 1
+    endif
+endfunction
+
+" s:CorrectFocusOnStartup() {{{2
+" For whatever reason the focus will be on the Tagbar window if
+" tagbar#autoopen is used with a FileType autocommand on startup and
+" g:tagbar_left is set. This should work around it by jumping to the window of
+" the current file after startup.
+function! s:CorrectFocusOnStartup() abort
+    if bufwinnr('__Tagbar__') != -1 && !g:tagbar_autofocus && !s:last_autofocus
+        let curfile = s:known_files.getCurrent()
+        if !empty(curfile) && curfile.fpath != fnamemodify(bufname('%'), ':p')
+            let winnr = bufwinnr(curfile.fpath)
+            if winnr != -1
+                call s:winexec(winnr . 'wincmd w')
+            endif
+        endif
+    endif
+endfunction
+
+" Tag processing {{{1
+" s:ProcessFile() {{{2
+" Execute ctags and put the information into a 'FileInfo' object
+function! s:ProcessFile(fname, ftype) abort
+    call s:LogDebugMessage('ProcessFile called [' . a:fname . ']')
+
+    if !s:IsValidFile(a:fname, a:ftype)
+        call s:LogDebugMessage('Not a valid file, returning')
+        return
+    endif
+
+    " If the file has only been updated preserve the fold states, otherwise
+    " create a new entry
+    if s:known_files.has(a:fname) && !empty(s:known_files.get(a:fname))
+        let fileinfo = s:known_files.get(a:fname)
+        call fileinfo.reset()
+    else
+        let fileinfo = s:FileInfo.New(a:fname, a:ftype)
+    endif
+
+    " Use a temporary files for ctags processing instead of the original one.
+    " This allows using Tagbar for files accessed with netrw, and also doesn't
+    " slow down Tagbar for files that sit on slow network drives.
+    let tempfile = tempname()
+    let ext = fnamemodify(fileinfo.fpath, ':e')
+    if ext != ''
+        let tempfile .= '.' . ext
+    endif
+
+    call writefile(getbufline(fileinfo.bufnr, 1, '$'), tempfile)
+    let fileinfo.mtime = getftime(tempfile)
+
+    let ctags_output = s:ExecuteCtagsOnFile(tempfile, a:fname, a:ftype)
+
+    call delete(tempfile)
+
+    if ctags_output == -1
+        call s:LogDebugMessage('Ctags error when processing file')
+        " Put an empty entry into known_files so the error message is only
+        " shown once
+        call s:known_files.put({}, a:fname)
+        return
+    elseif ctags_output == ''
+        call s:LogDebugMessage('Ctags output empty')
+        " No need to go through the tag processing if there are no tags, and
+        " preserving the old fold state isn't necessary either
+        call s:known_files.put(s:FileInfo.New(a:fname, a:ftype), a:fname)
+        return
+    endif
+
+    let typeinfo = fileinfo.typeinfo
+
+    call s:LogDebugMessage('Filetype tag kinds: ' .
+                         \ string(keys(typeinfo.kinddict)))
+
+    " Parse the ctags output lines
+    call s:LogDebugMessage('Parsing ctags output')
+    let rawtaglist = split(ctags_output, '\n\+')
+    for line in rawtaglist
+        " skip comments
+        if line =~# '^!_TAG_'
+            continue
+        endif
+
+        let parts = split(line, ';"')
+        if len(parts) == 2 " Is a valid tag line
+            let taginfo = s:ParseTagline(parts[0], parts[1], typeinfo, fileinfo)
+            let fileinfo.fline[taginfo.fields.line] = taginfo
+            call add(fileinfo.tags, taginfo)
+        endif
+    endfor
+
+    " Process scoped tags
+    let processedtags = []
+    if has_key(typeinfo, 'kind2scope')
+        call s:LogDebugMessage('Processing scoped tags')
+
+        let scopedtags = []
+        let is_scoped = 'has_key(typeinfo.kind2scope, v:val.fields.kind) ||
+                       \ has_key(v:val, "scope")'
+        let scopedtags += filter(copy(fileinfo.tags), is_scoped)
+        call filter(fileinfo.tags, '!(' . is_scoped . ')')
+
+        call s:AddScopedTags(scopedtags, processedtags, {}, 0,
+                           \ typeinfo, fileinfo)
+
+        if !empty(scopedtags)
+            echoerr 'Tagbar: ''scopedtags'' not empty after processing,'
+                  \ 'this should never happen!'
+                  \ 'Please contact the script maintainer with an example.'
+        endif
+    endif
+    call s:LogDebugMessage('Number of top-level tags: ' . len(processedtags))
+
+    " Create a placeholder tag for the 'kind' header for folding purposes
+    for kind in typeinfo.kinds
+
+        let curtags = filter(copy(fileinfo.tags),
+                           \ 'v:val.fields.kind ==# kind.short')
+        call s:LogDebugMessage('Processing kind: ' . kind.short .
+                             \ ', number of tags: ' . len(curtags))
+
+        if empty(curtags)
+            continue
+        endif
+
+        let kindtag          = s:KindheaderTag.New(kind.long)
+        let kindtag.short    = kind.short
+        let kindtag.numtags  = len(curtags)
+        let kindtag.fileinfo = fileinfo
+
+        for tag in curtags
+            let tag.parent = kindtag
+        endfor
+    endfor
+
+    if !empty(processedtags)
+        call extend(fileinfo.tags, processedtags)
+    endif
+
+    " Clear old folding information from previous file version to prevent leaks
+    call fileinfo.clearOldFolds()
+
+    " Sort the tags
+    let s:compare_typeinfo = typeinfo
+    call fileinfo.sortTags()
+
+    call s:known_files.put(fileinfo)
+endfunction
+
+" s:ExecuteCtagsOnFile() {{{2
+function! s:ExecuteCtagsOnFile(fname, realfname, ftype) abort
+    call s:LogDebugMessage('ExecuteCtagsOnFile called [' . a:fname . ']')
+
+    let typeinfo = s:known_types[a:ftype]
+
+    if has_key(typeinfo, 'ctagsargs')
+        let ctags_args = ' ' . typeinfo.ctagsargs . ' '
+    else
+        let ctags_args  = ' -f - '
+        let ctags_args .= ' --format=2 '
+        let ctags_args .= ' --excmd=pattern '
+        let ctags_args .= ' --fields=nksSa '
+        let ctags_args .= ' --extra= '
+        let ctags_args .= ' --sort=yes '
+
+        " Include extra type definitions
+        if has_key(typeinfo, 'deffile')
+            let ctags_args .= ' --options=' . typeinfo.deffile . ' '
+        endif
+
+        let ctags_type = typeinfo.ctagstype
+
+        let ctags_kinds = ''
+        for kind in typeinfo.kinds
+            let ctags_kinds .= kind.short
+        endfor
+
+        let ctags_args .= ' --language-force=' . ctags_type .
+                        \ ' --' . ctags_type . '-kinds=' . ctags_kinds . ' '
+    endif
+
+    if has_key(typeinfo, 'ctagsbin')
+        " reset 'wildignore' temporarily in case *.exe is included in it
+        let wildignore_save = &wildignore
+        set wildignore&
+        let ctags_bin = expand(typeinfo.ctagsbin)
+        let &wildignore = wildignore_save
+    else
+        let ctags_bin = g:tagbar_ctags_bin
+    endif
+
+    let ctags_cmd = s:EscapeCtagsCmd(ctags_bin, ctags_args, a:fname)
+    if ctags_cmd == ''
+        return ''
+    endif
+
+    let ctags_output = s:ExecuteCtags(ctags_cmd)
+
+    if v:shell_error || ctags_output =~ 'Warning: cannot open source file'
+        if !s:known_files.has(a:realfname) ||
+         \ !empty(s:known_files.get(a:realfname))
+            echoerr 'Tagbar: Could not execute ctags for ' . a:fname . '!'
+            echomsg 'Executed command: "' . ctags_cmd . '"'
+            if !empty(ctags_output)
+                call s:LogDebugMessage('Command output:')
+                call s:LogDebugMessage(ctags_output)
+                echomsg 'Command output:'
+                for line in split(ctags_output, '\n')
+                    echomsg line
+                endfor
+            endif
+        endif
+        return -1
+    endif
+
+    call s:LogDebugMessage('Ctags executed successfully')
+    return ctags_output
+endfunction
+
+" s:ParseTagline() {{{2
+" Structure of a tag line:
+" tagname<TAB>filename<TAB>expattern;"fields
+" fields: <TAB>name:value
+" fields that are always present: kind, line
+function! s:ParseTagline(part1, part2, typeinfo, fileinfo) abort
+    let basic_info  = split(a:part1, '\t')
+
+    let taginfo      = s:NormalTag.New(basic_info[0])
+    let taginfo.file = basic_info[1]
+
+    " the pattern can contain tabs and thus may have been split up, so join
+    " the rest of the items together again
+    let pattern = join(basic_info[2:], "\t")
+    let start   = 2 " skip the slash and the ^
+    let end     = strlen(pattern) - 1
+    if pattern[end - 1] ==# '$'
+        let end -= 1
+        let dollar = '\$'
+    else
+        let dollar = ''
+    endif
+    let pattern         = strpart(pattern, start, end - start)
+    let taginfo.pattern = '\V\^\C' . pattern . dollar
+
+    " When splitting fields make sure not to create empty keys or values in
+    " case a value illegally contains tabs
+    let fields = split(a:part2, '^\t\|\t\ze\w\+:')
+    let taginfo.fields.kind = remove(fields, 0)
+    for field in fields
+        " can't use split() since the value can contain ':'
+        let delimit = stridx(field, ':')
+        let key = strpart(field, 0, delimit)
+        " Remove all tabs that may illegally be in the value
+        let val = substitute(strpart(field, delimit + 1), '\t', '', 'g')
+        if len(val) > 0
+            let taginfo.fields[key] = val
+        endif
+    endfor
+    " Needed for jsctags
+    if has_key(taginfo.fields, 'lineno')
+        let taginfo.fields.line = taginfo.fields.lineno
+    endif
+
+    " Make some information easier accessible
+    if has_key(a:typeinfo, 'scope2kind')
+        for scope in keys(a:typeinfo.scope2kind)
+            if has_key(taginfo.fields, scope)
+                let taginfo.scope = scope
+                let taginfo.path  = taginfo.fields[scope]
+
+                let taginfo.fullpath = taginfo.path . a:typeinfo.sro .
+                                     \ taginfo.name
+                break
+            endif
+        endfor
+        let taginfo.depth = len(split(taginfo.path, '\V' . a:typeinfo.sro))
+    endif
+
+    let taginfo.fileinfo = a:fileinfo
+    let taginfo.typeinfo = a:typeinfo
+
+    " Needed for folding
+    try
+        call taginfo.initFoldState()
+    catch /^Vim(\a\+):E716:/ " 'Key not present in Dictionary'
+        " The tag has a 'kind' that doesn't exist in the type definition
+        call s:LogDebugMessage('ERROR Unknown tag kind: ' . taginfo.fields.kind)
+        echoerr 'Unknown tag kind encountered: ' . taginfo.fields.kind
+              \ 'Your ctags and Tagbar configurations are out of sync!'
+              \ 'Please read '':help tagbar-extend''.'
+    endtry
+
+    return taginfo
+endfunction
+
+" s:AddScopedTags() {{{2
+" Recursively process tags. Unfortunately there is a problem: not all tags in
+" a hierarchy are actually there. For example, in C++ a class can be defined
+" in a header file and implemented in a .cpp file (so the class itself doesn't
+" appear in the .cpp file and thus doesn't generate a tag). Another example
+" are anonymous structures like namespaces, structs, enums, and unions, that
+" also don't get a tag themselves. These tags are thus called 'pseudo-tags' in
+" Tagbar. Properly parsing them is quite tricky, so try not to think about it
+" too much.
+function! s:AddScopedTags(tags, processedtags, parent, depth,
+                        \ typeinfo, fileinfo) abort
+    if !empty(a:parent)
+        let curpath = a:parent.fullpath
+        let pscope  = a:typeinfo.kind2scope[a:parent.fields.kind]
+    else
+        let curpath = ''
+        let pscope  = ''
+    endif
+
+    let is_cur_tag = 'v:val.depth == a:depth'
+
+    if !empty(curpath)
+        " Check whether the tag is either a direct child at the current depth
+        " or at least a proper grandchild with pseudo-tags in between. If it
+        " is a direct child also check for matching scope.
+        let is_cur_tag .= ' &&
+        \ (v:val.path ==# curpath ||
+         \ match(v:val.path, ''\V\^\C'' . curpath . a:typeinfo.sro) == 0) &&
+        \ (v:val.path ==# curpath ? (v:val.scope ==# pscope) : 1)'
+    endif
+
+    let curtags = filter(copy(a:tags), is_cur_tag)
+
+    if !empty(curtags)
+        call filter(a:tags, '!(' . is_cur_tag . ')')
+
+        let realtags   = []
+        let pseudotags = []
+
+        while !empty(curtags)
+            let tag = remove(curtags, 0)
+
+            if tag.path != curpath
+                " tag is child of a pseudo-tag, so create a new pseudo-tag and
+                " add all its children to it
+                let pseudotag = s:ProcessPseudoTag(curtags, tag, a:parent,
+                                                 \ a:typeinfo, a:fileinfo)
+
+                call add(pseudotags, pseudotag)
+            else
+                call add(realtags, tag)
+            endif
+        endwhile
+
+        " Recursively add the children of the tags on the current level
+        for tag in realtags
+            let tag.parent = a:parent
+
+            if !has_key(a:typeinfo.kind2scope, tag.fields.kind)
+                continue
+            endif
+
+            if !has_key(tag, 'children')
+                let tag.children = []
+            endif
+
+            call s:AddScopedTags(a:tags, tag.children, tag, a:depth + 1,
+                               \ a:typeinfo, a:fileinfo)
+        endfor
+        call extend(a:processedtags, realtags)
+
+        " Recursively add the children of the tags that are children of the
+        " pseudo-tags on the current level
+        for tag in pseudotags
+            call s:ProcessPseudoChildren(a:tags, tag, a:depth, a:typeinfo,
+                                       \ a:fileinfo)
+        endfor
+        call extend(a:processedtags, pseudotags)
+    endif
+
+    " Now we have to check if there are any pseudo-tags at the current level
+    " so we have to check for real tags at a lower level, i.e. grandchildren
+    let is_grandchild = 'v:val.depth > a:depth'
+
+    if !empty(curpath)
+        let is_grandchild .=
+        \ ' && match(v:val.path, ''\V\^\C'' . curpath . a:typeinfo.sro) == 0'
+    endif
+
+    let grandchildren = filter(copy(a:tags), is_grandchild)
+
+    if !empty(grandchildren)
+        call s:AddScopedTags(a:tags, a:processedtags, a:parent, a:depth + 1,
+                           \ a:typeinfo, a:fileinfo)
+    endif
+endfunction
+
+" s:ProcessPseudoTag() {{{2
+function! s:ProcessPseudoTag(curtags, tag, parent, typeinfo, fileinfo) abort
+    let curpath = !empty(a:parent) ? a:parent.fullpath : ''
+
+    let pseudoname = substitute(a:tag.path, curpath, '', '')
+    let pseudoname = substitute(pseudoname, '\V\^' . a:typeinfo.sro, '', '')
+    let pseudotag  = s:CreatePseudoTag(pseudoname, a:parent, a:tag.scope,
+                                     \ a:typeinfo, a:fileinfo)
+    let pseudotag.children = [a:tag]
+
+    " get all the other (direct) children of the current pseudo-tag
+    let ispseudochild = 'v:val.path ==# a:tag.path && v:val.scope ==# a:tag.scope'
+    let pseudochildren = filter(copy(a:curtags), ispseudochild)
+    if !empty(pseudochildren)
+        call filter(a:curtags, '!(' . ispseudochild . ')')
+        call extend(pseudotag.children, pseudochildren)
+    endif
+
+    return pseudotag
+endfunction
+
+" s:ProcessPseudoChildren() {{{2
+function! s:ProcessPseudoChildren(tags, tag, depth, typeinfo, fileinfo) abort
+    for childtag in a:tag.children
+        let childtag.parent = a:tag
+
+        if !has_key(a:typeinfo.kind2scope, childtag.fields.kind)
+            continue
+        endif
+
+        if !has_key(childtag, 'children')
+            let childtag.children = []
+        endif
+
+        call s:AddScopedTags(a:tags, childtag.children, childtag, a:depth + 1,
+                           \ a:typeinfo, a:fileinfo)
+    endfor
+
+    let is_grandchild = 'v:val.depth > a:depth &&
+                       \ match(v:val.path, ''^\C'' . a:tag.fullpath) == 0'
+    let grandchildren = filter(copy(a:tags), is_grandchild)
+    if !empty(grandchildren)
+        call s:AddScopedTags(a:tags, a:tag.children, a:tag, a:depth + 1,
+                           \ a:typeinfo, a:fileinfo)
+    endif
+endfunction
+
+" s:CreatePseudoTag() {{{2
+function! s:CreatePseudoTag(name, parent, scope, typeinfo, fileinfo) abort
+    if !empty(a:parent)
+        let curpath = a:parent.fullpath
+        let pscope  = a:typeinfo.kind2scope[a:parent.fields.kind]
+    else
+        let curpath = ''
+        let pscope  = ''
+    endif
+
+    let pseudotag             = s:PseudoTag.New(a:name)
+    let pseudotag.fields.kind = a:typeinfo.scope2kind[a:scope]
+
+    let parentscope = substitute(curpath, a:name . '$', '', '')
+    let parentscope = substitute(parentscope,
+                               \ '\V\^' . a:typeinfo.sro . '\$', '', '')
+
+    if pscope != ''
+        let pseudotag.fields[pscope] = parentscope
+        let pseudotag.scope    = pscope
+        let pseudotag.path     = parentscope
+        let pseudotag.fullpath =
+                    \ pseudotag.path . a:typeinfo.sro . pseudotag.name
+    endif
+    let pseudotag.depth = len(split(pseudotag.path, '\V' . a:typeinfo.sro))
+
+    let pseudotag.parent = a:parent
+
+    let pseudotag.fileinfo = a:fileinfo
+    let pseudotag.typeinfo = a:typeinfo
+
+    call pseudotag.initFoldState()
+
+    return pseudotag
+endfunction
+
+" Sorting {{{1
+" s:SortTags() {{{2
+function! s:SortTags(tags, comparemethod) abort
+    call sort(a:tags, a:comparemethod)
+
+    for tag in a:tags
+        if has_key(tag, 'children')
+            call s:SortTags(tag.children, a:comparemethod)
+        endif
+    endfor
+endfunction
+
+" s:CompareByKind() {{{2
+function! s:CompareByKind(tag1, tag2) abort
+    let typeinfo = s:compare_typeinfo
+
+    if typeinfo.kinddict[a:tag1.fields.kind] <#
+     \ typeinfo.kinddict[a:tag2.fields.kind]
+        return -1
+    elseif typeinfo.kinddict[a:tag1.fields.kind] >#
+         \ typeinfo.kinddict[a:tag2.fields.kind]
+        return 1
+    else
+        " Ignore '~' prefix for C++ destructors to sort them directly under
+        " the constructors
+        if a:tag1.name[0] ==# '~'
+            let name1 = a:tag1.name[1:]
+        else
+            let name1 = a:tag1.name
+        endif
+        if a:tag2.name[0] ==# '~'
+            let name2 = a:tag2.name[1:]
+        else
+            let name2 = a:tag2.name
+        endif
+
+        if name1 <=# name2
+            return -1
+        else
+            return 1
+        endif
+    endif
+endfunction
+
+" s:CompareByLine() {{{2
+function! s:CompareByLine(tag1, tag2) abort
+    return a:tag1.fields.line - a:tag2.fields.line
+endfunction
+
+" s:ToggleSort() {{{2
+function! s:ToggleSort() abort
+    let fileinfo = s:known_files.getCurrent()
+    if empty(fileinfo)
+        return
+    endif
+
+    let curline = line('.')
+
+    match none
+
+    let s:compare_typeinfo = s:known_types[fileinfo.ftype]
+
+    if has_key(s:compare_typeinfo, 'sort')
+        let s:compare_typeinfo.sort = !s:compare_typeinfo.sort
+    else
+        let g:tagbar_sort = !g:tagbar_sort
+    endif
+
+    call fileinfo.sortTags()
+
+    call s:RenderContent()
+
+    execute curline
+endfunction
+
+" Display {{{1
+" s:RenderContent() {{{2
+function! s:RenderContent(...) abort
+    call s:LogDebugMessage('RenderContent called')
+    let s:new_window = 0
+
+    if a:0 == 1
+        let fileinfo = a:1
+    else
+        let fileinfo = s:known_files.getCurrent()
+    endif
+
+    if empty(fileinfo)
+        call s:LogDebugMessage('Empty fileinfo, returning')
+        return
+    endif
+
+    let tagbarwinnr = bufwinnr('__Tagbar__')
+
+    if &filetype == 'tagbar'
+        let in_tagbar = 1
+    else
+        let in_tagbar = 0
+        let prevwinnr = winnr()
+
+        " Get the previous window number, so that we can reproduce
+        " the window entering history later. Do not run autocmd on
+        " this command, make sure nothing is interfering.
+        call s:winexec('noautocmd wincmd p')
+        let pprevwinnr = winnr()
+
+        call s:winexec(tagbarwinnr . 'wincmd w')
+    endif
+
+    if !empty(s:known_files.getCurrent()) &&
+     \ fileinfo.fpath ==# s:known_files.getCurrent().fpath
+        " We're redisplaying the same file, so save the view
+        call s:LogDebugMessage('Redisplaying file [' . fileinfo.fpath . ']')
+        let saveline = line('.')
+        let savecol  = col('.')
+        let topline  = line('w0')
+    endif
+
+    let lazyredraw_save = &lazyredraw
+    set lazyredraw
+    let eventignore_save = &eventignore
+    set eventignore=all
+
+    setlocal modifiable
+
+    silent %delete _
+
+    call s:PrintHelp()
+
+    let typeinfo = fileinfo.typeinfo
+
+    " Print tags
+    call s:PrintKinds(typeinfo, fileinfo)
+
+    " Delete empty lines at the end of the buffer
+    for linenr in range(line('$'), 1, -1)
+        if getline(linenr) =~ '^$'
+            execute 'silent ' . linenr . 'delete _'
+        else
+            break
+        endif
+    endfor
+
+    setlocal nomodifiable
+
+    if !empty(s:known_files.getCurrent()) &&
+     \ fileinfo.fpath ==# s:known_files.getCurrent().fpath
+        let scrolloff_save = &scrolloff
+        set scrolloff=0
+
+        call cursor(topline, 1)
+        normal! zt
+        call cursor(saveline, savecol)
+
+        let &scrolloff = scrolloff_save
+    else
+        " Make sure as much of the Tagbar content as possible is shown in the
+        " window by jumping to the top after drawing
+        execute 1
+        call winline()
+
+        " Invalidate highlight cache from old file
+        let s:last_highlight_tline = 0
+    endif
+
+    let &lazyredraw  = lazyredraw_save
+    let &eventignore = eventignore_save
+
+    if !in_tagbar
+        call s:winexec(pprevwinnr . 'wincmd w')
+        call s:winexec(prevwinnr . 'wincmd w')
+    endif
+endfunction
+
+" s:PrintKinds() {{{2
+function! s:PrintKinds(typeinfo, fileinfo) abort
+    call s:LogDebugMessage('PrintKinds called')
+
+    let first_tag = 1
+
+    for kind in a:typeinfo.kinds
+        let curtags = filter(copy(a:fileinfo.tags),
+                           \ 'v:val.fields.kind ==# kind.short')
+        call s:LogDebugMessage('Printing kind: ' . kind.short .
+                             \ ', number of (top-level) tags: ' . len(curtags))
+
+        if empty(curtags)
+            continue
+        endif
+
+        if has_key(a:typeinfo, 'kind2scope') &&
+         \ has_key(a:typeinfo.kind2scope, kind.short)
+            " Scoped tags
+            for tag in curtags
+                if g:tagbar_compact && first_tag && s:short_help
+                    silent 0put =tag.strfmt()
+                else
+                    silent  put =tag.strfmt()
+                endif
+
+                " Save the current tagbar line in the tag for easy
+                " highlighting access
+                let curline                   = line('.')
+                let tag.tline                 = curline
+                let a:fileinfo.tline[curline] = tag
+
+                " Print children
+                if tag.isFoldable() && !tag.isFolded()
+                    for ckind in a:typeinfo.kinds
+                        let childtags = filter(copy(tag.children),
+                                          \ 'v:val.fields.kind ==# ckind.short')
+                        if len(childtags) > 0
+                            " Print 'kind' header of following children, but
+                            " only if they are not scope-defining tags (since
+                            " those already have an identifier)
+                            if !has_key(a:typeinfo.kind2scope, ckind.short)
+                                let indent  = g:tagbar_indent
+                                let indent += g:tagbar_show_visibility
+                                let indent += 1 " fold symbol
+                                silent put =repeat(' ', indent) .
+                                                 \ '[' . ckind.long . ']'
+                                " Add basic tag to allow folding when on the
+                                " header line
+                                let headertag = s:BaseTag.New(ckind.long)
+                                let headertag.parent = tag
+                                let headertag.fileinfo = tag.fileinfo
+                                let a:fileinfo.tline[line('.')] = headertag
+                            endif
+                            for childtag in childtags
+                                call s:PrintTag(childtag, 1,
+                                              \ a:fileinfo, a:typeinfo)
+                            endfor
+                        endif
+                    endfor
+                endif
+
+                if !g:tagbar_compact
+                    silent put _
+                endif
+
+                let first_tag = 0
+            endfor
+        else
+            " Non-scoped tags
+            let kindtag = curtags[0].parent
+
+            if kindtag.isFolded()
+                let foldmarker = s:icon_closed
+            else
+                let foldmarker = s:icon_open
+            endif
+
+            let padding = g:tagbar_show_visibility ? ' ' : ''
+            if g:tagbar_compact && first_tag && s:short_help
+                silent 0put =foldmarker . padding . kind.long
+            else
+                silent  put =foldmarker . padding . kind.long
+            endif
+
+            let curline                   = line('.')
+            let kindtag.tline             = curline
+            let a:fileinfo.tline[curline] = kindtag
+
+            if !kindtag.isFolded()
+                for tag in curtags
+                    let str = tag.strfmt()
+                    silent put =repeat(' ', g:tagbar_indent) . str
+
+                    " Save the current tagbar line in the tag for easy
+                    " highlighting access
+                    let curline                   = line('.')
+                    let tag.tline                 = curline
+                    let a:fileinfo.tline[curline] = tag
+                    let tag.depth                 = 1
+                endfor
+            endif
+
+            if !g:tagbar_compact
+                silent put _
+            endif
+
+            let first_tag = 0
+        endif
+    endfor
+endfunction
+
+" s:PrintTag() {{{2
+function! s:PrintTag(tag, depth, fileinfo, typeinfo) abort
+    " Print tag indented according to depth
+    silent put =repeat(' ', a:depth * g:tagbar_indent) . a:tag.strfmt()
+
+    " Save the current tagbar line in the tag for easy
+    " highlighting access
+    let curline                   = line('.')
+    let a:tag.tline               = curline
+    let a:fileinfo.tline[curline] = a:tag
+
+    " Recursively print children
+    if a:tag.isFoldable() && !a:tag.isFolded()
+        for ckind in a:typeinfo.kinds
+            let childtags = filter(copy(a:tag.children),
+                                 \ 'v:val.fields.kind ==# ckind.short')
+            if len(childtags) > 0
+                " Print 'kind' header of following children, but only if they
+                " are not scope-defining tags (since those already have an
+                " identifier)
+                if !has_key(a:typeinfo.kind2scope, ckind.short)
+                    let indent  = (a:depth + 1) * g:tagbar_indent
+                    let indent += g:tagbar_show_visibility
+                    let indent += 1 " fold symbol
+                    silent put =repeat(' ', indent) . '[' . ckind.long . ']'
+                    " Add basic tag to allow folding when on the header line
+                    let headertag = s:BaseTag.New(ckind.long)
+                    let headertag.parent = a:tag
+                    let headertag.fileinfo = a:tag.fileinfo
+                    let a:fileinfo.tline[line('.')] = headertag
+                endif
+                for childtag in childtags
+                    call s:PrintTag(childtag, a:depth + 1,
+                                  \ a:fileinfo, a:typeinfo)
+                endfor
+            endif
+        endfor
+    endif
+endfunction
+
+" s:PrintHelp() {{{2
+function! s:PrintHelp() abort
+    if !g:tagbar_compact && s:short_help
+        silent 0put ='\" Press <F1> for help'
+        silent  put _
+    elseif !s:short_help
+        silent 0put ='\" Tagbar keybindings'
+        silent  put ='\"'
+        silent  put ='\" --------- General ---------'
+        silent  put ='\" <Enter> : Jump to tag definition'
+        silent  put ='\" p       : As above, but stay in'
+        silent  put ='\"           Tagbar window'
+        silent  put ='\" <C-N>   : Go to next top-level tag'
+        silent  put ='\" <C-P>   : Go to previous top-level tag'
+        silent  put ='\" <Space> : Display tag prototype'
+        silent  put ='\"'
+        silent  put ='\" ---------- Folds ----------'
+        silent  put ='\" +, zo   : Open fold'
+        silent  put ='\" -, zc   : Close fold'
+        silent  put ='\" o, za   : Toggle fold'
+        silent  put ='\" *, zR   : Open all folds'
+        silent  put ='\" =, zM   : Close all folds'
+        silent  put ='\"'
+        silent  put ='\" ---------- Misc -----------'
+        silent  put ='\" s       : Toggle sort'
+        silent  put ='\" x       : Zoom window in/out'
+        silent  put ='\" q       : Close window'
+        silent  put ='\" <F1>    : Remove help'
+        silent  put _
+    endif
+endfunction
+
+" s:RenderKeepView() {{{2
+" The gist of this function was taken from NERDTree by Martin Grenfell.
+function! s:RenderKeepView(...) abort
+    if a:0 == 1
+        let line = a:1
+    else
+        let line = line('.')
+    endif
+
+    let curcol  = col('.')
+    let topline = line('w0')
+
+    call s:RenderContent()
+
+    let scrolloff_save = &scrolloff
+    set scrolloff=0
+
+    call cursor(topline, 1)
+    normal! zt
+    call cursor(line, curcol)
+
+    let &scrolloff = scrolloff_save
+
+    redraw
+endfunction
+
+" User actions {{{1
+" s:HighlightTag() {{{2
+function! s:HighlightTag(openfolds, ...) abort
+    let tagline = 0
+
+    let force = a:0 > 0 ? a:1 : 0
+
+    if a:0 > 1
+        let tag = s:GetNearbyTag(1, a:2)
+    else
+        let tag = s:GetNearbyTag(1)
+    endif
+    if !empty(tag)
+        let tagline = tag.tline
+    endif
+
+    " Don't highlight the tag again if it's the same one as last time.
+    " This prevents the Tagbar window from jumping back after scrolling with
+    " the mouse.
+    if !force && tagline == s:last_highlight_tline
+        return
+    else
+        let s:last_highlight_tline = tagline
+    endif
+
+    let tagbarwinnr = bufwinnr('__Tagbar__')
+    if tagbarwinnr == -1
+        return
+    endif
+    let prevwinnr = winnr()
+    call s:winexec(tagbarwinnr . 'wincmd w')
+
+    match none
+
+    " No tag above cursor position so don't do anything
+    if tagline == 0
+        call s:winexec(prevwinnr . 'wincmd w')
+        redraw
+        return
+    endif
+
+    if g:tagbar_autoshowtag || a:openfolds
+        call s:OpenParents(tag)
+    endif
+
+    " Check whether the tag is inside a closed fold and highlight the parent
+    " instead in that case
+    let tagline = tag.getClosedParentTline()
+
+    " Go to the line containing the tag
+    execute tagline
+
+    " Make sure the tag is visible in the window
+    call winline()
+
+    let foldpat = '[' . s:icon_open . s:icon_closed . ' ]'
+    let pattern = '/^\%' . tagline . 'l\s*' . foldpat . '[-+# ]\zs[^( ]\+\ze/'
+    call s:LogDebugMessage("Highlight pattern: '" . pattern . "'")
+    execute 'match TagbarHighlight ' . pattern
+
+    if a:0 <= 1 " no line explicitly given, so assume we were in the file window
+        call s:winexec(prevwinnr . 'wincmd w')
+    endif
+
+    redraw
+endfunction
+
+" s:JumpToTag() {{{2
+function! s:JumpToTag(stay_in_tagbar) abort
+    let taginfo = s:GetTagInfo(line('.'), 1)
+
+    let autoclose = w:autoclose
+
+    if empty(taginfo) || !taginfo.isNormalTag()
+        return
+    endif
+
+    let tagbarwinnr = winnr()
+
+    " This elaborate construct will try to switch to the correct
+    " buffer/window; if the buffer isn't currently shown in a window it will
+    " open it in the first window with a non-special buffer in it
+    call s:winexec('wincmd p')
+    let filebufnr = bufnr(taginfo.fileinfo.fpath)
+    if bufnr('%') != filebufnr
+        let filewinnr = bufwinnr(filebufnr)
+        if filewinnr != -1
+            call s:winexec(filewinnr . 'wincmd w')
+        else
+            for i in range(1, winnr('$'))
+                call s:winexec(i . 'wincmd w')
+                if &buftype == ''
+                    execute 'buffer ' . filebufnr
+                    break
+                endif
+            endfor
+        endif
+        " To make ctrl-w_p work we switch between the Tagbar window and the
+        " correct window once
+        call s:winexec(tagbarwinnr . 'wincmd w')
+        call s:winexec('wincmd p')
+    endif
+
+    " Mark current position so it can be jumped back to
+    mark '
+
+    " Jump to the line where the tag is defined. Don't use the search pattern
+    " since it doesn't take the scope into account and thus can fail if tags
+    " with the same name are defined in different scopes (e.g. classes)
+    execute taginfo.fields.line
+
+    " If the file has been changed but not saved, the tag may not be on the
+    " saved line anymore, so search for it in the vicinity of the saved line
+    if match(getline('.'), taginfo.pattern) == -1
+        let interval = 1
+        let forward  = 1
+        while search(taginfo.pattern, 'W' . forward ? '' : 'b') == 0
+            if !forward
+                if interval > line('$')
+                    break
+                else
+                    let interval = interval * 2
+                endif
+            endif
+            let forward = !forward
+        endwhile
+    endif
+
+    " If the tag is on a different line after unsaved changes update the tag
+    " and file infos/objects
+    let curline = line('.')
+    if taginfo.fields.line != curline
+        let taginfo.fields.line = curline
+        let taginfo.fileinfo.fline[curline] = taginfo
+    endif
+
+    " Center the tag in the window and jump to the correct column if available
+    normal! z.
+    call cursor(taginfo.fields.line, taginfo.fields.column)
+
+    if foldclosed('.') != -1
+        .foldopen
+    endif
+
+    redraw
+
+    if a:stay_in_tagbar
+        call s:HighlightTag(0)
+        call s:winexec(tagbarwinnr . 'wincmd w')
+    elseif g:tagbar_autoclose || autoclose
+        call s:CloseWindow()
+    else
+        call s:HighlightTag(0)
+    endif
+endfunction
+
+" s:ShowPrototype() {{{2
+function! s:ShowPrototype(short) abort
+    let taginfo = s:GetTagInfo(line('.'), 1)
+
+    if empty(taginfo)
+        return ''
+    endif
+
+    echo taginfo.getPrototype(a:short)
+endfunction
+
+" s:ToggleHelp() {{{2
+function! s:ToggleHelp() abort
+    let s:short_help = !s:short_help
+
+    " Prevent highlighting from being off after adding/removing the help text
+    match none
+
+    call s:RenderContent()
+
+    execute 1
+    redraw
+endfunction
+
+" s:GotoNextToplevelTag() {{{2
+function! s:GotoNextToplevelTag(direction) abort
+    let curlinenr = line('.')
+    let newlinenr = line('.')
+
+    if a:direction == 1
+        let range = range(line('.') + 1, line('$'))
+    else
+        let range = range(line('.') - 1, 1, -1)
+    endif
+
+    for tmplinenr in range
+        let taginfo = s:GetTagInfo(tmplinenr, 0)
+
+        if empty(taginfo)
+            continue
+        elseif empty(taginfo.parent)
+            let newlinenr = tmplinenr
+            break
+        endif
+    endfor
+
+    if curlinenr != newlinenr
+        execute newlinenr
+        call winline()
+    endif
+
+    redraw
+endfunction
+
+" Folding {{{1
+" s:OpenFold() {{{2
+function! s:OpenFold() abort
+    let fileinfo = s:known_files.getCurrent()
+    if empty(fileinfo)
+        return
+    endif
+
+    let curline = line('.')
+
+    let tag = s:GetTagInfo(curline, 0)
+    if empty(tag)
+        return
+    endif
+
+    call tag.openFold()
+
+    call s:RenderKeepView()
+endfunction
+
+" s:CloseFold() {{{2
+function! s:CloseFold() abort
+    let fileinfo = s:known_files.getCurrent()
+    if empty(fileinfo)
+        return
+    endif
+
+    match none
+
+    let curline = line('.')
+
+    let curtag = s:GetTagInfo(curline, 0)
+    if empty(curtag)
+        return
+    endif
+
+    let newline = curtag.closeFold()
+
+    call s:RenderKeepView(newline)
+endfunction
+
+" s:ToggleFold() {{{2
+function! s:ToggleFold() abort
+    let fileinfo = s:known_files.getCurrent()
+    if empty(fileinfo)
+        return
+    endif
+
+    match none
+
+    let curtag = s:GetTagInfo(line('.'), 0)
+    if empty(curtag)
+        return
+    endif
+
+    let newline = line('.')
+
+    if curtag.isKindheader()
+        call curtag.toggleFold()
+    elseif curtag.isFoldable()
+        if curtag.isFolded()
+            call curtag.openFold()
+        else
+            let newline = curtag.closeFold()
+        endif
+    else
+        let newline = curtag.closeFold()
+    endif
+
+    call s:RenderKeepView(newline)
+endfunction
+
+" s:SetFoldLevel() {{{2
+function! s:SetFoldLevel(level, force) abort
+    if a:level < 0
+        echoerr 'Foldlevel can''t be negative'
+        return
+    endif
+
+    let fileinfo = s:known_files.getCurrent()
+    if empty(fileinfo)
+        return
+    endif
+
+    call s:SetFoldLevelRecursive(fileinfo, fileinfo.tags, a:level)
+
+    let typeinfo = fileinfo.typeinfo
+
+    " Apply foldlevel to 'kind's
+    if a:level == 0
+        for kind in typeinfo.kinds
+            call fileinfo.closeKindFold(kind)
+        endfor
+    else
+        for kind in typeinfo.kinds
+            if a:force || !kind.fold
+                call fileinfo.openKindFold(kind)
+            endif
+        endfor
+    endif
+
+    let fileinfo.foldlevel = a:level
+
+    call s:RenderContent()
+endfunction
+
+" s:SetFoldLevelRecursive() {{{2
+" Apply foldlevel to normal tags
+function! s:SetFoldLevelRecursive(fileinfo, tags, level) abort
+    for tag in a:tags
+        if tag.depth >= a:level
+            call tag.setFolded(1)
+        else
+            call tag.setFolded(0)
+        endif
+
+        if has_key(tag, 'children')
+            call s:SetFoldLevelRecursive(a:fileinfo, tag.children, a:level)
+        endif
+    endfor
+endfunction
+
+" s:OpenParents() {{{2
+function! s:OpenParents(...) abort
+    let tagline = 0
+
+    if a:0 == 1
+        let tag = a:1
+    else
+        let tag = s:GetNearbyTag(1)
+    endif
+
+    if !empty(tag)
+        call tag.openParents()
+        call s:RenderKeepView()
+    endif
+endfunction
+
+" Helper functions {{{1
+" s:AutoUpdate() {{{2
+function! s:AutoUpdate(fname, force) abort
+    call s:LogDebugMessage('AutoUpdate called [' . a:fname . ']')
+
+    " Get the filetype of the file we're about to process
+    let bufnr = bufnr(a:fname)
+    let ftype = getbufvar(bufnr, '&filetype')
+
+    " Don't do anything if we're in the tagbar window
+    if ftype == 'tagbar'
+        call s:LogDebugMessage('In Tagbar window, stopping processing')
+        return
+    endif
+
+    " Only consider the main filetype in cases like 'python.django'
+    let sftype = get(split(ftype, '\.'), 0, '')
+    call s:LogDebugMessage("Vim filetype: '" . ftype . "', " .
+                         \ "sanitized filetype: '" . sftype . "'")
+
+    " Don't do anything if the file isn't supported
+    if !s:IsValidFile(a:fname, sftype)
+        call s:LogDebugMessage('Not a valid file, stopping processing')
+        let s:nearby_disabled = 1
+        return
+    endif
+
+    let updated = 0
+
+    " Process the file if it's unknown or the information is outdated.
+    " Testing the mtime of the file is necessary in case it got changed
+    " outside of Vim, for example by checking out a different version from a
+    " VCS.
+    if s:known_files.has(a:fname)
+        let curfile = s:known_files.get(a:fname)
+        " if a:force || getbufvar(curfile.bufnr, '&modified') ||
+        if a:force || empty(curfile) ||
+         \ (filereadable(a:fname) && getftime(a:fname) > curfile.mtime)
+            call s:LogDebugMessage('File data outdated, updating' .
+                                 \ ' [' . a:fname . ']')
+            call s:ProcessFile(a:fname, sftype)
+            let updated = 1
+        else
+            call s:LogDebugMessage('File data seems up to date' .
+                                 \ ' [' . a:fname . ']')
+        endif
+    elseif !s:known_files.has(a:fname)
+        call s:LogDebugMessage('New file, processing [' . a:fname . ']')
+        call s:ProcessFile(a:fname, sftype)
+        let updated = 1
+    endif
+
+    let fileinfo = s:known_files.get(a:fname)
+
+    " If we don't have an entry for the file by now something must have gone
+    " wrong, so don't change the tagbar content
+    if empty(fileinfo)
+        call s:LogDebugMessage('fileinfo empty after processing' .
+                             \ ' [' . a:fname . ']')
+        return
+    endif
+
+    " Display the tagbar content if the tags have been updated or a different
+    " file is being displayed
+    if bufwinnr('__Tagbar__') != -1 &&
+     \ (s:new_window || updated ||
+      \ (!empty(s:known_files.getCurrent()) &&
+       \ a:fname != s:known_files.getCurrent().fpath))
+        call s:RenderContent(fileinfo)
+    endif
+
+    " Call setCurrent after rendering so RenderContent can check whether the
+    " same file is being redisplayed
+    if !empty(fileinfo)
+        call s:LogDebugMessage('Setting current file [' . a:fname . ']')
+        call s:known_files.setCurrent(fileinfo)
+        let s:nearby_disabled = 0
+    endif
+
+    call s:HighlightTag(0)
+    call s:LogDebugMessage('AutoUpdate finished successfully')
+endfunction
+
+" s:CheckMouseClick() {{{2
+function! s:CheckMouseClick() abort
+    let line   = getline('.')
+    let curcol = col('.')
+
+    if (match(line, s:icon_open . '[-+ ]') + 1) == curcol
+        call s:CloseFold()
+    elseif (match(line, s:icon_closed . '[-+ ]') + 1) == curcol
+        call s:OpenFold()
+    elseif g:tagbar_singleclick
+        call s:JumpToTag(0)
+    endif
+endfunction
+
+" s:DetectFiletype() {{{2
+function! s:DetectFiletype(bufnr) abort
+    " Filetype has already been detected for loaded buffers, but not
+    " necessarily for unloaded ones
+    let ftype = getbufvar(a:bufnr, '&filetype')
+
+    if bufloaded(a:bufnr)
+        return ftype
+    endif
+
+    if ftype != ''
+        return ftype
+    endif
+
+    " Unloaded buffer with non-detected filetype, need to detect filetype
+    " manually
+    let bufname = bufname(a:bufnr)
+
+    let eventignore_save = &eventignore
+    set eventignore=FileType
+    let filetype_save = &filetype
+
+    exe 'doautocmd filetypedetect BufRead ' . bufname
+    let ftype = &filetype
+
+    let &filetype = filetype_save
+    let &eventignore = eventignore_save
+
+    return ftype
+endfunction
+
+" s:EscapeCtagsCmd() {{{2
+" Assemble the ctags command line in a way that all problematic characters are
+" properly escaped and converted to the system's encoding
+" Optional third parameter is a file name to run ctags on
+function! s:EscapeCtagsCmd(ctags_bin, args, ...) abort
+    call s:LogDebugMessage('EscapeCtagsCmd called')
+    call s:LogDebugMessage('ctags_bin: ' . a:ctags_bin)
+    call s:LogDebugMessage('ctags_args: ' . a:args)
+
+    if exists('+shellslash')
+        let shellslash_save = &shellslash
+        set noshellslash
+    endif
+
+    if a:0 == 1
+        let fname = shellescape(a:1)
+    else
+        let fname = ''
+    endif
+
+    let ctags_cmd = shellescape(a:ctags_bin) . ' ' . a:args . ' ' . fname
+
+    " Stupid cmd.exe quoting
+    if &shell =~ 'cmd\.exe'
+        let reserved_chars = '&()@^'
+        " not allowed in filenames, but escape anyway just in case
+        let reserved_chars .= '<>|'
+        let pattern = join(split(reserved_chars, '\zs'), '\|')
+        let ctags_cmd = substitute(ctags_cmd, '\V\(' . pattern . '\)',
+                                 \ '^\0', 'g')
+    endif
+
+    if exists('+shellslash')
+        let &shellslash = shellslash_save
+    endif
+
+    " Needed for cases where 'encoding' is different from the system's
+    " encoding
+    if has('multi_byte')
+        if g:tagbar_systemenc != &encoding
+            let ctags_cmd = iconv(ctags_cmd, &encoding, g:tagbar_systemenc)
+        elseif $LANG != ''
+            let ctags_cmd = iconv(ctags_cmd, &encoding, $LANG)
+        endif
+    endif
+
+    call s:LogDebugMessage('Escaped ctags command: ' . ctags_cmd)
+
+    if ctags_cmd == ''
+        echoerr 'Tagbar: Encoding conversion failed!'
+              \ 'Please make sure your system is set up correctly'
+              \ 'and that Vim is compiled with the "+iconv" feature.'
+    endif
+
+    return ctags_cmd
+endfunction
+
+" s:ExecuteCtags() {{{2
+" Execute ctags with necessary shell settings
+" Partially based on the discussion at
+" http://vim.1045645.n5.nabble.com/bad-default-shellxquote-in-Widows-td1208284.html
+function! s:ExecuteCtags(ctags_cmd) abort
+    call s:LogDebugMessage('Executing ctags command: ' . a:ctags_cmd)
+
+    if exists('+shellslash')
+        let shellslash_save = &shellslash
+        set noshellslash
+    endif
+
+    if &shell =~ 'cmd\.exe'
+        let shellxquote_save = &shellxquote
+        set shellxquote=\"
+        let shellcmdflag_save = &shellcmdflag
+        set shellcmdflag=/s\ /c
+    endif
+
+    let ctags_output = system(a:ctags_cmd)
+
+    if &shell =~ 'cmd\.exe'
+        let &shellxquote  = shellxquote_save
+        let &shellcmdflag = shellcmdflag_save
+    endif
+
+    if exists('+shellslash')
+        let &shellslash = shellslash_save
+    endif
+
+    return ctags_output
+endfunction
+
+" s:GetNearbyTag() {{{2
+" Get the tag info for a file near the cursor in the current file
+function! s:GetNearbyTag(all, ...) abort
+    if s:nearby_disabled
+        return {}
+    endif
+
+    let fileinfo = s:known_files.getCurrent()
+    if empty(fileinfo)
+        return {}
+    endif
+
+    let typeinfo = fileinfo.typeinfo
+    if a:0 > 0
+        let curline = a:1
+    else
+        let curline = line('.')
+    endif
+    let tag = {}
+
+    " If a tag appears in a file more than once (for example namespaces in
+    " C++) only one of them has a 'tline' entry and can thus be highlighted.
+    " The only way to solve this would be to go over the whole tag list again,
+    " making everything slower. Since this should be a rare occurence and
+    " highlighting isn't /that/ important ignore it for now.
+    for line in range(curline, 1, -1)
+        if has_key(fileinfo.fline, line)
+            let curtag = fileinfo.fline[line]
+            if a:all || typeinfo.getKind(curtag.fields.kind).stl
+                let tag = curtag
+                break
+            endif
+        endif
+    endfor
+
+    return tag
+endfunction
+
+" s:GetTagInfo() {{{2
+" Return the info dictionary of the tag on the specified line. If the line
+" does not contain a valid tag (for example because it is empty or only
+" contains a pseudo-tag) return an empty dictionary.
+function! s:GetTagInfo(linenr, ignorepseudo) abort
+    let fileinfo = s:known_files.getCurrent()
+
+    if empty(fileinfo)
+        return {}
+    endif
+
+    " Don't do anything in empty and comment lines
+    let curline = getbufline(bufnr('__Tagbar__'), a:linenr)[0]
+    if curline =~ '^\s*$' || curline[0] == '"'
+        return {}
+    endif
+
+    " Check if there is a tag on the current line
+    if !has_key(fileinfo.tline, a:linenr)
+        return {}
+    endif
+
+    let taginfo = fileinfo.tline[a:linenr]
+
+    " Check if the current tag is not a pseudo-tag
+    if a:ignorepseudo && taginfo.isPseudoTag()
+        return {}
+    endif
+
+    return taginfo
+endfunction
+
+" s:IsValidFile() {{{2
+function! s:IsValidFile(fname, ftype) abort
+    call s:LogDebugMessage('Checking if file is valid [' . a:fname . ']')
+
+    if a:fname == '' || a:ftype == ''
+        call s:LogDebugMessage('Empty filename or type')
+        return 0
+    endif
+
+    if !filereadable(a:fname) && getbufvar(a:fname, 'netrw_tmpfile') == ''
+        call s:LogDebugMessage('File not readable')
+        return 0
+    endif
+
+    if &previewwindow
+        call s:LogDebugMessage('In preview window')
+        return 0
+    endif
+
+    if&